build.gradle

plugins {
    //support Idea IDE
    id 'idea'
    id "io.spring.dependency-management" version "1.0.9.RELEASE"
    // Build uber-jar
    id 'com.github.johnrengelman.shadow' version '5.2.0' apply false
}

idea {
    project {
        languageLevel = 13
    }
    module {
        downloadJavadoc = true
        downloadSources = true
    }
}

allprojects {
    group "ru.otus"

    repositories {
        mavenCentral()
    }

    apply plugin: "io.spring.dependency-management"
    dependencyManagement {
        dependencies {
            imports {
                mavenBom("org.springframework.boot:spring-boot-dependencies:2.2.6.RELEASE")
            }
            dependency("com.google.guava:guava:${Versions.guava}")
            dependency("org.testcontainers:junit-jupiter:${Versions.testcontainers}")
            dependency("com.google.code.gson:gson:${Versions.gson}")
            dependency("org.glassfish:javax.json:${Versions.glassfishJson}")
        }
    }

    configurations.all {
        resolutionStrategy {
            failOnVersionConflict()
        }

    }
}

//print versions from BOM
task managedVersions {
    doLast {
        dependencyManagement.managedVersions.each {
            println it
        }
    }
}