build.gradle.kts

import org.jetbrains.changelog.Changelog
import org.jetbrains.changelog.markdownToHTML

fun properties(key: String) = providers.gradleProperty(key)
fun environment(key: String) = providers.environmentVariable(key)

plugins {
    id("java") // Java support
    id("org.jetbrains.intellij") version "1.16.0"
    id("org.jetbrains.changelog") version "2.2.0"
}

group = properties("pluginGroup").get()
version = properties("pluginVersion").get()

repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    implementation("org.openjdk.nashorn:nashorn-core:15.4")
//    testImplementation("org.junit.jupiter:junit-jupiter-api:5.10.1")
//    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:5.10.1")
}

// See https://github.com/JetBrains/gradle-intellij-plugin/
intellij {
    pluginName = properties("pluginName")
    version = properties("platformVersion")
    type = properties("platformType")
    updateSinceUntilBuild = false
    plugins = properties("platformPlugins").get().split(',').map(String::trim).filter(String::isNotEmpty)
}


changelog {
    groups.empty()
    repositoryUrl = properties("pluginRepositoryUrl")
}

tasks {

    buildSearchableOptions {
        enabled = false
    }

    compileJava {
        options.encoding = "UTF-8"
        options.compilerArgs = listOf("-Xlint:unchecked", "-Xlint:deprecation")
    }

    wrapper {
        gradleVersion = properties("gradleVersion").get()
    }

    patchPluginXml {
        version = properties("pluginVersion")
        sinceBuild = properties("pluginSinceBuild")
        untilBuild = properties("pluginUntilBuild")

//         Extract the <!-- Plugin description --> section from README.md and provide for the plugin's manifest
//        pluginDescription = providers.fileContents(layout.projectDirectory.file("README.md")).asText.map {
////            val start = "<!-- Plugin description -->"
////            val end = "<!-- Plugin description end -->"
//
//            with (it.lines()) {
////                if (!containsAll(listOf(start, end))) {
////                    throw GradleException("Plugin description section not found in README.md:\n$start ... $end")
////                }
////                subList(indexOf(start) + 1, indexOf(end)).joinToString("\n").let(::markdownToHTML)
//                joinToString("\n").let(::markdownToHTML)
//            }
//        }
        pluginDescription = providers.fileContents(layout.projectDirectory.file("DESCRIPTION.md")).asText.get().let(::markdownToHTML)

        val changelog = project.changelog // local variable for configuration cache compatibility
        // Get the latest available change notes from the changelog file
        changeNotes = properties("pluginVersion").map { pluginVersion ->
            with(changelog) {
                renderItem(
                        (getOrNull(pluginVersion) ?: getUnreleased())
                                .withHeader(false)
                                .withEmptySections(false),
                        Changelog.OutputType.HTML,
                )
            }
        }
    }

    signPlugin {
        certificateChain = environment("CERTIFICATE_CHAIN")
        privateKey = environment("PRIVATE_KEY")
        password = environment("PRIVATE_KEY_PASSWORD")
    }

    publishPlugin {
        dependsOn("patchChangelog")
        token = environment("PUBLISH_TOKEN")
        // The pluginVersion is based on the SemVer (https://semver.org) and supports pre-release labels, like 2.1.7-alpha.3
        // Specify pre-release label to publish the plugin in a custom Release Channel automatically. Read more:
        // https://plugins.jetbrains.com/docs/intellij/deployment.html#specifying-a-release-channel
        channels = properties("pluginVersion").map { listOf(it.split('-').getOrElse(1) { "default" }.split('.').first()) }
    }
}