build.gradle

plugins {
    id 'eclipse'
    id 'idea'
    id 'java-library'
    id 'maven-publish'
    id 'net.neoforged.gradle.userdev' version '7.0.145'
    id 'io.github.goooler.shadow' version '8.1.8'
}

group = 'com.lovetropics.lib'
base {
    archivesName = 'LTLib'
}

ext.buildnumber = 0
project.buildnumber = System.getenv('BUILD_NUMBER')
version = "${mod_version}" + (buildnumber ? ".${buildnumber}" : ".0-SNAPSHOT")

java.toolchain.languageVersion = JavaLanguageVersion.of(21)

runs {
    configureEach {
        workingDirectory project.file('run')

        systemProperty 'forge.logging.markers', 'REGISTRIES'
        systemProperty 'forge.logging.console.level', 'debug'

        modSource project.sourceSets.main
    }

    client {
        programArguments.addAll '--username', 'Dev###'
    }

    server {
        programArgument '--nogui'
    }

    data {
        programArguments.addAll '--mod', project.mod_id, '--all', '--output', file('src/generated/resources/').getAbsolutePath(), '--existing', file('src/main/resources/').getAbsolutePath()
    }
}

subsystems {
    parchment {
        minecraftVersion = minecraft_version
        mappingsVersion = parchment_version
    }
}

sourceSets.main.resources {
    srcDir 'src/generated/resources'
}

repositories {
    mavenLocal()
}

dependencies {
    implementation "net.neoforged:neoforge:${neo_version}"

    shadow ('io.netty:netty-codec-http:4.1.82.Final') {
        transitive = false
    }
}

tasks.named('jar', Jar).configure {
    manifest {
        attributes([
            "FMLModType": "GAMELIBRARY",
            "Specification-Title": "ltlib",
            "Specification-Vendor": "lovetropics",
            "Specification-Version": "1", // We are version 1 of ourselves
            "Implementation-Title": project.name,
            "Implementation-Version": "${version}",
            "Implementation-Vendor" :"lovetropics",
            "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
        ])
    }

    archiveClassifier = 'slim'
}

tasks.register('sourceJar', Jar) {
    dependsOn classes
    archiveClassifier = 'sources'
    from sourceSets.main.java
}

configurations {
    shadow
    implementation.extendsFrom shadow
}

shadowJar {
    configurations = [project.configurations.shadow]
    archiveClassifier = ''

    ['http', 'rtsp', 'spdy'].forEach {
        relocate "io.netty.handler.codec.$it", "com.lovetropics.lib.repack.io.netty.handler.codec.$it"
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifact shadowJar
            artifact sourceJar
        }
    }

    repositories {
        if (project.hasProperty('mavendir')) {
            maven { url mavendir }
        } else {
            mavenLocal()
        }
    }
}