build.gradle

plugins {
    id 'net.researchgate.release' version '3.0.0'
    id 'java'
    id  'maven-publish'
    id 'signing'
    id("io.github.gradle-nexus.publish-plugin") version "1.1.0"
}

group = 'fr.maif'

subprojects {
    apply plugin: 'java'
    apply plugin: 'maven-publish'
    apply plugin: 'signing'
    group = 'fr.maif'

    repositories {
        mavenCentral()
    }

    java {
        withSourcesJar()
        withJavadocJar()
        toolchain {
            languageVersion = JavaLanguageVersion.of(17)
        }
    }
    ext {
        jacksonVersion = "2.10.5"
        akkaVersion = "2.6.6"
        vavrVersion = "0.10.0"
        _jooqVersion = "3.19.5"
        scalaVersion = "2.13"
        reactorVersion = "3.6.3"
    }
    test {
        testLogging {
            events "PASSED", "SKIPPED", "FAILED", "STANDARD_OUT", "STANDARD_ERROR"
        }
    }

    tasks.named('test') {
        useJUnitPlatform()
    }

    publishing {
        publications {
            mavenJava(MavenPublication) {
                from(components.java)
                pom {
                    name = "Jooq Async"
                    description = "Reactive vertx integration with jooq"
                    inceptionYear = "2020"
                    url = "https://github.com/maif/jooq-async"
                    licenses {
                        license {
                            name = "The Apache License, Version 2.0"
                            url = "http://www.apache.org/licenses/LICENSE-2.0.txt"
                            distribution = "http://www.apache.org/licenses/LICENSE-2.0.txt"
                        }
                    }
                    developers {
                        developer {
                                id = 'alexandre.delegue'
                                name = 'Alexandre Delègue'
                                url = 'https://github.com/larousso'
                            }
                            developer {
                                id = 'benjamin.cavy'
                                name = 'Benjamin Cavy'
                                url = 'https://github.com/ptitFicus'
                            }
                    }
                    scm {
                        url = "https://github.com/maif/jooq-async"
                        connection = "scm:git:git://github.com/maif/jooq-async.git"
                        developerConnection = "scm:git:ssh://github.com/maif/jooq-async.git"
                    }
                }
            }
        }
    }

    signing {
        sign publishing.publications.mavenJava
    }
}


nexusPublishing {
    repositories {
        sonatype {
            nexusUrl.set(uri("https://s01.oss.sonatype.org/service/local/"))
            snapshotRepositoryUrl.set(uri("https://s01.oss.sonatype.org/content/repositories/snapshots/"))
            username = System.env.SONATYPE_USERNAME
            password = System.env.SONATYPE_PASSWORD
        }
    }
}

release {
    tagTemplate = 'v${version}'
}
release.git.requireBranch.set('master')