Космические торговцы!!!!!

code/__DEFINES/gamemodes.dm

@@ -25,6 +25,7 @@
 #define F_XENOMORPH_HIVE     "Alien Hivemind"
 #define F_ZOMBIES            "Zobmies"
 #define F_REPLICATORS        "Replicators"
+#define F_SPACE_TRADERS      "Space Traders"
 
 // Role IDs
 #define ABDUCTOR_AGENT "Abductor Agent"
@@ -67,6 +68,7 @@
 #define REPLICATOR "Replicator"
 #define PIRATE "Pirate"
 #define PRISONER "Prisoner"
+#define SPACE_TRADER "Space Trader"
 
 ////////////////////// GREETS /////////////////////////
 #define GREET_DEFAULT		"default"

code/_globalvars/lists/names.dm

@@ -14,6 +14,7 @@ var/global/list/pirate_second = file2list("static/names/piratesecond.txt")
 var/global/list/moth_first = file2list("static/names/moth_first.txt")
 var/global/list/moth_second = file2list("static/names/moth_second.txt")
 var/global/list/serpentid_names = file2list("static/names/serpentid.txt")
+var/global/list/tajaran_male_first = file2list("static/names/tajaran_male_first.txt")
 
 // Traitors key-words
 var/global/list/rus_nouns

code/datums/announcements/events.dm

@@ -266,3 +266,9 @@
 	name = "Event: Icarus Recovered"
 	subtitle = "Тревога. Сбойные дроны"
 	message = "Контроль дронов ВКН Икар разочарован в потере боевого крыла. Выжившие дроны будут восстановлены."
+
+/datum/announcement/centcomm/space_traders
+	name = "Event: Space Traders"
+	subtitle = "Космоторговцы."
+	message = "Мы получили и одобрили запрос на стыковку от группы космоторговцев. " + \
+			"У них кончаются припасы и есть товары для продажи. Ожидайте гостей."

code/datums/outfits/misc/space_traders.dm

@@ -0,0 +1,33 @@
+/datum/outfit/space_trader
+	survival_box = TRUE
+	l_ear = /obj/item/device/radio/headset
+
+/datum/outfit/space_trader/dealer
+	name = "Space Trader Dealer"
+	uniform = /obj/item/clothing/under/lawyer/oldman
+	suit = /obj/item/clothing/suit/storage/postal_dude_coat
+	glasses = /obj/item/clothing/glasses/sunglasses
+	shoes = /obj/item/clothing/shoes/boots
+	back = /obj/item/weapon/storage/backpack/satchel/norm
+
+	r_pocket = /obj/item/weapon/reagent_containers/spray/pepper
+
+/datum/outfit/space_trader/guard
+	name = "Space Trader Guard"
+	uniform = /obj/item/clothing/under/syndicate
+	suit = /obj/item/clothing/suit/storage/flak
+	glasses = /obj/item/clothing/glasses/sunglasses
+	shoes = /obj/item/clothing/shoes/boots
+	belt = /obj/item/weapon/storage/belt/security/ert
+	back = /obj/item/weapon/storage/backpack/satchel/sec
+	gloves = /obj/item/clothing/gloves/security
+	suit_store = /obj/item/weapon/gun/energy/gun
+	backpack_contents = list(/obj/item/clothing/head/helmet)
+
+	r_pocket = /obj/item/clothing/accessory/holster
+
+/datum/outfit/space_trader/porter
+	name = "Space Trader Porter"
+	uniform = /obj/item/clothing/under/rank/cargotech
+	shoes = /obj/item/clothing/shoes/boots/work
+	back = /obj/item/weapon/storage/backpack

code/datums/spawners_menu/spawners.dm

@@ -746,3 +746,71 @@
 	var/datum/role/wizard/R = SSticker.mode.CreateRole(/datum/role/wizard, H)
 	R.rename = FALSE
 	setup_role(R, TRUE)
