build.gradle

plugins {
    id 'java'
    id 'application'
    id 'org.openjfx.javafxplugin' version '0.0.13'
    id 'org.beryx.jlink' version '2.25.0'
}

version = '1.0'
archivesBaseName = 'AsciiImage'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

javafx {
    version = "19"
    modules = [ 'javafx.controls' , 'javafx.swing' ]
}

repositories {
    mavenCentral()
}

dependencies {
//    runtimeOnly "org.openjfx:javafx-graphics:$javafx.version:win"
//    runtimeOnly "org.openjfx:javafx-graphics:$javafx.version:linux"
//    runtimeOnly "org.openjfx:javafx-graphics:$javafx.version:mac"
}


application {
    mainClass = 'AsciiImage.Main'
    mainModule = 'AsciiImage'
}


jlink {
    options = ['--strip-debug', '--compress', '2', '--no-header-files', '--no-man-pages']
    imageName = 'AsciiImage'
    launcher{
        name = 'Launch'
        noConsole = true
        windowsScriptTemplate = file('templates/wintemplate.txt')
        unixScriptTemplate = file('templates/unixtemplate.txt')
    }
}

tasks.jlink.doLast {
    delete("${buildDir}\\AsciiImage\\release")
    copy {
        from("${buildDir}\\AsciiImage\\bin\\Launch")
        into("${buildDir}\\AsciiImage")
        rename('Launch', 'Launch.sh')
        
    }
    copy {
        from("${buildDir}\\AsciiImage\\bin\\Launch.bat")
        into("${buildDir}\\AsciiImage")
    }
    delete("${buildDir}\\AsciiImage\\bin\\Launch")
    delete("${buildDir}\\AsciiImage\\bin\\Launch.bat")
}

jar {
    manifest {
        attributes([
            'Main-Class': 'AsciiImage.Main',
            'Implementation-Title': 'AsciiImage',
            'Implementation-Version': version,
            'Built-By': 'WispySparks'
        ]) 
    }
}

defaultTasks 'clean'