build.gradle

// Information for all projects

// The default tasks for all projects
defaultTasks 'clean', 'build', 'createReleaseJar', 'install'

allprojects
{
    version = "2.8.5-SNAPSHOT"
    group = "com.almuradev"
}

// Information for all subprojects
// (common, forge and bukkit, but not this file)
subprojects
{   task ->

    task.plugins.withType(org.gradle.api.plugins.JavaBasePlugin)
    {
        sourceCompatibility = '1.8'
        targetCompatibility = '1.8'

        // Generate Eclipse config files when using "gradle eclipse"
        task.apply plugin: 'eclipse'

        // Generate IntelliJ IDEA config files
        task.apply plugin: 'idea'

    }

    // Generate a pom.xml, upload to local Maven repository
    apply plugin: 'maven'

    if(project.hasProperty('sonatypeUsername') && project.hasProperty('sonatypePassword')) {
        uploadArchives {
            repositories {
                mavenDeployer {
                    repository(url: 'https://oss.sonatype.org/service/local/staging/deploy/maven2/') {
                        authentication(userName: sonatypeUsername, password: sonatypePassword)
                    }

                    snapshotRepository(url: 'https://oss.sonatype.org/content/repositories/snapshots/') {
                        authentication(userName: sonatypeUsername, password: sonatypePassword)
                    }

                    pom.project {
                        name project.name

                        issueManagement {
                            system 'GitHub Issues'
                            url 'https://github.com/AlmuraDev/TerrainControl/issues'
                        }

                        licenses {
                            license {
                                name 'MIT License'
                                url 'https://opensource.org/licenses/MIT'
                            }
                        }

                        scm {
                            connection 'scm:git@github.com:AlmuraDev/TerrainControl.git'
                            developerConnection 'scm:git@github.com:AlmuraDev/TerrainControl.git'
                            url 'https://github.com/AlmuraDev/TerrainControl/'
                        }
                    }
                }
            }
        }
    }
}