CMakeLists.txt

IF(CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)
	#########################################################################################
	# Header Message
	#
	MESSAGE(STATUS "+--------------------------------------------------------------------+")
	MESSAGE(STATUS "|                             LibPRF                                 |")
	MESSAGE(STATUS "+--------------------------------------------------------------------+")
	MESSAGE(STATUS "|     (C) Copyright SIB Swiss Institute of Bioinformatics            |")
	MESSAGE(STATUS "|         Thierry Schuepbach (thierry.schuepbach@sib.swiss)          |")
	MESSAGE(STATUS "|                                                                    |")
	MESSAGE(STATUS "+--------------------------------------------------------------------+")

	#########################################################################################
	# CMAKE
	#
	CMAKE_MINIMUM_REQUIRED(VERSION 2.8 FATAL_ERROR)
	PROJECT(PRF C CXX)
	IF(COMMAND cmake_policy)
		IF(POLICY CMP0003) 
			CMAKE_POLICY(SET CMP0003 NEW)
		ENDIF(POLICY CMP0003)
		IF(POLICY CMP0053) 
			CMAKE_POLICY(SET CMP0053 NEW)
		ENDIF(POLICY CMP0053) 
		IF(POLICY CMP0042)
                        CMAKE_POLICY(SET CMP0042 NEW)
                ENDIF(POLICY CMP0042)
	ENDIF(COMMAND cmake_policy)
	SET(PRF_MASTER_PROJECT ON)
ENDIF(CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)

LIST(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)

#########################################################################################
# Version with GIT
#
SET(MAJOR_VERSION "3")
SET(MINOR_VERSION "2")

FIND_PACKAGE(Git REQUIRED)
FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/pfVersion.h.in
"\#define PRF_MAJOR_VERSION ${MAJOR_VERSION}\n"
"\#define PRF_MINOR_VERSION ${MINOR_VERSION}\n"
"\#define PRF_PATCH_VERSION @PATCH_VERSION@\n"
"\#define PRF_VERSION \"${MAJOR_VERSION}.${MINOR_VERSION}-@PATCH_VERSION@\"\n"
)
FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/version.cmake
"EXECUTE_PROCESS(
     COMMAND ${GIT_EXECUTABLE} rev-parse --verify --short HEAD
     WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
     OUTPUT_VARIABLE PATCH_VERSION
     OUTPUT_STRIP_TRAILING_WHITESPACE
 )
 CONFIGURE_FILE(\${SRC} \${DST} @ONLY)
")
INCLUDE_DIRECTORIES(${CMAKE_CURRENT_BINARY_DIR})
ADD_CUSTOM_TARGET(
    prf_git_version
    ${CMAKE_COMMAND} -D SRC=${CMAKE_CURRENT_BINARY_DIR}/pfVersion.h.in
                     -D DST=${CMAKE_CURRENT_BINARY_DIR}/pfVersion.h
                     -P ${CMAKE_CURRENT_BINARY_DIR}/version.cmake
)

EXECUTE_PROCESS(
     COMMAND ${GIT_EXECUTABLE} rev-parse --verify --short HEAD
     WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
     OUTPUT_VARIABLE PATCH_VERSION
     OUTPUT_STRIP_TRAILING_WHITESPACE
)
MESSAGE(STATUS "GIT version ${PATCH_VERSION}")
#########################################################################################
# External googletest pump
#
INCLUDE(ExternalProject)
INCLUDE(cmake/google_pump.cmake)

#########################################################################################
# Architectures
#
INCLUDE(CMakeDetermineSystem)

IF(CMAKE_SYSTEM_PROCESSOR)
    MESSAGE(STATUS "Compilation on architecture ${CMAKE_SYSTEM_PROCESSOR}.")
ENDIF(CMAKE_SYSTEM_PROCESSOR)

#########################################################################################
# What type of build
#
IF(NOT CMAKE_BUILD_TYPE)
  SET(CMAKE_BUILD_TYPE Release CACHE STRING
      "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
      FORCE)
ENDIF(NOT CMAKE_BUILD_TYPE)

