build.gradle

plugins {
    id 'java-library'
    id 'maven-publish'
//     id 'signing'
}

tasks.register('tablesZip', Zip) {
    from 'src/main/dist/'
    include 'org/mwhapples/jlouis/tables/*'
    archiveClassifier = 'tables'
}


group = 'org.bitbucket.mwhapples'
//  archivesBaseName = 'jlouis'
version = '1.0.5'

java {
    withJavadocJar()
    withSourcesJar()
}

compileJava {
    options.release = 8
}

test {
    useTestNG()
    systemProperty("jlouis.test.data.path", layout.projectDirectory.dir("src/main/dist/org/mwhapples/jlouis/tables").asFile.absolutePath)
}

publishing {
    publications
            {
                mavenJava(MavenPublication)
                        {
                            from components.java
                            artifact source: tablesZip, extension: 'zip'
                            afterEvaluate {
                                artifactId = 'jlouis'
                            }
//	suppressAllPomMetadataWarnings ()
                            versionMapping
                                    {
                                        usage('java-api')
                                                {
                                                    fromResolutionOf('runtimeClasspath')
                                                }
                                        usage('java-runtime')
                                                {
                                                    fromResolutionResult()
                                                }

                                    }
                            pom
                                    {
                                        name = 'jlouis'
                                        description = 'Java bindings for LibLouis Braille translator'
                                        url = 'https://nexus.aphtech.org/repository/aphtech-mrepo/'

                                        properties = [
                                                myProp          : "value",
                                                "prop.with.dots": "anotherValue"
                                        ]

                                        licenses
                                                {
                                                    license
                                                            {
                                                                name = 'The Apache License, Version 2.0'
                                                                url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                                                            }
                                                }

                                        developers
                                                {
                                                    developer
                                                            {
                                                                id = 'mwhapples'
                                                                name = 'Michael Whapples'
                                                                email = 'mwhapples@aim.com'
                                                            }
                                                }

                                        scm
                                                {
                                                    connection = 'scm:hg:http://bitbucket.org/mwhapples/jlouis'
                                                    developerConnection = 'scm:hg:https://bitbucket.org/mwhapples/jlouis'
                                                    url = 'http://bitbucket.org/mwhapples/jlouis'
                                                }
                                    }
                        }
            }


    repositories
            {
                maven
                        {
//mavenCentral ()
//mavenLocal()
                            name = 'aphtech-mrepo'
                            url = 'https://nexus.aphtech.org/repository/aphtech-mrepo/'
                            credentials {
                                username = System.getenv('MAVEN_REPO_USER')
                                password = System.getenv('MAVEN_REPO_PASS')
                            }
                        }
            }
} //publishing

//signing {
//    sign publishing.publications.mavenJava
//}

javadoc {
    if (JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}

repositories {
    mavenCentral()
}


dependencies {
    //Use maven version ranges as ant-like ranges are incompatible with everything else
    implementation group: 'net.java.dev.jna', name: 'jna', version: '5.14.0'
    implementation group: 'com.google.guava', name: 'guava', version: '[33.0.0-jre,)'
    testImplementation group: 'javax.xml.bind', name: 'jaxb-api', version: '[2.3.1,)'
    testRuntimeOnly group: 'org.glassfish.jaxb', name: 'jaxb-runtime', version: '[2.3.1,)'

    // block slf4j 1.8 due to jigsaw rewrite and logback not being fully updated -Leon April 27, 2017
    // original version range '[1.7,)'
    implementation group: 'org.slf4j', name: 'slf4j-api', version: '1.7.25'
    runtimeOnly group: 'ch.qos.logback', name: 'logback-classic', version: '[1.1,)'
    testImplementation group: 'org.testng', name: 'testng', version: '7.7.0'
    testImplementation group: 'org.assertj', name: 'assertj-core', version: '[3,)'
}


artifacts {
    archives tablesZip
}

wrapper {
    gradleVersion = '8.5'
}