CreateRelease.pkl

amends "package://pkg.pkl-lang.org/github.com/stefma/pkl-gha/com.github.action@0.0.2#/GitHubAction.pkl"
import "modules/Steps.pkl"

name = "CreateRelease"

on {
  push {
    tags {
      "*"
    }
  }
}

permissions = new Permissions {
  contents = "write"
}

jobs {
  ["createRelease"] {
    `runs-on` = new UbuntuLatest {}
    steps {
      ...Steps.checkoutAndInstallPkl()
      new {
        name = "Package pkl module"
        run = "pkl project package"
        env {
          ["VERSION"] = "${{ github.ref_name }}"
        }
      }
      new {
        name = "Extract version number from tag"
        run = """
          VERSION_NUMBER=${{ github.ref_name }}
          VERSION_NUMBER=${VERSION_NUMBER#*@}
          echo "VERSION_NUMBER=$VERSION_NUMBER" >> $GITHUB_ENV
          """
      }
      new {
        uses = "softprops/action-gh-release@v2"
        with {
          ["files"] = ".out/com.github.action@${{ env.VERSION_NUMBER }}/*"
          ["fail_on_unmatched_files"] = true
          ["prerelease"] = true
          ["draft"] = true
        }
      }
    }
  }
}