room29.asc

// Flur 3. Stock (Edison Mansion)

/****************************
*   Raum-Funktionen
****************************/
function room_Load()
{
	String seperator = String.Format("\\ **** Flur 3. Stock");
	Door[eDoorNumTentakelzimmer].Init(oTuerTentakel, hTuerTentakel);
	Door[eDoorNumEdna].Init(oTuerEdna, hTuerEdna);
	Door[eDoorNumEd].Init(oTuerEd, hTuerEd);
	Door[eDoorNumKraftraum].Init(oTuerKraft, hTuerKraft);
	Door[eDoorNumKaminzimmer].Init(oTuerKamin, hTuerKamin);
	
	if ( !gb_TreppenZweiterStockDritterStock )
	{
		oBretter.Visible = true;
		RemoveWalkableArea(2);
		region[1].Enabled = false;
	}
}


/****************************
*   Tür-Hotspot-Funktionen
****************************/
function hTuerTentakel_AnyClick()
{
	if ( player == cPurple )
	{
		Door[eDoorNumTentakelzimmer].s_LookAt	= "Das ist meine Zimmertür.";
	}
	else
	{
		Door[eDoorNumTentakelzimmer].s_LookAt	= "Das ist die Tür zu Purpurs Zimmer.";
	}
	
	if ( Door[eDoorNumTentakelzimmer].ClickSpecial(2, 3, 1000, 0) == 0 ) Unhandled();
}

function hTuerEdna_AnyClick()
{
	if ( player == cEdna )
	{
		Door[eDoorNumEdna].s_LookAt	= "Das ist meine Zimmertür.";
	}
	else
	{
		Door[eDoorNumEdna].s_LookAt	= "Das ist die Tür zu Ednas Zimmer.";
	}
	
	if ( Door[eDoorNumEdna].ClickSpecial(2, 3, 1000, 0) == 0 ) Unhandled();
}

function hTuerEd_AnyClick()
{
	if ( player == cEd )
	{ 
		if ( gb_WiegeInEdsZimmer )
		{
			Door[eDoorNumEd].s_LookAt	= "Das ist das Zimmer von mir und der Kröte.";
		}
		else
		{
			Door[eDoorNumEd].s_LookAt	= "Das ist meine Zimmertür.";
		}
	}
	else
	{
		if ( gb_WiegeInEdsZimmer )
		{
			Door[eDoorNumEd].s_LookAt	= "Das ist die Tür zu Eds Zimmer.";
		}
		else
		{
			Door[eDoorNumEd].s_LookAt	= "Das ist meine Zimmertür.";
		}
	}
	
	if ( Door[eDoorNumEd].ClickSpecial(2, 3, 1000, 0) == 0 ) Unhandled();
}

function hTuerKraft_AnyClick()
{
	if ( Door[eDoorNumKraftraum].ClickSpecial(2, 3, 1000, 0) == 0 ) Unhandled();
}

function hTuerKamin_AnyClick()
{
	if ( Door[eDoorNumKaminzimmer].ClickSpecial(2, 3, 1000, 0) == 0 ) Unhandled();
}


/****************************
*   Objekt-Funktionen
****************************/
function oBretter_AnyClick()
{
	if (any_click_move(71, 135, eDirectionLeft))
	{
		if (UsedAction(eActWalkTo))
		{
		}
		else if (UsedAction(eActLookAt))
		{
			Wait(5);
			player.Say("Da komme ich nicht durch.");
		}
		else if (UsedAction(eActPickUp) || UsedAction(eActOpen) || UsedAction(eActPull))
		{
			Wait(5);
			player.Say("Die sind fest vernagelt.");
		}
		else if (UsedAction(eActUse))
		{
			Wait(5);
			player.Say("Ich wüsste nicht wie.");
		}
		else if (UsedAction(eActClose) || UsedAction(eActPush))
		{
			Wait(5);
			player.Say("Die Nägel sitzen bereits fest.");
		}
		else if (UsedAction(eActUseInventory))
		{
			Wait(5);
			player.Say("Damit werden die Bretter auch nicht lose.");
		}
		else Unhandled();
	}
}


/****************************
*   Hotspot-Funktionen
****************************/
function hDurchgang_AnyClick()
{
	if (UsedAction(eActWalkTo) || UsedAction(eActUse))
	{
		Wait(5);
		if ( !gb_TreppenZweiterStockDritterStock )
		{
			if (any_click_move(71, 135, eDirectionLeft))
			{
				player.Say("Da kann ich nicht hin.");
			}
		}
		else
		{
			any_click_move(49, 135, eDirectionLeft);
		}
	}
	else if (any_click_move(71, 135, eDirectionLeft))
	{
		if (UsedAction(eActLookAt))
		{
			Wait(5);
			player.Say("Da geht es zur Treppe.");
		}
		else if (UsedAction(eActPickUp))
		{
			Wait(5);
			player.Say("Klasse Gag.");
		}
		else Unhandled();
	}
}


/****************************
*   Regionen-Funktionen
****************************/
function region1_WalksOnto()
{
	player.ChangeRoom(27, 60, 73, eDirectionDown);
}