build.gradle

plugins {
    id 'fabric-loom' version '0.12-SNAPSHOT'
    id 'maven-publish'
}

repositories {
    maven {
        url 'https://masa.dy.fi/maven'
    }
    maven {
        url 'https://maven.terraformersmc.com/releases'
    }
    maven {
        url 'https://www.cursemaven.com'
    }
    maven {
        url 'https://jitpack.io'
    }
}


sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

String versionSuffix = ''
if (System.getenv("BUILD_RELEASE") != "true") {
    versionSuffix += '-SHAPSHOT'
}
String buildNumber = System.getenv("BUILD_ID")
if (buildNumber != null) {
    versionSuffix += '+build.' + buildNumber
}
String fullModVersion = project.mod_version + versionSuffix

archivesBaseName = project.archives_base_name
version = 'mc' + project.minecraft_version + '-v' + fullModVersion
group = project.maven_group

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // dependencies
    modImplementation("curse.maven:malilib-303119:${project.malilib_file_id}")
    modImplementation "curse.maven:tweakeroo-297344:${project.tweakeroo_file_id}"
    modImplementation "curse.maven:item-scroller-242064:${project.itemscroller_file_id}"
    modImplementation "curse.maven:litematica-308892:${project.litematica_file_id}"
    modImplementation "com.terraformersmc:modmenu:${project.mod_menu_version}"
    include(modImplementation("com.github.Fallen-Breath:conditional-mixin:${project.conditionalmixin_version}"))

    // runtime mods
    modRuntimeOnly "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"
    modRuntimeOnly "com.github.astei:lazydfu:0.1.2"  // faster startup
}

processResources {
    inputs.property "version", fullModVersion

    filesMatching("fabric.mod.json") {
        expand "version": fullModVersion
    }
}

// ensure that the encoding is set to UTF-8, no matter what the system default is
// this fixes some edge cases with special characters not displaying correctly
// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
}

// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
// if it is present.
// If you remove this task, sources will not be generated.
task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = "sources"
    from sourceSets.main.allSource
}

jar {
    from "LICENSE"
}

// configure the maven publication
publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }

    // select the repositories you want to publish to
    repositories {
        // uncomment to publish to the local maven
        // mavenLocal()
    }
}