build.gradle

buildscript {
  repositories {
    jcenter()
  }
  dependencies {
    classpath 'com.github.jengelman.gradle.plugins:shadow:5.2.0'
  }
}

apply plugin: 'java'
apply plugin: 'application'
apply plugin: 'eclipse'
apply plugin: 'maven-publish'
apply plugin: 'jacoco'
// for compliance with higher Java versions
jacoco {
  toolVersion = "0.8.5"
}
apply plugin: 'com.github.johnrengelman.shadow'

mainClassName = 'at.uibk.dps.ee.deploy.server.ApolloServer'

repositories {
  mavenCentral()
  maven { url "https://jitpack.io" }
}

dependencies {
  if (project.hasProperty("local")) {
    implementation project (':EE-Core')
    implementation project (':EE-Guice')
    implementation project (':EE-Model')
    implementation project (':EE-IO')
    implementation project (':EE-Enactables')
    implementation project (':SC-Core')
    implementation project (':EE-Control')
    implementation project (':EE-Docker')
    implementation project (':EE-Visualization')
  }else {
    implementation 'com.github.Apollo-Core:EE-Core:master-SNAPSHOT'
    implementation 'com.github.Apollo-Core:EE-Guice:main-SNAPSHOT'
    implementation 'com.github.Apollo-Core:EE-Model:main-SNAPSHOT'
    implementation 'com.github.Apollo-Core:EE-IO:main-SNAPSHOT'
    implementation 'com.github.Apollo-Core:EE-Enactables:master-SNAPSHOT'
    implementation 'com.github.Apollo-Core:EE-Control:master-SNAPSHOT'
    implementation 'com.github.Apollo-Core:EE-Visualization:master-SNAPSHOT'
    implementation 'com.github.Apollo-Core:SC-Core:main-SNAPSHOT'
  }

  // dependency to Opt4J
  implementation 'com.github.FedorSmirnov89:opt4j:master-SNAPSHOT'
  // dependency to opendse
  implementation 'com.github.FedorSmirnov89:opendse:master-SNAPSHOT'
  // test dependencies
  // JUnit 5
  testImplementation(platform('org.junit:junit-bom:5.7.2'))
  testImplementation('org.junit.jupiter:junit-jupiter')
  testCompile group: 'org.mockito',     name: 'mockito-core',     version: '3.4.4'
  // dependency to local files
  // compile files('libs/lib.jar')

  implementation 'com.google.code.gson:gson:2.8.6'
  implementation group: 'com.io7m.xom', name: 'xom', version: '1.2.10'

  // the server dependencies
  implementation 'io.vertx:vertx-web:4.0.3'
  implementation 'io.vertx:vertx-web-client:4.0.3'

  // AWS Lambda
  implementation 'com.amazonaws:aws-lambda-java-core:1.2.1'
  implementation group: 'com.amazonaws', name: 'aws-lambda-java-events', version: '3.9.0'

  // SLF4J and Logback for logging
  implementation group: "ch.qos.logback", name: "logback-classic", version: "1.2.3"
}

java {
  withSourcesJar()
}

publishing {
  publications {
    maven(MavenPublication) {
      from components.java
    }
  }
}

if (rootProject == project) {
  wrapper {
    gradleVersion = "6.8.3"
    distributionType = Wrapper.DistributionType.ALL
  }
}

test {
  useJUnitPlatform()
}

jacocoTestReport {
  reports {
    xml.enabled true
  }
  afterEvaluate {
    classDirectories.from = files(classDirectories.files.collect {
      fileTree(dir: it, exclude: '**/modules/**')
    })
  }
}

shadowJar {
  sourceCompatibility = 11
  baseName = 'apolloLambda'
  classifier = null
  version = null
}