+
+/*
+ * SPACE TRADERS
+*/
+/datum/spawner/space_trader
+	name = "Космический торговец"
+	desc = "Космический торговец."
+
+	ranks = list(ROLE_GHOSTLY)
+
+	register_only = TRUE
+	time_for_registration = 0.5 MINUTES
+
+	time_while_available = 4 MINUTES
+	var/datum/role/role
+
+/datum/spawner/space_trader/spawn_body(mob/dead/spectator)
+	var/spawnloc = pick_spawn_location()
+	var/client/C = spectator.client
+
+	var/mob/living/carbon/human/H = new
+	C.create_human_apperance(H)
+	H.key = C.key
+	H.forceMove(spawnloc)
+
+	var/datum/faction/space_traders/F = find_faction_by_type(/datum/faction/space_traders)
+	F.roletype = role
+	add_faction_member(F, H, TRUE, TRUE)
+
+/datum/spawner/space_trader/dealer
+	name = "Космоторговец барыга"
+	desc = "Барыга, владеющий торговым судном и товаром на нём. Заработайте столько денег, сколько сможете увезти!"
+	spawn_landmark_name = "Space Trader Dealer"
+	role = /datum/role/space_trader/dealer
+
+/datum/spawner/space_trader/guard
+	name = "Космоторговец охранник"
+	desc = "ЧОПовец, нанятый барыгой для охраны судна и товара на нём от станционных воришек и космических пиратов."
+	spawn_landmark_name = "Space Trader Guard"
+	role = /datum/role/space_trader/guard
+
+/datum/spawner/space_trader/porter
+	name = "Космоторговец посыльный"
+	desc = "Таяран грузчик, работающий на барыгу. Таскайте грузы, выставляйте товары на продажу, помогите барыге обогатиться и не забудьте спросить свою долю!"
+	spawn_landmark_name = "Space Trader Porter"
+	role = /datum/role/space_trader/porter
+
+// porter - always tajaran
+/datum/spawner/space_trader/porter/can_spawn(mob/dead/spectator)
+	if(is_alien_whitelisted_banned(spectator, TAJARAN) || !is_alien_whitelisted(spectator, TAJARAN))
+		to_chat(spectator, "<span class='warning'>Вы не можете играть за таярана.</span>")
+		return FALSE
+	return ..()
+
+/datum/spawner/space_trader/porter/spawn_body(mob/dead/spectator)
+	var/spawnloc = pick_spawn_location()
+	var/client/C = spectator.client
+
+	var/mob/living/carbon/human/H = new(null, TAJARAN)
+	var/new_name = capitalize(pick(global.tajaran_male_first)) + " " + capitalize(pick(global.last_names))
+	C.create_human_apperance(H, new_name)
+	H.key = C.key
+	H.forceMove(spawnloc)
+
+	var/datum/faction/space_traders/F = find_faction_by_type(/datum/faction/space_traders)
+	F.roletype = role
+	add_faction_member(F, H, TRUE, TRUE)
+

code/game/area/shuttle_areas.dm

@@ -262,17 +262,19 @@
 	icon_state = "shuttlered2"
 	looped_ambience = 'sound/ambience/loop_space.ogg'
 
-//Administration Centcom Shuttle
-/area/shuttle/administration/centcom
-	name = "Administration Shuttle Centcom"
-	cases = list("административный шаттл", "административного шаттла", "административному шаттлу", "административный шаттл", "административным шаттлом", "административном шаттле")
+//Space Traders Shuttle
+/area/shuttle/trader
+	name = "Trader Shuttle"
+	cases = list("торговый шаттл", "торгового шаттла", "торговому шаттлу", "торговый шаттл", "торговым шаттлом", "торговом шаттле")
 	icon_state = "shuttlered"
 
