build.gradle

plugins {
    id 'java'
    id 'application'
    id 'checkstyle'
    id 'com.github.johnrengelman.shadow' version '5.1.0'
    id 'org.asciidoctor.convert' version '1.5.6'
    id 'com.github.kt3k.coveralls' version '2.8.4'
    id 'jacoco'

}

checkstyle {
    toolVersion = '8.23'
}

jacocoTestReport {
    reports {
        xml.enabled = true
        html.enabled = true
        html.destination file("${buildDir}/jacocoHtml")
    }
}

task coverage(type: JacocoReport) {
    sourceDirectories.from files(sourceSets.main.allSource.srcDirs)
    classDirectories.from files(sourceSets.main.output)
    executionData.from files(jacocoTestReport.executionData)
    afterEvaluate {
        classDirectories.from files(classDirectories.files.collect {
            fileTree(dir: it, exclude: ['**/*.jar'])
        })
    }
    reports {
        html.enabled = true
        xml.enabled = true
    }
}

coveralls {
    sourceDirs = sourceSets.main.allSource.srcDirs.absolutePath
    jacocoReportPath = "${buildDir}/reports/jacoco/coverage/coverage.xml"
}

tasks.coveralls {
    dependsOn coverage
}

shadowJar {
    archiveBaseName = "AlgoSenpaiAdventures"
    archiveVersion = "1.3.3"
    archiveClassifier = null
    archiveAppendix = null
}


group 'com.algosenpai.app'
version '0.1.0'

repositories {
    mavenCentral()
}

application {
    mainClassName = "com.algosenpai.app.Launcher"
}

run {
    standardInput = System.in
}

dependencies {
    
    implementation group: 'org.openjfx', name: 'javafx-base', version: '11', classifier: 'win'
    implementation group: 'org.openjfx', name: 'javafx-base', version: '11', classifier: 'mac'
    implementation group: 'org.openjfx', name: 'javafx-base', version: '11', classifier: 'linux'
    implementation group: 'org.openjfx', name: 'javafx-controls', version: '11', classifier: 'win'
    implementation group: 'org.openjfx', name: 'javafx-controls', version: '11', classifier: 'mac'
    implementation group: 'org.openjfx', name: 'javafx-controls', version: '11', classifier: 'linux'
    implementation group: 'org.openjfx', name: 'javafx-fxml', version: '11', classifier: 'win'
    implementation group: 'org.openjfx', name: 'javafx-fxml', version: '11', classifier: 'mac'
    implementation group: 'org.openjfx', name: 'javafx-fxml', version: '11', classifier: 'linux'
    implementation group: 'org.openjfx', name: 'javafx-graphics', version: '11', classifier: 'win'
    implementation group: 'org.openjfx', name: 'javafx-graphics', version: '11', classifier: 'mac'
    implementation group: 'org.openjfx', name: 'javafx-graphics', version: '11', classifier: 'linux'
    implementation group: 'org.openjfx', name: 'javafx-media', version: '11', classifier: 'win'
    implementation group: 'org.openjfx', name: 'javafx-media', version: '11', classifier: 'mac'
    implementation group: 'org.openjfx', name: 'javafx-media', version: '11', classifier: 'linux'

    implementation 'com.itextpdf:itextpdf:5.5.10'
    implementation 'org.bouncycastle:bcprov-jdk15on:1.56'
    testImplementation 'org.testfx:testfx-core:4.0.16-alpha'
    testImplementation 'org.testfx:testfx-junit5:4.0.16-alpha'
    testImplementation 'org.junit.jupiter:junit-jupiter:5.5.0'
    testImplementation 'org.testfx:openjfx-monocle:jdk-11+26'
}

test {
    useJUnitPlatform()
    testLogging {
        exceptionFormat = 'full'
    }
    testLogging.showStandardStreams = true
    testLogging {
        events "passed", "skipped", "failed"
    }

    systemProperty 'java.awt.headless', 'true'
    systemProperty 'testfx.robot', 'glass'
    systemProperty 'testfx.headless', 'true' 
    systemProperty 'prism.order', 'sw'
    systemProperty 'prism.text', 't2k'
    systemProperty 'testfx.setup.timeout', '2500'



}

asciidoctor {
    backends 'html5'
    sourceDir 'docs'
    outputDir "${buildDir}/docs"

    options = [
            template_dirs: [file("${sourceDir}/templates")],
    ]

    attributes = [
            linkcss: true,
            stylesheet: 'gh-pages.css',
            'source-highlighter': 'coderay',
            icons: 'font',
            experimental: true,
            sectlinks: true,
            idprefix: '',  // for compatibility with GitHub preview
            idseparator: '-',
            'site-root': "${sourceDir}",  // must be the same as sourceDir, do not modify
            'site-name': 'AlgoSenpai Adventures',
            'site-githuburl': 'https://github.com/AY1920S1-CS2113T-T09-3/main',
    ]

    options['template_dirs'].each {
        inputs.files fileTree(it)
    }
}

// Copies stylesheets into the directory containing generated HTML files as
// Asciidoctor does not copy linked CSS files to the output directory when rendering.
// This is needed for linked stylesheets and embedded stylesheets which import other files.
task copyStylesheets(type: Copy) {
    from "${asciidoctor.sourceDir}/stylesheets"
    into "${asciidoctor.outputDir}/html5/stylesheets"
}
asciidoctor.dependsOn copyStylesheets