flake.nix

{
  description = "A Nix-flake-based Go 1.21 development environment";

  inputs.nixpkgs.url = "https://flakehub.com/f/NixOS/nixpkgs/0.1.*.tar.gz";

  outputs = { self, nixpkgs }:
    let
      goVersion = 21; # Change this to update the whole stack
      nodejsVersion = 18; # Change this to update the docs

      supportedSystems = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
      forEachSupportedSystem = f: nixpkgs.lib.genAttrs supportedSystems (system: f {
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ self.overlays.default ];
        };
      });
    in
    {
      overlays.default = final: prev: {
        go = final."go_1_${toString goVersion}";
        nodejs = final."nodejs_${toString nodejsVersion}";
      };

      devShells = forEachSupportedSystem ({ pkgs }: {
        default = pkgs.mkShell {
          packages = with pkgs; [
            # nodejs used for docs
            nodejs

            # go (version is specified by overlay)
            go

            # goimports, godoc, etc.
            gotools

            # https://github.com/golangci/golangci-lint
            golangci-lint

            # Tests summaries
            gotestsum
          ];
          shellHook = ''
            export CGO_ENABLED="0" # disables cgo. Not sure why this fixes debugger on tests in vscode
          '';
        };
      });
    };
}