settings.gradle

pluginManagement {
	repositories {
		gradlePluginPortal()
		maven { url "https://maven.fabricmc.net/" }
		maven { url "https://maven.architectury.dev/" }
		maven { url "https://files.minecraftforge.net/maven/" }
		maven { url "https://maven.kikugie.dev/releases" }
		maven { url "https://maven.kikugie.dev/snapshots" }
	}
}

plugins {
	id "dev.kikugie.stonecutter" version "0.5-beta.5"
}

rootProject.name = 'structurify'

def dists = [
	common: stonecutter_enabled_common_versions.split(',').collect { it.trim() }.toList(),
	fabric: stonecutter_enabled_fabric_versions.split(',').collect { it.trim() }.toList(),
	forge: stonecutter_enabled_forge_versions.split(',').collect { it.trim() }.toList(),
	neoforge: stonecutter_enabled_neoforge_versions.split(',').collect { it.trim() }.toList(),
]

def uniqueVersions = dists.values().flatten().collect { it.trim() }.unique()

stonecutter {
	create(rootProject) {
		versions(uniqueVersions as String[])

		dists.each { branchName, branchVersions ->
			branch(branchName, b -> {
				b.versions(branchVersions as String[])
			})
		}
	}
}