Add hyperparameter tuning to node embeddings

Author: JohT

cypher/Dependencies_Projection/Dependencies_13_Sample_Projected_Graph.cypher

@@ -0,0 +1,11 @@
+// Creates a smaller projection by sampling the original graph using "Common Neighbour Aware Random Walk"
+
+CALL gds.graph.sample.cnarw(
+  $dependencies_projection + '-sampled-cleaned',
+  $dependencies_projection,
+  {
+    samplingRatio: toFloat($dependencies_projection_sampling_ratio)
+  }
+)
+YIELD graphName, fromGraphName, nodeCount, relationshipCount, startNodeCount, projectMillis
+RETURN graphName, fromGraphName, nodeCount, relationshipCount, startNodeCount, projectMillis

cypher/Node_Embeddings/Node_Embeddings_1d_Fast_Random_Projection_Stream.cypher

@@ -4,6 +4,7 @@ CALL gds.fastRP.stream(
  $dependencies_projection + '-cleaned', {
       embeddingDimension: toInteger($dependencies_projection_embedding_dimension)
      ,randomSeed: 30
+     ,normalizationStrength: 0.3
      ,relationshipWeightProperty: $dependencies_projection_weight_property
   }
 )

cypher/Node_Embeddings/Node_Embeddings_1d_Fast_Random_Projection_Tuneable_Stream.cypher

@@ -0,0 +1,26 @@
+// Node Embeddings 1d using Fast Random Projection: Stream for Hyper-Parameter tuning. Requires "Add_file_name and_extension.cypher".
+
+CALL gds.fastRP.stream(
+ $dependencies_projection + '-cleaned', {
+      embeddingDimension: toInteger($dependencies_projection_embedding_dimension)
+     ,randomSeed: toInteger($dependencies_projection_embedding_random_seed)
+     ,normalizationStrength: toFloat($dependencies_projection_fast_random_projection_normalization_strength)
+     ,iterationWeights: [0.0, 0.0, 1.0, toFloat($dependencies_projection_fast_random_projection_forth_iteration_weight)]
+     ,relationshipWeightProperty: $dependencies_projection_weight_property
+  }
+)
+YIELD nodeId, embedding
+ WITH gds.util.asNode(nodeId) AS codeUnit
+     ,embedding
+OPTIONAL MATCH (artifact:Java:Artifact)-[:CONTAINS]->(codeUnit)
+   WITH *, artifact.name AS artifactName
+OPTIONAL MATCH (projectRoot:Directory)<-[:HAS_ROOT]-(proj:TS:Project)-[:CONTAINS]->(codeUnit)
+   WITH *, last(split(projectRoot.absoluteFileName, '/')) AS projectName   
+ RETURN DISTINCT 
+        coalesce(codeUnit.fqn, codeUnit.globalFqn, codeUnit.fileName, codeUnit.signature, codeUnit.name) AS codeUnitName
+       ,codeUnit.name                               AS shortCodeUnitName
+       ,elementId(codeUnit)                         AS nodeElementId
+       ,coalesce(artifactName, projectName)         AS projectName
+       ,coalesce(codeUnit.communityLeidenId, 0)     AS communityId
+       ,coalesce(codeUnit.centralityPageRank, 0.01) AS centrality
+       ,embedding

cypher/Node_Embeddings/Node_Embeddings_3d_Node2Vec_Tuneable_Stream.cypher

@@ -0,0 +1,32 @@
+// Node Embeddings 3c using Node2Vec: Stream. Requires "Add_file_name and_extension.cypher".
+
+CALL gds.node2vec.stream(
+ $dependencies_projection + '-cleaned', {
+      embeddingDimension: toInteger($dependencies_projection_embedding_dimension)
+     ,randomSeed: toInteger($dependencies_projection_embedding_random_seed)
+     ,iterations: toInteger($dependencies_projection_node2vec_iterations)
+     ,inOutFactor: toFloat($dependencies_projection_node2vec_in_out_factor)
+     ,returnFactor: toFloat($dependencies_projection_node2vec_return_factor)
+     ,windowSize: toInteger($dependencies_projection_node2vec_window_size)
+     ,walksPerNode: toInteger($dependencies_projection_node2vec_walks_per_node)
+     ,walkLength: toInteger($dependencies_projection_node2vec_walk_length)
+     ,negativeSamplingRate: toInteger($dependencies_projection_node2vec_negative_sampling_rate)
+     ,positiveSamplingFactor: toFloat($dependencies_projection_node2vec_positive_sampling_factor)
+     ,relationshipWeightProperty: $dependencies_projection_weight_property
+  }
+)
+YIELD nodeId, embedding
+ WITH gds.util.asNode(nodeId) AS codeUnit
+     ,embedding
+OPTIONAL MATCH (artifact:Java:Artifact)-[:CONTAINS]->(codeUnit)
+   WITH *, artifact.name AS artifactName
+OPTIONAL MATCH (projectRoot:Directory)<-[:HAS_ROOT]-(proj:TS:Project)-[:CONTAINS]->(codeUnit)
+   WITH *, last(split(projectRoot.absoluteFileName, '/')) AS projectName   
+ RETURN DISTINCT 
+        coalesce(codeUnit.fqn, codeUnit.globalFqn, codeUnit.fileName, codeUnit.signature, codeUnit.name) AS codeUnitName
+       ,codeUnit.name                               AS shortCodeUnitName
+       ,elementId(codeUnit)                         AS nodeElementId
+       ,coalesce(artifactName, projectName)         AS projectName
+       ,coalesce(codeUnit.communityLeidenId, 0)     AS communityId
+       ,coalesce(codeUnit.centralityPageRank, 0.01) AS centrality
+       ,embedding