PKGBUILD

# Maintainer: JordanViknar

pkgname=simplesteamtinker-git
pkgver=r44.84be422
pkgrel=1
pkgdesc="A work-in-progress simple, fast and modern Adwaita alternative to SteamTinkerLaunch."
arch=('x86_64' 'i686' 'armv7h' 'aarch64')
url=https://github.com/JordanViknar/SimpleSteamTinker
license=('MPL2')
makedepends=(
	'git'
	'make'
)
depends=(
	'lua'
	'lua-lgi-git' # Used for GTK (git version because latest release neither supports Libadwaita nor GTK4 and is pretty old)
	'libadwaita'
	'gtk4'
	'lua-filesystem' # Used for some filesystem operations
	'lua-socket' # Used for network operations
	'lua-sec' # Used for secure https interactions
	'lua-dkjson' # Used for json parsing
	'xclip' # Used for copying to clipboard
	'libnotify' # Used for notifications
)
optdepends=(
	'gamemode: Enable GameMode support'
	'mangohud: Enable MangoHud support'
	'mesa: Enable Zink support'
	'switcheroo-control: Launch games with your dedicated GPU'
	'gamescope: Enable GameScope support'
	'protonplus: Recommended to install with SimpleSteamTinker'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/JordanViknar/SimpleSteamTinker')
sha256sums=('SKIP')

pkgver() {
	cd SimpleSteamTinker
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
	cd SimpleSteamTinker
	make system
	cp -r dist/* "${pkgdir}/"
}