vimrc.before

" Before initialization

function! BundleExists(section, bundle)
	return (index(g:use_bundles[a:section], a:bundle) >= 0)
endfunction

function! AddBundle(section, bundle)
	if index(g:use_bundles[a:section], a:bundle) < 0
		call add(g:use_bundles[a:section], a:bundle)
	endif
endfunction

function! RemoveBundle(section, bundle)
	if index(g:use_bundles[a:section], a:bundle) >= 0
		call remove(g:use_bundles[a:section], index(g:use_bundles[a:section], a:bundle))
	endif
endfunction

if exists("g:hardcore_mode_with_arrow_keys") && !exists("g:hardcore_mode")
	let g:hardcore_mode = 1
endif

let g:use_bundles = {
			\ "apperances": ["common", "airline", "numbers", "indentline"],
			\ "languages": ["common", "ruby", "javascript", "textobjects", "html/css", "other"]
			\}

if !exists("g:hardcore_mode")
	let g:use_bundles.autocomplete = ["common", "youcompleteme"]
	let g:use_bundles.tools = ["common", "tagbar", "nerdtree", "commenter", "git", "undotree", "search"]
else
	if exists("g:use_arrow_keys")
		unlet g:use_arrow_keys
	endif

	if exists("g:use_copy_cut_paste_keys")
		unlet g:use_copy_cut_paste_keys
	endif

	let g:use_bundles.tools = ["common"]
	let g:use_bundles.autocomplete = []
endif