v5 ideas

[PatrickF1]

This'll be my scratch space for what I plan to include in the next major release. For anything seeing this, feel free to chime in!

Configurability

fzf.fish, now that it has reached a broader audience, should cater to more users by being more configurable.

One thing many people have asked for configurability on is the preview file functionality. Areas to make configurable

• ls command for previewing dirs (done in Make preview directory command configurable #120)
• bat command for previewing files
• fd command for finding files

Other

• refactor fzf invocations to use a wrapper that makes sure SHELL and fzf default opts are set, which would also make out-of-the-box Tmux support possible
• fzf to quickly find pid, which can be used with kill, pkill, or cat /proc/:pid/*
• killing processes by searching for pid

Post v5 edit:

Things that were done / in progress

• @paddor's suggestion for searching for files under a path that has already been typed in the command
• (partial) quick cd without typing cd

I've changed my mind about configurability. Not to the idea in general if there's a sound case to be made for it, but in regards to making the search files feature more configurable. See my reasoning here. But tl;dr I don't want to compete with file managers which have solved the problem of navigating directories, previewing files, and opening them a million times over and way better than I can.

Everything else above I will consider for minor releases for 5.x

[paddor]

What about searching for files under a path that has already been typed in the command?

vi lib/<ctrl-f>

Or am I just not used to fzf enough yet?

[PatrickF1]

Hi @paddor, interesting use-case. That's really clever, but that's also really hard to implement and it'll also require a completely new command since the search files feature is intended and is probably understood by users to always search the current directory. Let me keep thinking about it.

[paddor]

I saw FZF mention this feature as CTRL-T. Maybe you can build on that.

[wawa19933]

Just found this exciting plugin and found that it lacks Alt + C command to cd into selected dir.

[PatrickF1]

Hey @wawa19933 sorry to disappoint but I don't plan on implementing that for now. I want to keep the plugin laser focused on completing commands quicker, not executing commands for you. That keeps the code, documentation, learning curve, and maintenance of the plugin (including what features to add or exclude) much easier. However, who knows? Maybe I or someone else will start another fzf plugin that executes commands for you.

[PatrickF1]

@wawa19933 actually, there is now something nearly as good as an Alt+C command to cd into the selected dir. See #72

It only requires you to hit enter one extra time after using selecting the directory.

[imr0]

Hey, I am bit new to fish so the following suggestion might be a bit rough around the edges, but I was looking into the same behaviour that @paddor mentioned because that is the most convenient use case for me as well.
Modifying the first block of the current __fzf_search_current_dir.fish as

# Token under cursor                                                                       
set --local token (string unescape (commandline --current-token))           
                                                                            
if test -d $token                                                           
    # Add trailing slash if not present                                     
    string match -qr '[^/]$' $token && set token $token/                    
                                                                            
    # Use $token as base directory and concatenate file paths with it       
    set file_paths_selected $token(                                         
        fd --hidden --color=always --exclude=.git --exclude=.hg --base-directory=$token |
        fzf --multi --ansi --preview='__fzf_preview_file {}' --prompt=$token
    )                                                                       
else                                                                        
    set file_paths_selected (                                               
        fd --hidden --color=always --exclude=.git --exclude=.hg |           
        fzf --multi --ansi --preview='__fzf_preview_file {}' --query=$token 
    )                                                                       
end   

will yield the desired results. First, a check is performed to see whether the token under the cursor is a directory or not. If it is, then it will be the base directory when calling fd. If it is not, then everything is as before.

[PatrickF1]

Hi @imr0, no it's not rough around the edges at all! Your use of fzf's API is splendid! Thank you for your suggestion.
Unfortunately, for better or for worse, @kidonng and I recently implemented a similar feature that precludes adding this one. See #73. Basically, similar to this, the current token is always used to pre-populate the query. That means we can't also use the current token as the base directory. The good news is that since it's used as the current token, it should filter out the results from other directories but the search will run slower.

[paddor]

I find the behavior of @imr0’s function way more intuitive than #73. And it’s faster.

Why I think it’s more intuitive: When you’re typing your command, and start typing a path using TAB because of years of muscle memory, you’re not thinking about FZF yet. Simple directory scoping should apply.

However, if you know you wanna use your current token as the FZF query, you might as well hit ^F first and then type your query.

[paddor]

Something that doesn't work with #73 is searching in a parent-sibling directory, like vi ../lib<TAB>. It will pre-populate the query with ../lib which of course finds nothing.

[kidonng]

@paddor It has nothing to do with the PR. This command is called search currect dir.

[paddor]

So for anyone who wants ^F to search the current directory OR the one you've just typed, put this into ~/config/fish/functions/__fzf_search_this_dir.fish:

function __fzf_search_this_dir --description "Search this directory (CWD or typed directory) using fzf and fd. Insert the selected relative file path into the commandline at the cursor."

    # Token under cursor
    set --local token (string unescape (commandline --current-token))

    if test -d $token
                # Add trailing slash if not present
                string match -qr '[^/]$' $token && set token $token/

                # Use $token as base directory and concatenate file paths with it
                set file_paths_selected $token(
                        fd --hidden --color=always --exclude=.git --exclude=.hg . $token |
                        fzf --multi --ansi --preview='__fzf_preview_file {}' --prompt=$token
                )
    else
                set file_paths_selected (
                        fd --hidden --color=always --exclude=.git --exclude=.hg |
                        fzf --multi --ansi --preview='__fzf_preview_file {}' --query=$token
                )
    end

    if test $status -eq 0
        # If this function was triggered with an empty commandline and the only thing selected is a directory, then
        # prepend ./ to the dir path. Because fish will attempt to cd implicitly if a directory name starting with a dot
        # is provided, this allows the user to hit Enter one more time to quickly cd into the selected directory.
        if test (count (commandline --tokenize)) = 0 && test (count $file_paths_selected) = 1 && test -d $file_paths_selected
            set file_paths_selected ./$file_paths_selected
        end

        commandline --current-token --replace (string escape $file_paths_selected | string join ' ')
    end

    commandline --function repaint
end

And this into ~/config/fish/conf.d/fzf_custom.fish:

bind \cf '__fzf_search_this_dir'

if test "$fish_key_bindings" = 'fish_vi_key_bindings'
    bind --mode insert \cf '__fzf_search_this_dir'
end

[kidonng]

@paddor I have opened a PR about @imr0's sugggestion, please give your thoughts there 👋

[imr0]

I also wrote a little function (inspired by the official zsh script for fzf which I was using frequently) to kill processes via an fzf search. The following script could go into an e.g. __fzf_kill_process.fish:

function __fzf_kill_process --description "Kill running processes via fzf search."

    # Get kill command from command line (e.g. kill, kill -9, etc.)
    set kill_command (commandline --tokenize)

    if test -n "$kill_command"
        # Do nothing if the command does not start with 'kill'
        test "$kill_command[1]" != "kill" && return
    else
        # Set default to 'kill' if command line is empty
        set kill_command "kill"
    end

    # Select process IDs with fzf (inspired by the official fzf script for zsh)
    set processes_selected (
        ps -ef | sed 1d |
        fzf -m --preview 'echo {}' --preview-window down:3:wrap --min-height 15 |
        awk '{print $2}'
    )

    if test $status -eq 0 && test -n "$processes_selected"
        commandline --replace (string join ' ' "$kill_command" "$processes_selected")
    end

    commandline --function repaint
end

One could then bind it to let's say Ctrl+K (as in K for kill).

• If the command line is empty, the command kill is prepended to the pids selected by fzf.
• If the first argument of the command line is kill (e.g. kill, kill -9, kill -USR1, etc.) then this is kept.
• Nothing happens if none of the above.

What do you think?

[PatrickF1]

FYI search processes feature released!

[PatrickF1]

Hey @imr0, yes, I do plan on adding something like that. Thanks for getting me started. I'd prefer to keep the functions generic so they can apply to as many use cases as possible. So I'd probably set one up for finding pid, which can then be used in conjunction with a kill, pkill, or some command to cat /proc/:pid/*

[PatrickF1]

Closing this now that v5 has been released but please feel free to open more issues for suggestions.