build.gradle

buildscript {
    repositories {
        mavenCentral()
    }
}

plugins {
    id 'com.github.johnrengelman.shadow' version '7.1.2'
    id 'java'
    id 'jacoco'
    id 'idea'
}

apply from: "$rootDir/gradle/jacoco.gradle"
apply from: "$rootDir/gradle/publish.gradle"

if (project.hasProperty("local_script")) {
    apply from: file(local_script + "/build.local.gradle")
}

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

group project.property("group")

archivesBaseName = project.property("pluginName")

repositories {
    mavenLocal()
    mavenCentral()
    maven { url = 'https://jitpack.io' }
    maven { url 'https://repo.georgev22.com/releases' }
}

dependencies {

    compileOnly 'org.apache.commons:commons-lang3:3.12.0'
    compileOnly 'com.google.guava:guava:33.0.0-jre'
    compileOnly 'org.jetbrains:annotations:24.0.1'

    implementation 'me.lucko:jar-relocator:1.7'
    implementation 'org.ow2.asm:asm:9.6'
    implementation 'org.ow2.asm:asm-commons:9.6'

    testImplementation 'com.georgev22:api:7.3.0'
    testImplementation 'org.jetbrains:annotations:24.0.1'
    testImplementation 'commons-io:commons-io:2.11.0'
    testImplementation 'org.apache.logging.log4j:log4j-core:2.19.0'
    testImplementation 'org.yaml:snakeyaml:2.0'
    testImplementation 'commons-lang:commons-lang:2.6'
    testImplementation 'org.jline:jline:3.25.0'
    testImplementation 'net.minecrell:terminalconsoleappender:1.3.0'
    testImplementation 'org.jline:jline-terminal-jna:3.21.0'
    testImplementation 'net.java.dev.jna:jna:5.12.1'
    testImplementation 'org.apache.logging.log4j:log4j-jul:2.19.0'
    testImplementation 'com.lmax:disruptor:3.4.4'
}

shadowJar {
    archiveClassifier.set('')
    relocate 'me.lucko.jarrelocator', "${packageName}.relocator"
    relocate 'org.objectweb.asm', "${packageName}.asm"
}

tasks.build.dependsOn(shadowJar)
tasks.publish.dependsOn(shadowJar)
tasks.register('testJar', Jar) {
    dependsOn testClasses
    archiveClassifier.set('test')
    manifest {
        attributes 'Manifest-Version': '1.0', 'Implementation-Title': 'xyz', 'Implementation-Version': version, 'Main-Class': 'com.georgev22.api.tests.Tests'
    }
    from sourceSets.test.output + sourceSets.main.output
}

test {
    useJUnitPlatform()
    testLogging {
        events "skipped", "failed"
    }
    ignoreFailures = false
}

processResources {
    project.properties.put("version", this.version)
    expand project.properties
}

defaultTasks 'build'