-/area/shuttle/administration/station
-	name = "Administration Shuttle"
-	cases = list("административный шаттл", "административного шаттла", "административному шаттлу", "административный шаттл", "административным шаттлом", "административном шаттле")
+/area/shuttle/trader/station
+	name = "Trader Shuttle Station"
+	ambience = 'sound/ambience/space_traders.ogg'
+
+/area/shuttle/trader/space
+	name = "Trader Shuttle Space"
 	icon_state = "shuttlered2"
-	looped_ambience = 'sound/ambience/loop_space.ogg'
 
 //Vox shuttle
 /area/shuttle/vox/arkship
@@ -390,7 +392,6 @@ var/global/list/centcom_shuttle_areas = list (
 	/area/shuttle/escape_pod3/centcom,
 	/area/shuttle/escape_pod4/centcom,
 	/area/shuttle/transport1/centcom,
-	/area/shuttle/administration/centcom,
 	/area/shuttle/specops/centcom,
 	/area/shuttle/officer/centcom
 )
@@ -403,7 +404,7 @@ var/global/list/station_shuttle_areas = list (
 	/area/shuttle/escape_pod3/station,
 	/area/shuttle/escape_pod4/station,
 	/area/shuttle/transport1/station,
-	/area/shuttle/administration/station,
+	/area/shuttle/trader/station,
 	/area/shuttle/specops/station,
 	/area/shuttle/officer/station,
 	/area/shuttle/supply/station,

code/game/gamemodes/factions/space_traders.dm

@@ -0,0 +1,32 @@
+/obj/effect/landmark/space_traders/product
+	name = "Space Traders Product"
+	icon = 'icons/obj/storage.dmi'
+	icon_state = "crate"
+
+/obj/effect/landmark/space_traders/dealer
+	name = "Space Trader Dealer"
+	icon = 'icons/mob/landmarks.dmi'
+	icon_state = "Quartermaster"
+
+/obj/effect/landmark/space_traders/guard
+	name = "Space Trader Guard"
+	icon = 'icons/mob/landmarks.dmi'
+	icon_state = "Blueshield Officer"
+
+/obj/effect/landmark/space_traders/porter
+	name = "Space Trader Porter"
+	icon = 'icons/mob/landmarks.dmi'
+	icon_state = "Trader Porter"
+
+/datum/faction/space_traders
+	name = F_SPACE_TRADERS
+	ID = F_SPACE_TRADERS
+
+	logo_state = "space_traders"
+	max_roles = 3
+
+/datum/faction/space_traders/forgeObjectives()
+	if(!..())
+		return FALSE
+	AppendObjective(/datum/objective/make_money/faction/traders)
+	return TRUE

code/game/gamemodes/objectives/traders_objectives.dm

@@ -0,0 +1,99 @@
+/datum/objective/make_money
+	var/required_money
+
+/datum/objective/make_money/New()
+	explanation_text = "Заработать [required_money] кредитов. В конце смены они должны находиться на вашем счёте."
+
+/datum/objective/make_money/check_completion()
+	if(owner)
+		var/datum/money_account/MA = get_account(owner.get_key_memory(MEM_ACCOUNT_NUMBER))
+		if(MA.money >= required_money)
+			return OBJECTIVE_WIN
+	return OBJECTIVE_LOSS
+
+/datum/objective/make_money/faction/check_completion()
+	if(faction)
+		var/total_money = 0
+		for(var/datum/role/R in faction.members)
+			var/datum/money_account/MA = get_account(R.antag.get_key_memory(MEM_ACCOUNT_NUMBER))
+			total_money += MA.money
+		if(total_money >= required_money)
+			return OBJECTIVE_WIN
+	return OBJECTIVE_LOSS
+
+/datum/objective/make_money/faction/traders
+	required_money = 40000
+
+
+/datum/objective/trader_purchase
+	var/item_name1
+	var/item_name2
+	var/static/possible_items[] = list(
+		"эмиттер" = /obj/machinery/power/emitter,
+		"инкубатор вирусов" = /obj/machinery/disease2/incubator,
+		"хим диспенсер" = /obj/machinery/chem_dispenser,
+		"микроволновку" = /obj/machinery/kitchen_machine/microwave,
+		"бипски" = /obj/machinery/bot/secbot/beepsky,
+		"биогенератор" = /obj/machinery/biogenerator,
+		"экстрактор семян" = /obj/machinery/seed_extractor,
+		"бухломат" = /obj/machinery/vending/boozeomat,
+		"переносной флэшер" = /obj/machinery/flasher/portable,
+		"шкаф главы службы безопасности" = /obj/structure/closet/secure_closet/hos,
+		"канистру азота" = /obj/machinery/portable_atmospherics/canister/nitrogen,
+		"факс" = /obj/machinery/faxmachine,
+		"ядерную боеголовку" = /obj/machinery/nuclearbomb,
+		"раздатчик атмосферных труб" = /obj/machinery/pipedispenser,
+		"кошку главврача Дасти" = /mob/living/simple_animal/cat/dusty,
+		"плазменный дробовик" = /obj/item/weapon/gun/plasma/p104sass,
+		"ручной телепортер" = /obj/item/weapon/hand_tele,
+		"тыквяк" = /obj/item/weapon/reagent_containers/food/snacks/grown/gourd,
+		"имплант защиты разума" = /obj/item/weapon/implantcase/mindshield,
+		"смирительную рубашку" = /obj/item/clothing/suit/straight_jacket,
+		"капитанское жёлтое мыло" = /obj/item/weapon/reagent_containers/food/snacks/soap/deluxe,
+		"мулбота" = /obj/machinery/bot/mulebot,
+		"новогоднюю ёлку" = /obj/item/device/flashlight/lamp/fir,
+		"двухстволку бармена" = /obj/item/weapon/gun/projectile/revolver/doublebarrel,
+		"джукбокс" = /obj/machinery/media/jukebox/bar,
+		"полностью собранное ядро ИИ" = /obj/structure/AIcore/deactivated,
+		"алтарь священника" = /obj/structure/altar_of_gods)
+
+/datum/objective/trader_purchase/New()
+	item_name1 = pick(possible_items)
+	do item_name2 = pick(possible_items)
+	while(item_name1 == item_name2)
+	explanation_text = "Достать и притащить на наш шаттл [item_name1] и [item_name2]."
+
+/datum/objective/trader_purchase/check_completion()
+	var/list/areas = list(/area/shuttle/trader/space, /area/shuttle/trader/station)
+	var/counter = 0
+	for(var/type in areas)
+		for(var/obj/O in get_area_by_type(type))
+			if(istype(O, possible_items[item_name1]) || istype(O, possible_items[item_name2]))
+				counter++
+	if(counter == 2)
+		return OBJECTIVE_WIN
+	else if(counter)
+		return OBJECTIVE_HALFWIN
+	return OBJECTIVE_LOSS
+
+
+/datum/objective/traders_escape
+	explanation_text = "Живыми улететь на своём шаттле со станции."
+
+/datum/objective/traders_escape/check_completion()
+	var/counter = 0
+	if(faction)
+		var/list/mems = faction.members
+		for(var/datum/role/R in mems)
+			var/mob/M = R.antag.current
+			if(!M || ((M.stat == DEAD) && !M.fake_death) || isbrain(M) || issilicon(M)) // alive?
+				continue
+			if(istype(get_area(M), /area/shuttle/trader/space)) // in space on shuttle?
+				counter++
+		if(counter == mems.len) 	// ALL TRADERS ESCAPE ALIVE
+			return OBJECTIVE_WIN
+		else if(counter) 			// AT LEAST ONE TRADER ESCAPE ALIVE
+			return OBJECTIVE_HALFWIN
+		else
+			return OBJECTIVE_LOSS
+	return OBJECTIVE_LOSS