A nested loop variation

[housten]

Chatgpt gave me the following suggestion for looping which I was doubtful about but in just this case it would be very tidy. When I look at all the questions about looping, none of them are asking about the method at the end of the bicep below.

I am currently getting an error running this but I wonder if it is just that I have the syntax a little wrong or that nested loops in this way won't work. Is it possible?

The rest of the syntax is fine; the module works without the nesting when groups are iterated outside of the module but inside the module would be cleaner...

@description('Name of existing APIM')
param apiManagementName string

@description('A list of groups to create with a corresponding products')
param groups array

resource apimService 'Microsoft.ApiManagement/service@2021-08-01' existing = {
  name: apiManagementName
}

resource serviceGroup 'Microsoft.ApiManagement/service/groups@2021-08-01' = [for group in groups: {
  name: group.Name
  parent: apimService
  properties: {
    displayName: group.DisplayName
    description: group.Description
    externalId: group.?AADGroupId 
    type:  ( empty(group.AADGroupId)  ? 'custom' : 'external')
  }
} ]

// Loop to associate groups with products
resource groupProductAssociations 'Microsoft.ApiManagement/service/products/groups@2021-08-01' = [for group in groups: [ for product in group.Products: {
  name: '${apiManagementName}/${product}/${group.Name}'
  dependsOn: [ serviceGroup ]
}]

For completeness' sake, here is the corresponding parameter file that is parsed and sent to the module by a calling bicep file.

{
    "$schema": "https://schema.management.azure.com/schemas/2019-04-01/deploymentParameters.json#",
    "contentVersion": "1.0.0.0",
    "parameters": {
        "apiManagementName": {
            "value": "apim-dev"
        },
        "groups": {
            "value": [
                {
                    "name": "gr01",
                    "displayName": "group 01",
                    "description": "This is the description for group 01",
                    "AADGroupId": "",
                    "Products": [
                        "sample02",
                        "demo1"
                    ]
                }
            ]
        }
    }
}

[GABRIELNGBTUC]

Nested looping is not possible but using map() you can create the desired outcome:

var test = [
  {
    name: 'name'
    products: [
      1
      2
    ]
  }
]

var productByName = [for item in test: map(item.products, product => {
  name: item.name
  product: product
})]

output testFlatten array = flatten(productByName)

testFlatten resolves to the following array:

[{"name":"name","product":1},{"name":"name","product":2}]

Which you can then loop over with the items() function.

Also I would not rely on ChatGPT for anything bicep related. If Github copilot which uses real repositories as a data source can't get it right most of the time, a LLM that confidently spits false information is never going to give you anything useable.

[housten]

Thanks for the answer @GABRIELNGBTUC, that got me on the right track! I didn't quite understand what you meant with the items() bit but got it working using for looping.

:) I know ChatGPT is likely to lead me astray, that was why I mentioned it - trying to indicate I recognized it as a dubious source but worth double checking JIC. For some reason I just get an error from VS Code when I try to ask bicep related questions.

I tried to do the mapping and flattening in the one variable assignment but the validation steps didn't like it. Could be I had some other error in the assignment...

This is my updated code, in case anyone would like to see it.

@description('Name of existing APIM')
param apiManagementName string

@description('An array of groups to create, each with a list of products to attach to')
param groups array

var productBasedArray = [for group in groups: map(group.products, product => {
  groupname: group.name
  productname: product
})]

var flattenedArray = flatten(productBasedArray)

resource apimService 'Microsoft.ApiManagement/service@2021-08-01' existing = {
  name: apiManagementName
}
// Loop to create groups
resource serviceGroups 'Microsoft.ApiManagement/service/groups@2021-08-01' = [for group in groups: {
  name: group.Name
  parent: apimService
  properties: {
    displayName: group.DisplayName
    description: group.Description
    externalId: group.AADGroupId != '' ? group.AADGroupId : null
    type: group.AADGroupId != '' ? 'external' : 'custom'
  }
}]
// Loop to associate groups with products
resource groupProductAssociations 'Microsoft.ApiManagement/service/products/groups@2021-08-01' = [for product in flattenedArray: {
  name: '${apiManagementName}/${product.productname}/${product.groupname}'
  dependsOn: [
    serviceGroups
  ]
}]

Thank you again for taking the time to answer!

[GABRIELNGBTUC]

Sorry about the confusion regarding the items function. I copy pasted the flattened result from the portal after writing my comment so at that time I probably forgot that flatten would return an array and not a dictionary.

Glad you got the module to work thanks to the map.