build.gradle

def computeVersionName() {
  def lastGitTag = "git describe --tags HEAD".execute().text
  def tagMatcher = lastGitTag =~ /^v(.*)/
  if (tagMatcher) {
    lastGitTag = tagMatcher[0][1]
  } else {
    return "0.0.1-SNAPSHOT"
  }
  def snapshotMatcher = lastGitTag =~ /^[^-]*-[^-]*-g/
  if (snapshotMatcher) {
    "${lastGitTag}-SNAPSHOT"
  } else {
    lastGitTag
  }
}

def computeVersion() {
  def lastVersion = "git describe --tags --abbrev=0".execute().text
  def matcher = lastVersion =~ /^v(.*)/
  lastVersion = matcher ? matcher[0][1] : "0.0.0"
  def parts = lastVersion.split("\\.", 3)
  def versionName = computeVersionName()
  if (versionName.endsWith('-SNAPSHOT')) {
    parts[2] = Integer.toString(parts[2].toInteger() + 1)
    parts[0] + '.' + parts[1] + '.' + parts[2] + '-SNAPSHOT'
  } else {
    lastVersion
  }
}

ext {
  compileSdkVersion = 17
  buildToolsVersion = '21.1.2'

  versionName = computeVersionName()
  version = computeVersion()
  println 'versionName: ' + versionName
  println 'version: ' + version
}

task wrapper(type: Wrapper) {
  gradleVersion = '1.10'
}

subprojects {

  buildscript {
    repositories {
      mavenCentral()
      maven {
        name 'Sonatype Snapshots'
        url 'https://oss.sonatype.org/content/repositories/snapshots/'
      }
    }
    dependencies {
      classpath 'com.android.tools.build:gradle:1.0.1'
      classpath 'com.github.jcandksolutions.gradle:android-unit-test:2.1.1'
      classpath 'com.github.dcendents:android-maven-plugin:1.0'
    }
  }

  repositories {
    mavenCentral()
  }

  tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
  }

}