#########################################################################################
# Determine C Compiler
#
IF(NOT CMAKE_COMPILER_IS_GNUCC)
    EXEC_PROGRAM(${CMAKE_C_COMPILER} ARGS ${CMAKE_BOOT_C_FLAGS} -E "\"${PFTOOLS_SOURCE_DIR}/cmake/CMakeTestIntel.c\"" OUTPUT_VARIABLE CMAKE_COMPILER_OUTPUT RETURN_VALUE CMAKE_COMPILER_RETURN)
    SET(CMAKE_COMPILER_IS_GNUCC_RUN 1)
    IF(NOT CMAKE_COMPILER_RETURN)
        IF("${CMAKE_COMPILER_OUTPUT}" MATCHES ".*THIS_IS_INTEL.*" )
             INCLUDE(${PFTOOLS_SOURCE_DIR}/cmake/Linux-icc.cmake)
        ENDIF("${CMAKE_COMPILER_OUTPUT}" MATCHES ".*THIS_IS_INTEL.*" )
    ENDIF(NOT CMAKE_COMPILER_RETURN)
ENDIF(NOT CMAKE_COMPILER_IS_GNUCC)

INCLUDE(CheckCCompilerFlag)
CHECK_C_COMPILER_FLAG(-msse HANDLE_SSE)
IF(HANDLE_SSE)
  SET(CMAKE_C_SSE_FLAGS "-msse")
ELSE(HANDLE_SSE)
  MESSAGE(FATAL_ERROR "C compiler does not support SSE")
ENDIF(HANDLE_SSE)
CHECK_C_COMPILER_FLAG(-msse2 HANDLE_SSE2)
IF(HANDLE_SSE2)
  SET(CMAKE_C_SSE2_FLAGS "-msse2")
ELSE(HANDLE_SSE2)
  MESSAGE(FATAL_ERROR "C compiler does not support SSE 2")
ENDIF(HANDLE_SSE2)
SET(SSE41_FLAGS "-msse4.1" "-msse41")
UNSET(CMAKE_C_SSE41_FLAGS)
FOREACH(flag IN LISTS SSE41_FLAGS)
  MESSAGE(STATUS "testing flag ${flag}...")
  CHECK_C_COMPILER_FLAG("${flag}" HANDLE_SSE41)
  IF(HANDLE_SSE41)
    SET(CMAKE_C_SSE41_FLAGS "${flag}")
    BREAK()
  ENDIF(HANDLE_SSE41)
ENDFOREACH(flag)
IF(NOT DEFINED CMAKE_C_SSE41_FLAGS)
  MESSAGE(FATAL_ERROR "C compiler does not support SSE 4.1")
ENDIF(NOT DEFINED CMAKE_C_SSE41_FLAGS)

CHECK_C_COMPILER_FLAG("-std=c99" HANDLE_C99)
IF(NOT HANDLE_C99)
  MESSAGE(FATAL_ERROR "PRF require a C compiler with C99 support")
ELSE(NOT HANDLE_C99)
  IF(CMAKE_C_FLAGS)
		SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99")
  ELSE(CMAKE_C_FLAGS)
		SET(CMAKE_C_FLAGS "-std=c99")
  ENDIF(CMAKE_C_FLAGS)
  MESSAGE(STATUS "Add -std=c99 to C compiler options")
ENDIF(NOT HANDLE_C99)

SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${CMAKE_C_SSE2_FLAGS}")
MESSAGE(STATUS "Add SSE2 to C compiler options")

IF(CMAKE_COMPILER_IS_GNUCC)
  CHECK_C_COMPILER_FLAG("-fms-extensions" MS_EXTENSION)
  IF(MS_EXTENSION)
    SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fms-extensions")
  ENDIF(MS_EXTENSION)
ENDIF(CMAKE_COMPILER_IS_GNUCC)

#########################################################################################
# Determine Fortran Compiler
#

#########################################################################################
# External Dependencies
#
SET(FIND_LIBRARY_USE_LIB64_PATHS 1)

# Check for pthread
FIND_PACKAGE(Threads REQUIRED)
IF( ${CMAKE_USE_WIN32_THREADS_INIT})
  MESSAGE(STATUS "Using Windows API for threads")
  SET(USE_WINAPI 1)
ENDIF(${CMAKE_USE_WIN32_THREADS_INIT})

# Check for presence of Perl for profile generation
FIND_PACKAGE(Perl)
IF(PERL_FOUND)
	MESSAGE(STATUS "Perl found - full test suite usable")
ELSE(PERL_FOUND)
	MESSAGE(STATUS "Perl not found - test suite only partially usable")
ENDIF(PERL_FOUND)
### insert here condition for which we do full test in case Perl is found
### or a slim version if Perl is absent

