build.gradle

plugins {
    id 'java'
    id 'eclipse'
    id "org.jetbrains.gradle.plugin.idea-ext" version "1.0.1"
    id 'com.github.johnrengelman.shadow' version '8.1.1'
}

group = 'ink.magma'
version = '1.3.0'

repositories {
    maven { url 'https://maven.aliyun.com/repository/central' }
    maven { url = 'https://jitpack.io' }
    maven {
        name = "papermc-repo"
        url = "https://repo.papermc.io/repository/maven-public/"
    }
    maven { url = uri("https://repo.ajg0702.us/releases") }
    maven { url 'https://oss.sonatype.org/content/repositories/snapshots' }
    maven { url "https://repo.william278.net/releases" }
    mavenCentral()
}

dependencies {
    compileOnly "com.velocitypowered:velocity-api:3.2.0-SNAPSHOT"
    annotationProcessor "com.velocitypowered:velocity-api:3.2.0-SNAPSHOT"

    compileOnly 'net.md-5:bungeecord-api:1.19-R0.1-SNAPSHOT'

    compileOnly "us.ajg0702.queue.api:api:2.5.0"
    implementation "com.github.Revxrsal.Lamp:common:3.1.5"
    implementation "com.github.Revxrsal.Lamp:bungee:3.1.5"
    implementation "net.kyori:adventure-api:4.16.0"
    implementation "net.kyori:adventure-text-minimessage:4.16.0"
    implementation "net.kyori:adventure-platform-bungeecord:4.3.2"
    implementation "net.william278:annotaml:2.0.7"
}

def templateSource = file('src/main/templates')
def templateDest = layout.buildDirectory.dir('generated/sources/templates')
def generateTemplates = tasks.register('generateTemplates', Copy) { task ->
    def props = [
            'version': project.version
    ]
    task.inputs.properties props

    task.from templateSource
    task.into templateDest
    task.expand props
}

sourceSets.main.java.srcDir(generateTemplates.map { it.outputs })

rootProject.idea.project.settings.taskTriggers.afterSync generateTemplates
project.eclipse.synchronizationTasks(generateTemplates)

tasks.withType(JavaCompile).configureEach {
    options.encoding = "UTF-8"
}

processResources {
    def props = [version: version]
    inputs.properties props
    expand props
    filteringCharset 'UTF-8'
    filesMatching('bungee.yml') {
        expand props
    }
}

import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar

tasks.named('shadowJar', ShadowJar) {
    enableRelocation true
    relocationPrefix "ink.magma.backtolastserver.libraries"
}