UI.bas

Attribute VB_Name = "UI"
Option Explicit


Private ribbon As Office.IRibbonUI


Private Sub UpdateUI()
    ribbon.Invalidate
End Sub


Private Sub UpdateControl(control As IRibbonControl)
    ribbon.InvalidateControl control.Id
End Sub


' This is an event
Public Sub OnUILoaded(rbn As IRibbonUI)
    On Error GoTo HandleError

    Set ribbon = rbn

    Main.Init

    UpdateUI

    Exit Sub

HandleError:

    LogLastErrorAt "UI.OnUILoaded"

End Sub


' This is a UI callabck
Public Sub ProcessText(control As IRibbonControl, text As String)

    If Not IsNumeric(text) Then
        MsgBox "Positive integer number required!", vbCritical, "PPVoting error"
        UpdateControl control
        Exit Sub
    End If

    If CInt(text) <= 0 Then
        MsgBox "Positive integer number required!", vbCritical, "PPVoting error"
        UpdateControl control
        Exit Sub
    End If

    Utils.UpdateSetting control.Tag, CInt(text)

End Sub


' This is a UI callabck
Public Sub GetText(control As IRibbonControl, ByRef text As Variant)

    text = settings(control.Tag)

End Sub


' This is a UI callabck
Public Sub ProcessBool(control As IRibbonControl, state As Boolean)

    Utils.UpdateSetting control.Tag, state

End Sub


' This is a UI callabck
Public Sub GetBool(control As IRibbonControl, ByRef state As Variant)

    state = settings(control.Tag)

End Sub


' This is a UI callabck
Public Sub CheckConnection()
    voting.CheckConnection
End Sub


' This is a UI callabck
Public Sub ChooseLogFile()
    With Application.FileDialog(msoFileDialogOpen)

        .AllowMultiSelect = False
        .InitialFileName = "*.txt"

        If .Show <> -1 Then Exit Sub

        Dim path As String
        path = .SelectedItems(1)

        Utils.UpdateSetting "logging.file", path

    End With
End Sub


' This is a UI callabck
Public Sub ViewLogFile()
    On Error GoTo HandleError

    Dim path As String
    path = settings("logging.file")

    If path = "" Then
        MsgBox "No log file selected", vbInformation, "PPVoting info"
        Exit Sub
    End If

    If Dir(path) = "" Then
        MsgBox "Cannot find " & Utils.QuoteString(path), vbExclamation, "PPVoting info"
        Exit Sub
    End If

    Utils.GetShell().Run "notepad " & Utils.QuoteString(path)

    Exit Sub

HandleError:

    LogLastErrorAt "UI.ViewLogFile"

End Sub


' This is a UI callabck
Public Sub OpenDeviceManager()
    On Error GoTo HandleError

    Utils.GetShell().Run "devmgmt.msc"

    Exit Sub

HandleError:

    LogLastErrorAt "UI.OpenDeviceManager"

End Sub


' This is a UI callabck
Public Sub RemoveSettings()

    Dim result As Boolean
    result = Utils.DeleteSettings

    If result Then
        MsgBox "Successfully removed all PPVoting settings", vbInformation, "PPVoting info"
    Else
        MsgBox "No PPVoting settings present", vbExclamation, "PPVoting info"
    End If

End Sub