#########################################################################################
# Options
#
IF(PRF_MASTER_PROJECT)
	INCLUDE(cmake/options.cmake)
ENDIF(PRF_MASTER_PROJECT)

#########################################################################################
# RPATH before calling dependencies
#
IF(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
	# No rpath on Darwin. Setting it will only cause trouble.
ELSE(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
	SET(CMAKE_EXE_LINKER_FLAGS "-Wl,--enable-new-dtags")
	# use, i.e. don't skip the full RPATH for the build tree
	SET(CMAKE_SKIP_BUILD_RPATH  FALSE)

	# when building, don't use the install RPATH already
	# (but later on when installing)
	SET(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE) 

	# add the automatically determined parts of the RPATH
	# which point to directories outside the build tree to the install RPATH
	SET(CMAKE_INSTALL_RPATH_USE_LINK_PATH FALSE)
	
	IF(NOT CMAKE_INSTALL_RPATH)
		SET(CMAKE_INSTALL_RPATH ${CMAKE_INSTALL_PREFIX}/lib)
	ENDIF(NOT CMAKE_INSTALL_RPATH)

	MESSAGE(STATUS "This is the install RPATH : ${CMAKE_INSTALL_RPATH}")
	
# 		# the RPATH to be used when installing, but only if it's not a system directory
# 		LIST(FIND CMAKE_PLATFORM_IMPLICIT_LINK_DIRECTORIES "${CMAKE_INSTALL_PREFIX}/lib" isSystemDir)
# 		IF("${isSystemDir}" STREQUAL "-1")
# 			SET(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
# 		ENDIF("${isSystemDir}" STREQUAL "-1")
ENDIF(CMAKE_SYSTEM_NAME STREQUAL "Darwin")

#########################################################################################
# Options deps
#
# Check for PCRE library 
IF(PRF_CORE_PCRE)
	IF(BUILD_STATIC_DEPENDENCIES)
		SET(BUILD_PCRE ON)
	ELSE(BUILD_STATIC_DEPENDENCIES)
		OPTION(BUILD_PCRE "Build libpcre from internal source file" OFF)
		IF (NOT BUILD_PCRE)
			FIND_PACKAGE(PCRE)
			IF (NOT PCRE_FOUND)
				MESSAGE(STATUS "libpcre not found, enforcing internal version to be built...")
				SET(BUILD_PCRE ON)
			ENDIF(NOT PCRE_FOUND)
		ENDIF(NOT BUILD_PCRE)
	ENDIF(BUILD_STATIC_DEPENDENCIES)
ENDIF(PRF_CORE_PCRE)

# Check for libHDF5
IF(PRF_INPUT_HDF5)
	IF(BUILD_STATIC_DEPENDENCIES)
		SET(BUILD_HDF5 ON)
	ELSE(BUILD_STATIC_DEPENDENCIES)
		FIND_PACKAGE(HDF5)
		IF(HDF5_FOUND)
			MESSAGE(STATUS "HDF5 library found")
		ELSE(HDF5_FOUND)
			MESSAGE(STATUS "libhdf5 not found, enforcing internal version to be built...")
			SET(BUILD_HDF5 ON)
		ENDIF(HDF5_FOUND)
	ENDIF(BUILD_STATIC_DEPENDENCIES)
ENDIF(PRF_INPUT_HDF5)

# Check for HARU PDF library
IF(PRF_OUTPUT_PDF)
	IF(BUILD_STATIC_DEPENDENCIES)
		SET(BUILD_hpdf ON)
	ELSE(BUILD_STATIC_DEPENDENCIES)
		FIND_PACKAGE(hpdf)
		IF(NOT hpdf_FOUND)
			MESSAGE(STATUS "libHaru not found, enforcing internal version to be built...")
			SET(BUILD_hpdf ON)
		ENDIF(NOT hpdf_FOUND)
	ENDIF(BUILD_STATIC_DEPENDENCIES)
ENDIF(PRF_OUTPUT_PDF)

# Check graphics libraries
IF(PRF_OUTPUT_GRAPHICS)
	IF(BUILD_STATIC_DEPENDENCIES)
		SET(BUILD_GD ON)
		SET(BUILD_PLplot OFF)
	ELSE(BUILD_STATIC_DEPENDENCIES)
		FIND_PACKAGE(GD)
		IF(GD_FOUND)
			IF(GD_SUPPORTS_PNG AND GD_SUPPORTS_JPEG)
				MESSAGE(STATUS "System GD supports PNG and JPEG")
				SET(USE_GD ON)
			ELSE(GD_SUPPORTS_PNG AND GD_SUPPORTS_JPEG)
				IF(GD_SUPPORTS_JPEG)
					MESSAGE(STATUS "System libGD does not support PNG file format")
				ELSE(GD_SUPPORTS_JPEG)
					MESSAGE(STATUS "System libGD does not supprt JPEG file format") 
				ENDIF(GD_SUPPORTS_JPEG)
					MESSAGE(STATUS "libGD does not provides all features, enforcing internal version to be built...")
					SET(BUILD_GD ON)
			ENDIF(GD_SUPPORTS_PNG AND GD_SUPPORTS_JPEG)
		ELSE(GD_FOUND)
			MESSAGE(STATUS "libGD not found,  enforcing internal version to be built...")
			SET(BUILD_GD ON)
		ENDIF(GD_FOUND)
	
		FIND_PACKAGE(PLplot)
		IF(PLplot_FOUND)
			Pac_library_exists(
				"${PLplot_LIBRARIES}"
				"plD_dispatch_init_jpeg"
				"${PLplot_LIBRARY_DIRS}"
				PLplot_SUPPORTS_JPEG
			)
			IF(PLplot_SUPPORTS_JPEG)
				SET(HAVE_PLplot ON)
				MESSAGE(STATUS "PLplot supports JPEG file format")
			ELSE(PLplot_SUPPORTS_JPEG)
				MESSAGE(STATUS "PLplot does not support JPEG file format")
				UNSET(PLplot_FOUND)
			ENDIF(PLplot_SUPPORTS_JPEG)
		ELSE(PLplot_FOUND)
			MESSAGE(STATUS "PLplot not found, enforcing internal version to be built...")
			SET(BUILD_PLplot ON)
		ENDIF(PLplot_FOUND)
	ENDIF(BUILD_STATIC_DEPENDENCIES)
ENDIF(PRF_OUTPUT_GRAPHICS)

IF(PRF_INPUT_PBBAM)
	#FIND_PACKAGE(PBBAM QUIET MODULE)
	IF(NOT PBBAM_FOUND)
		INCLUDE(cmake/build_internal_pbbam.cmake)
	ENDIF(NOT PBBAM_FOUND)
ENDIF(PRF_INPUT_PBBAM)

#########################################################################################
# EXTRA HEADER FILE
#
INCLUDE (CheckIncludeFiles)
CHECK_INCLUDE_FILES (emmintrin.h HAVE_SSE2_H)
CHECK_INCLUDE_FILES (smmintrin.h HAVE_SSE_41_H)
IF (NOT HAVE_SSE2_H OR NOT HAVE_SSE_41_H)
#   MESSAGE(FATAL_ERROR "PFTOOLS require a compiler with both SSE 2 and 4.1 support")
ENDIF(NOT HAVE_SSE2_H OR NOT HAVE_SSE_41_H)

CHECK_INCLUDE_FILES (mm_malloc.h HAVE_MM_MALLOC_H)
CHECK_INCLUDE_FILES (alloca.h HAVE_ALLOCA_H)

IF(PRF_USE_MMAP)
  CHECK_INCLUDE_FILES (sys/mman.h HAVE_MMAN_H)
  IF(NOT HAVE_MMAN_H)
      MESSAGE(WARNING "sys/mman.h is missing, memory mapping cannot be used")
      SET(PRF_USE_MMAP OFF)
  ENDIF(NOT HAVE_MMAN_H)
ENDIF(PRF_USE_MMAP)

#########################################################################################
# Compiling options
#
IF(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
  SET(PRF_USE_AFFINITY OFF)
ENDIF(CMAKE_SYSTEM_NAME STREQUAL "Darwin")

IF(MMAP)
  OPTION(PRF_USE_MMAP "DB files wil be mapped to memory for speed." ON)
ENDIF(MMAP)

#########################################################################################
# Enabling TESTING 
IF (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/data")
  include(CTest)
  IF(BUILD_TESTING)
    SET(TESTS_DIRECTORY "${CMAKE_BINARY_DIR}/Tests")
    IF (NOT EXISTS "${TESTS_DIRECTORY}" )
      FILE(MAKE_DIRECTORY "${TESTS_DIRECTORY}" )
    ENDIF (NOT EXISTS "${TESTS_DIRECTORY}" )
  ENDIF(BUILD_TESTING)
  SET(DATA_DIR "${CMAKE_CURRENT_SOURCE_DIR}/data")
  SET(UTIL_DIR "${CMAKE_CURRENT_SOURCE_DIR}/utils")
  MESSAGE(STATUS "Found data directory in ${DATA_DIR}")
  MESSAGE(STATUS "Found utils directory in ${UTIL_DIR}")
ELSE(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/data")
  MESSAGE(STATUS "No data directory found for tests")
ENDIF(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/data")

#########################################################################################
# STATIC BUILD
#
IF(BUILD_STATIC_DEPENDENCIES)
  #######################################################################################
  ## CHECK TO SEE IF PCRE HAS STATIC LIBRARY
  FIND_LIBRARY(ZLIB_STATIC libz.a)
  IF(NOT ZLIB_STATIC)
    MESSAGE(FATAL_ERROR "Standalone static building is not possible without static library zlib\n")
  ENDIF(NOT ZLIB_STATIC)
	
	IF(USE_GRAPHICS)
		FIND_LIBRARY(PNG_STATIC libpng.a)
		IF(NOT PNG_STATIC)
			MESSAGE(FATAL_ERROR "Standalone static building is not possible without static library PNG\n")
		ENDIF(NOT PNG_STATIC)
		
		FIND_LIBRARY(JPEG_STATIC libjpeg.a)
		IF(NOT JPEG_STATIC)
			MESSAGE(FATAL_ERROR "Standalone static building is not possible without static library JPEG\n")
		ENDIF(NOT JPEG_STATIC)
	ENDIF(USE_GRAPHICS)
	
  ADD_DEFINITIONS("-DNO_USERNAME")
  SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
#   SET (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
#   SET (CMAKE_SHARED_LIBRARY_LINK_C_FLAGS "-static")
  
# 	SET(CMAKE_SKIP_INSTALL_RPATH ON)
# 	SET(CMAKE_SKIP_RPATH ON)
	
ENDIF(BUILD_STATIC_DEPENDENCIES)

#########################################################################################
# Compiling external tools
#

IF(PRF_OUTPUT_PDF)
	IF(BUILD_hpdf)
		INCLUDE(cmake/build_internal_hpdf.cmake)
	ENDIF(BUILD_hpdf)
ENDIF(PRF_OUTPUT_PDF)

IF(PRF_OUTPUT_GRAPHICS)
	IF(BUILD_GD)
		FIND_PACKAGE(PNG)
		IF(NOT PNG_FOUND)
			INCLUDE(cmake/build_internal_png.cmake)
		ENDIF(NOT PNG_FOUND)
		INCLUDE(cmake/build_internal_GD.cmake)
		IF(NOT PNG_FOUND)
			ADD_DEPENDENCIES(libGD libPNG)
		ENDIF(NOT PNG_FOUND)
	ENDIF(BUILD_GD)
	IF(BUILD_PLplot)
		INCLUDE(cmake/build_internal_PLplot.cmake)
	ENDIF(BUILD_PLplot)
ENDIF(PRF_OUTPUT_GRAPHICS)

IF(BUILD_HDF5)
	INCLUDE(cmake/build_internal_hdf5.cmake)
ENDIF(BUILD_HDF5) 

IF(BUILD_PCRE)
	INCLUDE(cmake/build_internal_pcre.cmake)
ENDIF(BUILD_PCRE)


#########################################################################################
## PATHs 
INCLUDE_DIRECTORIES(${CMAKE_CURRENT_BINARY_DIR};${CMAKE_CURRENT_SOURCE_DIR}/include)

#########################################################################################
# Export
#
# INSTALL(EXPORT libprf.cmake DESTINATION ${CMAKE_CURRENT_BINARY_DIR} EXPORT_LINK_INTERFACE_LIBRARIES)

#########################################################################################
# Now treats subdirectories
#
ADD_SUBDIRECTORY(src)
# Data files
ADD_SUBDIRECTORY(data)
# Documentation 
#ADD_SUBDIRECTORY(doc)

#########################################################################################
# CONFIGURATION FILE
#
ADD_SUBDIRECTORY(include)


IF(PRF_MASTER_PROJECT)
#########################################################################################
## Packaging
	SET (CPACK_PACKAGE_NAME ProfileLibrary)
	SET (CPACK_PACKAGE_CONTACT "Thierry Schuepbach")
	SET (CPACK_PACKAGE_VENDOR "SIB Swiss Institute of Bioinformatics")
	SET (CPACK_PACKAGE_VERSION "${MAJOR_VERSION}.${MINOR_VERSION}.${PATCH_VERSION}")
	SET (CPACK_PACKAGE_VERSION_MAJOR   ${MAJOR_VERSION})
	SET (CPACK_PACKAGE_VERSION_MINOR  ${MINOR_VERSION})
	SET (CPACK_PACKAGE_VERSION_PATCH  ${PATCH_VERSION})
	SET (CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${CMAKE_SYSTEM_NAME}-${CMAKE_SYSTEM_PROCESSOR}")
	SET (CPACK_PACKAGE_INSTALL_DIRECTORY "${CPACK_PACKAGE_NAME}/${CPACK_PACKAGE_VERSION}")
	SET (CPACK_INCLUDE_TOPLEVEL_DIRECTORY 1)

	SET(CPACK_COMPONENT_APPLICATIONS_DISPLAY_NAME "PFrepeat suite")
	SET(CPACK_COMPONENT_APPLICATIONS_DESCRIPTION  "Binary executables")

	SET(CPACK_COMPONENT_DATAPRF_DISPLAY_NAME "Profiles files")
	SET(CPACK_COMPONENT_DATAPRF_DESCRIPTION  "Profiles data files")
	SET(CPACK_COMPONENT_DATAPRF_DISABLED TRUE)
	SET(CPACK_COMPONENT_DATAPRF_DEPENDS Applications)
	SET(CPACK_COMPONENT_DATAPRF_GROUP "data")

	SET(CPACK_COMPONENT_DEV_DISPLAY_NAME "Development library")
	SET(CPACK_COMPONENT_DEV_DESCRIPTION  "Development library")
	SET(CPACK_COMPONENT_DEV_DISABLED TRUE)
	SET(CPACK_COMPONENT_DEV_GROUP "dev")

	SET (CPACK_COMPONENTS_ALL Applications DataPrf DataPrfSeq DataCalibration DataBlossum Documentation)


	SET (CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/License.txt")

	UNSET(CPACK_COMPONENTS_ALL_IN_ONE_PACKAGE)
	IF(UNIX AND NOT WIN32)
			SET (CPACK_GENERATOR "TBZ2")
			SET (CPACK_DEB_COMPONENT_INSTALL ON)
			INSTALL(FILES "${CMAKE_CURRENT_SOURCE_DIR}/License.txt" DESTINATION .
							PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
							COMPONENT Applications)
							
			IF(USE_PDF)
				SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libhpdf")
			ENDIF(USE_PDF)
			IF(USE_PCRE)
				SET(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},pcre")
			ENDIF(USE_PCRE)
	ELSE(UNIX AND NOT WIN32)
		#SET (CPACK_COMPONENTS_ALL_IN_ONE_PACKAGE TRUE)
	ENDIF(UNIX AND NOT WIN32)

	SET(CPACK_SOURCE_GENERATOR "TBZ2")
	#SET(CPACK_SOURCE_OUTPUT_CONFIG_FILE "${CMAKE_CURRENT_SOURCE_DIR}/CPackSourceConfig.cmake")
	SET(CPACK_SOURCE_IGNORE_FILES 
		"/CVS/"
		"/Build/*"
		"/build/*"
		"/\\\\.svn/*"
		"/doc/Article/pfsearch3_v0.8.odt"
		"/doc/poster/"
		"/data/Benchmarks/"
		".*~"
		"/doc/Presentation/"
		"/src/C/experimental/"
		"/src/C/external/"
		"/src/C/generic/"
		"/data/.*\\\\.index"
		"/data/.*\\\\.fas"
		".*\\\\.am"
		".*\\\\.kdev4"
		"/\\\\.git/*"
		"/generic-cmake.config"
		"/output.c.diff" 
	)
	SET(CPACK_SOURCE_PACKAGE_FILE_NAME "PFTools-${VERSION}")
	SET(CPACK_SOURCE_STRIP_FILES "")


	INCLUDE(CPack)

	#########################################################################################
	## Post install script
	IF(BUILD_PLplot)
		INSTALL (SCRIPT ${PFTOOLS_SOURCE_DIR}/cmake/PostInstall.cmake)
	ENDIF(BUILD_PLplot)

	#########################################################################################
	## Output global build information
	include(summary)
	summary()
ENDIF(PRF_MASTER_PROJECT)