configure.in

dnl Process this file with autoconf to produce a configure script.

AC_INIT(configure.in)
AM_INIT_AUTOMAKE(xournal, 0.4.7)
AC_CONFIG_HEADERS(config.h)
AM_MAINTAINER_MODE

AC_ISC_POSIX
AC_PROG_CC
AC_PROG_RANLIB
AM_PROG_AR
AC_HEADER_STDC

LDFLAGS="$LDFLAGS -lz -lm"

pkg_modules="gtk+-2.0 >= 2.10.0 libgnomecanvas-2.0 >= 2.4.0 poppler-glib >= 0.5.4 pangoft2 >= 1.0"
unix_pkg_modules="gmodule-export-2.0 $pkg_modules"
win32_pkg_modules="$pkg_modules"


dnl detect Windows environment...
AC_CANONICAL_HOST
AC_MSG_CHECKING([for Windows environment])
case "$host" in
 *-*-mingw*)
   os_win32=yes;;
 *)
   os_win32=no;;
esac
AC_MSG_RESULT([$os_win32])
AM_CONDITIONAL(WIN32, test "$os_win32" = "yes")

AM_COND_IF([WIN32],
  [PKG_CHECK_MODULES(PACKAGE, [$win32_pkg_modules])],
  [PKG_CHECK_MODULES(PACKAGE, [$unix_pkg_modules])]
  )

AC_SUBST(PACKAGE_CFLAGS)
AC_SUBST(PACKAGE_LIBS)

GETTEXT_PACKAGE=xournal
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])

dnl Add the languages which your application supports here.
ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
AM_GLIB_GNU_GETTEXT

AC_OUTPUT([
Makefile
src/Makefile
src/ttsubset/Makefile
po/Makefile.in
])