Logging.bas

Attribute VB_Name = "Logging"
Option Explicit


Private started As Boolean

Private logFile As TextStream


Public Sub Start()
    On Error GoTo HandleError

    Set logFile = Utils.GetFileSystem().OpenTextFile(settings("logging.file"), ForAppending, True, TristateTrue)

    started = True

    LogSeparatorLine

    LogInfoAt "Logging.start", "Logging turned on"

    Exit Sub

HandleError:

    DebugLastErrorAt "Logging.start"

End Sub


Public Sub DebugLastErrorAt(functionName)
    Debug.Print "PPVoting error " & Err.Number & " in " & functionName & ": " & vbNewLine & Err.Description
End Sub


Public Sub LogLastErrorAt(functionName As String)
    DebugLastErrorAt functionName
    LogErrorAt functionName, Err.Number, Err.Description
End Sub


Public Sub LogErrorAt(procedure As String, errorNumber As Long, errorMessage As String)
    On Error GoTo HandleError

    If Not started Then Exit Sub

    logFile.WriteLine "[" & Now() & "] ERROR (" & procedure & ") #" & errorNumber & ": " & errorMessage

    Exit Sub

HandleError:

    DebugLastErrorAt "Logging.LogErrorAt"

End Sub


Public Sub LogVotes(ByRef votes As Dictionary)
    On Error GoTo HandleError

    If Not started Then Exit Sub

    logFile.Write "[" & Now() & "] INFO (votes): "

    Dim i As Integer
    For i = 1 To 7
        logFile.Write CStr(votes("total")(i))
        If i <> 7 Then logFile.Write ","
        logFile.Write " "
    Next i

    logFile.WriteLine

    If Not votes.Exists("votes") Then
        LogInfoAt "Logging.logVotes", "Voting information is not detailed (no {ID->vote} info)"
        Exit Sub
    End If

    Dim vote As Variant
    For Each vote In votes("votes")
        logFile.WriteLine "ID " & vote(1) & " voted for " & vote(2) + 1
    Next vote

    Exit Sub

HandleError:

    DebugLastErrorAt "Logging.LogVotes"

End Sub


Public Sub LogInfoAt(procesure As String, errorMessage As String)
    On Error GoTo HandleError

    If Not started Then Exit Sub

    logFile.WriteLine "[" & Now() & "] INFO (" & procesure & "): " & errorMessage

    Exit Sub

HandleError:

    DebugLastErrorAt "Logging.LogInfoAt"

End Sub


Public Sub LogSeparatorLine()
    On Error GoTo HandleError

    If Not started Then Exit Sub

    logFile.WriteLine String(16, "-")

    Exit Sub

HandleError:

    DebugLastErrorAt "Logging.LogSeparatorLine"

End Sub


Public Sub Finish()
    On Error GoTo HandleError

    If Not started Then Exit Sub

    LogInfoAt "Logging.Finish", "Logging turned off"

    logFile.Close

    started = False

    Exit Sub

HandleError:

    started = False

    DebugLastErrorAt "Logging.Finish"

End Sub