build.gradle

plugins {
    id 'java'
    id 'org.jetbrains.kotlin.jvm' version '2.0.0'
    id("io.github.goooler.shadow") version "8.1.7"
}

group = 'me.zepsizola'
version = '1.1'
def projectName = 'ZAutoBroadcast'

repositories {
    mavenCentral()
    maven {
        name = "papermc-repo"
        url = "https://repo.papermc.io/repository/maven-public/"
    }
    maven {
        name = "sonatype"
        url = "https://oss.sonatype.org/content/groups/public/"
    }
    maven {
        url = 'https://repo.extendedclip.com/content/repositories/placeholderapi/'
    }
    maven {
        name = "devmart-other"
        url = "https://nexuslite.gcnt.net/repos/other/"
    }
}

dependencies {
    compileOnly "io.papermc.paper:paper-api:1.20-R0.1-SNAPSHOT"
    //compileOnly "io.papermc.paper:paper-api:1.20.4-R0.1-SNAPSHOT"
    implementation "org.jetbrains.kotlin:kotlin-stdlib"
    compileOnly 'me.clip:placeholderapi:2.11.6'
    implementation "com.tcoded:FoliaLib:0.3.4"
    implementation("org.bstats:bstats-bukkit:3.0.2")
    compileOnly("io.github.miniplaceholders:miniplaceholders-api:2.2.3")
    compileOnly("io.github.miniplaceholders:miniplaceholders-kotlin-ext:2.2.3")

}

shadowJar {
    relocate('org.bstats', 'me.zepsizola.zautobroadcast.bstats')
    relocate('com.tcoded', 'me.zepsizola.zautobroadcast.FoliaLib')
    archiveBaseName.set(projectName)
    archiveVersion.set(version)
    archiveClassifier.set('')
    //configurations = [project.configurations.runtimeClasspath]
}

build.dependsOn shadowJar

def targetJavaVersion = 17
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

compileKotlin {
    kotlinOptions {
        jvmTarget = "${targetJavaVersion}"
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'

    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release.set(targetJavaVersion)
    }
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}