diff --git a/code/__DEFINES/subsystems.dm b/code/__DEFINES/subsystems.dm
index 3c2527136ed6..662bcb458c55 100644
--- a/code/__DEFINES/subsystems.dm
+++ b/code/__DEFINES/subsystems.dm
@@ -113,7 +113,8 @@
 #define SS_INIT_INPUT   85
 #define SS_INIT_FAIL_TO_TOPIC 84
 #define SS_INIT_TOPIC 83
-#define SS_INIT_RUST    26
+#define SS_INIT_RUST    30
+#define SS_INIT_INFLUXDRIVER 28
 #define SS_INIT_SUPPLY_SHUTTLE  25
 #define SS_INIT_GARBAGE 24
 #define SS_INIT_EVENTS 23.5
@@ -133,7 +134,9 @@
 #define SS_INIT_MORE_INIT   16
 #define SS_INIT_AIR 15
 #define SS_INIT_TELEPORTER  13
-#define SS_INIT_LIGHTING 12
+#define SS_INIT_INFLUXMCSTATS 12
+#define SS_INIT_INFLUXSTATS 11
+#define SS_INIT_LIGHTING 10
 #define SS_INIT_DEFCON 9
 #define SS_INIT_LAW 6
 #define SS_INIT_FZ_TRANSITIONS 5
@@ -212,12 +215,15 @@
 #define SS_PRIORITY_UNSPECIFIED 30
 #define SS_PRIORITY_PROCESS 25
 #define SS_PRIORITY_SOUNDSCAPE    24
+#define SS_PRIORITY_INFLUXDRIVER  23
 #define SS_PRIORITY_PAGER_STATUS   22
 #define SS_PRIORITY_LIGHTING    20
 #define SS_PRIORITY_TRACKING    19
+#define SS_PRIORITY_DATABASE    15
 #define SS_PRIORITY_MINIMAPS 11
 #define SS_PRIORITY_PING    10
-#define SS_PRIORITY_DATABASE    15
+#define SS_PRIORITY_INFLUXMCSTATS 9
+#define SS_PRIORITY_INFLUXSTATS 8
 #define SS_PRIORITY_PLAYTIME    5
 #define SS_PRIORITY_PERFLOGGING 4
 #define SS_PRIORITY_CORPSESPAWNER  3
diff --git a/code/__HELPERS/text.dm b/code/__HELPERS/text.dm
index 83da41b515a6..d4d9eb320633 100644
--- a/code/__HELPERS/text.dm
+++ b/code/__HELPERS/text.dm
@@ -164,6 +164,11 @@
 		t = "0[t]"
 	return t
 
+/proc/pad_trailing(text, padding, size)
+	while (length(text) < size)
+		text = "[text][padding]"
+	return text
+
 //Adds 'u' number of spaces ahead of the text 't'
 /proc/add_lspace(t, u)
 	while(length(t) < u)
diff --git a/code/_globalvars/global_lists.dm b/code/_globalvars/global_lists.dm
index f0279907f635..586d5e71a92d 100644
--- a/code/_globalvars/global_lists.dm
+++ b/code/_globalvars/global_lists.dm
@@ -10,6 +10,7 @@ GLOBAL_LIST_EMPTY(GeneralFaxes) //Inter-machine faxes
 GLOBAL_LIST_EMPTY(fax_contents) //List of fax contents to maintain it even if source paper is deleted
 
 GLOBAL_LIST_EMPTY(failed_fultons) //A list of fultoned items which weren't collected and fell back down
+GLOBAL_LIST_EMPTY(larva_burst_by_hive)
 
 GLOBAL_LIST_INIT_TYPED(custom_huds_list, /datum/custom_hud, setup_all_huds())
 GLOBAL_LIST_INIT_TYPED(custom_human_huds, /datum/custom_hud, setup_human_huds())
diff --git a/code/controllers/configuration/entries/general.dm b/code/controllers/configuration/entries/general.dm
index ba3f0b2609b6..751a75935fc6 100644
--- a/code/controllers/configuration/entries/general.dm
+++ b/code/controllers/configuration/entries/general.dm
@@ -529,6 +529,25 @@ This maintains a list of ip addresses that are able to bypass topic filtering.
 
 /datum/config_entry/string/round_results_webhook_url
 
+/// InfluxDB v2 Host to connect to for sending statistics (over HTTP API)
+/datum/config_entry/string/influxdb_host
+/// InfluxDB v2 Bucket to send staistics to
+/datum/config_entry/string/influxdb_bucket
+/// InfluxDB v2 Organization to access buckets of
+/datum/config_entry/string/influxdb_org
+/// InfluxDB v2 API Token to access the organization and bucket
+/datum/config_entry/string/influxdb_token
+
+/// How often to snapshot general game statistics to influxdb driver
+/datum/config_entry/number/influxdb_stats_period
+	config_entry_value = 30
+/// How often to snapshot MC statistics
+/datum/config_entry/number/influxdb_mcstats_period
+	config_entry_value = 60
+/// How often to send queued influxdb statistics
+/datum/config_entry/number/influxdb_send_period
+	config_entry_value = 10
+
 /// logs all timers in buckets on automatic bucket reset (Useful for timer debugging)
 /datum/config_entry/flag/log_timers_on_bucket_reset
 
diff --git a/code/controllers/subsystem/influxdriver.dm b/code/controllers/subsystem/influxdriver.dm
new file mode 100644
index 000000000000..7e5289dfc518
--- /dev/null
+++ b/code/controllers/subsystem/influxdriver.dm
@@ -0,0 +1,132 @@
+/// Sends collected statistics to an influxdb v2 backend periodically
+SUBSYSTEM_DEF(influxdriver)
+	name       = "InfluxDB Driver"
+	wait       = 10 SECONDS
+	init_order = SS_INIT_INFLUXDRIVER
+	priority   = SS_PRIORITY_INFLUXDRIVER
+	runlevels  = RUNLEVELS_DEFAULT|RUNLEVEL_LOBBY
+
+	var/list/send_queue = list()
+
+	/// Maximum amount of metric lines to send at most in one request
+	/// This is neccessary because sending a lot of metrics can get expensive
+	/// and drive the subsystem into overtime, but we can't split the work as it'd be even less efficient
+	var/max_batch = 150
+
+	/// Last timestamp in microseconds
+	var/timestamp_cache_realtime
+	/// Last tick time the timestamp was taken at
+	var/timestamp_cache_worldtime
+
+/datum/controller/subsystem/influxdriver/Initialize()
+	var/period = text2num(CONFIG_GET(number/influxdb_send_period))
+	if(isnum(period))
+		wait = max(period * (1 SECONDS), 2 SECONDS)
+	return SS_INIT_SUCCESS
+
+/datum/controller/subsystem/influxdriver/stat_entry(msg)
+	msg += "period=[wait] queue=[length(send_queue)]"
+	return ..()
+
+/datum/controller/subsystem/influxdriver/proc/unix_timestamp_string() // pending change to rust-g
+	return RUSTG_CALL(RUST_G, "unix_timestamp")()
+
+/datum/controller/subsystem/influxdriver/proc/update_timestamp()
+	PRIVATE_PROC(TRUE)
+	// We make only one request to rustg per game tick, so we cache the result per world.time
+	var/whole_timestamp = unix_timestamp_string() // Format "7129739474.4758981" - timestamp with up to 7-8 decimals
+	var/list/tsparts = splittext(whole_timestamp, ".")
+	var/fractional = copytext(pad_trailing(tsparts[2], "0", 6), 1, 7) // in microseconds
+	timestamp_cache_worldtime = world.time
+	timestamp_cache_realtime = "[tsparts[1]][fractional]"
+
+/datum/controller/subsystem/influxdriver/fire(resumed)
+	var/maxlen = min(length(send_queue)+1, max_batch)
+	var/list/queue = send_queue.Copy(1, maxlen)
+	send_queue.Cut(1, maxlen)
+	flush_queue(queue)
+
+/// Flushes measurements batch to InfluxDB backend
+/datum/controller/subsystem/influxdriver/proc/flush_queue(list/queue)
+	PRIVATE_PROC(TRUE)
+
+	var/host   = CONFIG_GET(string/influxdb_host)
+	var/token  = CONFIG_GET(string/influxdb_token)
+	var/bucket = CONFIG_GET(string/influxdb_bucket)
+	var/org    = CONFIG_GET(string/influxdb_org)
+
+	if(!host || !token || !bucket || !org)
+		can_fire = FALSE
+		return
+
+	if(!length(queue))
+		return // Nothing to do
+
+	var/url = "[host]/api/v2/write?org=[org]&bucket=[bucket]&precision=us" // microseconds
+	var/list/headers = list()
+	headers["Authorization"] = "Token [token]"
+	headers["Content-Type"] = "text/plain; charset=utf-8"
+	headers["Accept"] = "application/json"
+
+	var/datum/http_request/request = new
+	var/payload = ""
+	for(var/line in queue)
+		payload += "[line]\n"
+	request.prepare(RUSTG_HTTP_METHOD_POST, url, payload, headers)
+	request.begin_async()
+	// TODO possibly check back result of request later
+
+/// Enqueues sending to InfluxDB Backend selected measurement values - round_id and timestamp are filled in automatically
+/datum/controller/subsystem/influxdriver/proc/enqueue_stats(measurement, list/tags, list/fields)
+	. = FALSE
+	var/valid = FALSE
+	var/serialized = "[measurement],round_id=[GLOB.round_id]"
+	if(tags)
+		for(var/tag in tags)
+			var/serialized_tag = serialize_field(tag, tags[tag])
+			if(serialized_tag)
+				serialized += ",[serialized_tag]"
+	serialized += " "
+	var/comma = ""
+	for(var/field in fields)
+		var/serialized_field = serialize_field(field, fields[field])
+		if(serialized_field)
+			valid = TRUE
+			serialized += "[comma][serialized_field]"
+			comma = ","
+	if(!valid)
+		CRASH("Attempted to serialize to InfluxDB backend an invalid measurement (likely has no fields)")
+	if(timestamp_cache_worldtime != world.time)
+		update_timestamp()
+	serialized += " [timestamp_cache_realtime]"
+	send_queue += serialized
+	return TRUE
+
+/// Enqueues sending varied stats in a dumb and simpler format directly as: measurement count=
+/datum/controller/subsystem/influxdriver/proc/enqueue_stats_crude(measurement, value, field_name = "count")
+	. = FALSE
+	var/serialized_field = serialize_field(field_name, value)
+	if(!length(serialized_field))
+		return
+	if(timestamp_cache_worldtime != world.time)
+		update_timestamp()
+	var/serialized = "[measurement],round_id=[GLOB.round_id] [serialized_field] [timestamp_cache_realtime]"
+	send_queue += serialized
+	return TRUE
+
+/// Puts a single field or tag value into InfluxDB Line format
+/datum/controller/subsystem/influxdriver/proc/serialize_field(field, value)
+	var/static/regex/whitelistedCharacters = regex(@{"([^a-zA-Z0-9_]+)"}, "g")
+	var/sanitized_field = whitelistedCharacters.Replace("[field]", "")
+	if(!length(sanitized_field) || copytext(sanitized_field, 1, 2) == "_")
+		CRASH("Invalid tag/field for InfluxDB serialization: '[sanitized_field]' (original: '[field]')")
+	var/sanitized_value
+	if(isnum(value))
+		sanitized_value = value
+	else if(istext(value))
+		sanitized_value = whitelistedCharacters.Replace("[value]", "")
+		if(!length(sanitized_value) || copytext(sanitized_value, 1, 2) == "_")
+			CRASH("Invalid value for InfluxDB serialization: '[sanitized_value]' (original: '[value]')")
+	else
+		CRASH("Invalid value type passed for InfluxDB serialization: '[value]'")
+	return "[sanitized_field]=[sanitized_value]"
diff --git a/code/controllers/subsystem/influxmcstats.dm b/code/controllers/subsystem/influxmcstats.dm
new file mode 100644
index 000000000000..a1bf171d81a3
--- /dev/null
+++ b/code/controllers/subsystem/influxmcstats.dm
@@ -0,0 +1,47 @@
+SUBSYSTEM_DEF(influxmcstats)
+	name       = "InfluxDB MC Stats"
+	wait       = 60 SECONDS
+	priority   = SS_PRIORITY_INFLUXMCSTATS
+	init_order = SS_INIT_INFLUXMCSTATS
+	runlevels  = RUNLEVEL_LOBBY|RUNLEVELS_DEFAULT
+	flags      = SS_KEEP_TIMING
+	var/checkpoint = 0
+	var/list/subsystem_name_cache = list()
+
+/datum/controller/subsystem/influxmcstats/Initialize()
+	var/period = text2num(CONFIG_GET(number/influxdb_mcstats_period))
+	if(isnum(period))
+		wait = max(period * (1 SECONDS), 10 SECONDS)
+	return SS_INIT_SUCCESS
+
+/datum/controller/subsystem/influxmcstats/stat_entry(msg)
+	msg += "period=[wait] checkpoint=[checkpoint]"
+	return ..()
+
+/datum/controller/subsystem/influxmcstats/fire(resumed)
+	if(!SSinfluxdriver.can_fire)
+		can_fire = FALSE
+		return
+
+	var/list/data = list()
+	data["time_dilation_current"] = SStime_track.time_dilation_current
+	data["time_dilation_avg"] = SStime_track.time_dilation_avg
+	data["time_dilation_avg_slow"] = SStime_track.time_dilation_avg_slow
+	data["time_dilation_avg_fast"] = SStime_track.time_dilation_avg_fast
+	SSinfluxdriver.enqueue_stats("tidi", null, data)
+
+	SSinfluxdriver.enqueue_stats("cpu", null, list("cpu" = world.cpu, "map_cpu" = world.map_cpu))
+
+	var/static/regex/get_last_path_element = regex(@{"/([^/]+)$"})
+	checkpoint++
+	for(var/datum/controller/subsystem/SS in Master.subsystems)
+		if(!SS.can_fire)
+			continue
+		if(!subsystem_name_cache[SS.type])
+			get_last_path_element.Find("[SS.type]")
+			subsystem_name_cache[SS.type] = "SS[get_last_path_element.group[1]]"
+		var/SSname = subsystem_name_cache[SS.type]
+		if(!SSname)
+			stack_trace("Influx MC Stats couldnt name a subsystem, type=[SS.type]")
+			continue
+		SSinfluxdriver.enqueue_stats("sstimings", list("ss" = SSname), list("cost" = SS.cost, "tick_overrun" = SS.tick_overrun, "tick_usage" = SS.tick_usage, "wait" = SS.wait))
diff --git a/code/controllers/subsystem/influxstats.dm b/code/controllers/subsystem/influxstats.dm
new file mode 100644
index 000000000000..01015b83191d
--- /dev/null
+++ b/code/controllers/subsystem/influxstats.dm
@@ -0,0 +1,156 @@
+/// Sends generic round running statistics to the InfluxDB backend
+SUBSYSTEM_DEF(influxstats)
+	name       = "InfluxDB Game Stats"
+	wait       = 60 SECONDS
+	priority   = SS_PRIORITY_INFLUXSTATS
+	init_order = SS_INIT_INFLUXSTATS
+	runlevels  = RUNLEVEL_LOBBY|RUNLEVELS_DEFAULT
+	flags      = SS_KEEP_TIMING
+
+	var/checkpoint = 0 //! Counter of data snapshots sent
+	var/step = 1 //! Current task in progress, for pausing/resuming
+
+/datum/controller/subsystem/influxstats/Initialize()
+	var/period = text2num(CONFIG_GET(number/influxdb_stats_period))
+	if(isnum(period))
+		wait = max(period * (1 SECONDS), 10 SECONDS)
+	return SS_INIT_SUCCESS
+
+/datum/controller/subsystem/influxstats/stat_entry(msg)
+	msg += "period=[wait] checkpoint=[checkpoint] step=[step]"
+	return ..()
+
+/datum/controller/subsystem/influxstats/fire(resumed)
+	if(!SSinfluxdriver.can_fire)
+		can_fire = FALSE
+		return
+
+	checkpoint++
+	while(step < 5) // Yes, you could make one SS per stats category, and have proper scheduling and variable periods,  but...
+		switch(step++)
+			if(1) // Connected players statistics
+				run_player_statistics()
+			if(2) // Job occupations
+				if(SSticker.current_state == GAME_STATE_PLAYING)
+					run_job_statistics()
+			if(3) // Round-wide gameplay statistics held in entity
+				if(SSticker.current_state == GAME_STATE_PLAYING)
+					run_round_statistics()
+			if(4) // Handpicked Round-wide gameplay statistics
+				if(SSticker.current_state == GAME_STATE_PLAYING)
+					run_special_round_statistics()
+		if(MC_TICK_CHECK)
+			return
+
+	step = 1
+
+/datum/controller/subsystem/influxstats/proc/flatten_entity_list(list/data)
+	var/list/result = list()
+	for(var/key in data)
+		var/datum/entity/statistic/entry = data[key]
+		result[key] = entry.value
+	return result
+
+/datum/controller/subsystem/influxstats/proc/run_special_round_statistics()
+	for(var/hive_tag in GLOB.hive_datum)
+		var/datum/hive_status/hive = GLOB.hive_datum[hive_tag]
+		SSinfluxdriver.enqueue_stats("pooled_larva", list("hive" = hive.reporting_id), list("count" = hive.stored_larva))
+		var/burst_larvas = GLOB.larva_burst_by_hive[hive] || 0
+		SSinfluxdriver.enqueue_stats("burst_larva", list("hive" = hive.reporting_id), list("count" = burst_larvas))
+
+/datum/controller/subsystem/influxstats/proc/run_round_statistics()
+	var/datum/entity/statistic/round/stats = SSticker?.mode?.round_stats
+	if(!stats)
+		return // Sadge
+
+	SSinfluxdriver.enqueue_stats_crude("chestbursts", stats.total_larva_burst)
+	SSinfluxdriver.enqueue_stats_crude("hugged", stats.total_huggers_applied)
+	SSinfluxdriver.enqueue_stats_crude("friendlyfire", stats.total_friendly_fire_instances)
+
+	var/list/participants = flatten_entity_list(stats.participants)
+	if(length(participants))
+		SSinfluxdriver.enqueue_stats("participants", list(), participants)
+
+	var/list/total_deaths = flatten_entity_list(stats.total_deaths)
+	if(length(total_deaths))
+		SSinfluxdriver.enqueue_stats("deaths", list(), total_deaths)
+
+	SSinfluxdriver.enqueue_stats("shots", list(),
+		list("fired" = stats.total_projectiles_fired, "hits" = stats.total_projectiles_hit,
+		"hits_human" = stats.total_projectiles_hit_human, "hits_xeno" = stats.total_projectiles_hit_xeno)
+	)
+
+/datum/controller/subsystem/influxstats/proc/run_player_statistics()
+	var/staff_count = 0
+	var/mentor_count = 0
+	for(var/client/client in GLOB.admins)
+		if(CLIENT_IS_STAFF(client))
+			staff_count++
+		else if(CLIENT_HAS_RIGHTS(client, R_MENTOR))
+			mentor_count++
+	SSinfluxdriver.enqueue_stats("online", null, list("count" = length(GLOB.clients)))
+
+	var/list/adm = get_admin_counts()
+	var/present_admins = length(adm["present"])
+	var/afk_admins = length(adm["afk"])
+	SSinfluxdriver.enqueue_stats("online_staff", null, list("total" = staff_count, "mentors" = mentor_count, "present" = present_admins, "afk" = afk_admins))
+
+	// Grab ahelp stats
+	SSinfluxdriver.enqueue_stats("tickets", null, list(
+		"open" = length(GLOB.ahelp_tickets.active_tickets),
+		"closed" = length(GLOB.ahelp_tickets.closed_tickets),
+		"resolved" = length(GLOB.ahelp_tickets.resolved_tickets),
+	))
+
+/datum/controller/subsystem/influxstats/proc/run_job_statistics()
+	var/list/team_job_stats = list()
+	var/list/squad_job_stats = ROLES_SQUAD_ALL.Copy()
+	for(var/squad in squad_job_stats)
+		squad_job_stats[squad] = list()
+
+	for(var/client/client in GLOB.clients)
+		var/team
+		var/mob/mob = client.mob
+		if(!mob || mob.statistic_exempt)
+			continue
+		var/area/area = get_area(mob)
+		if(!area || area.statistic_exempt)
+			continue
+		var/job = mob.job
+		if(isobserver(mob) || mob.stat == DEAD)
+			job = JOB_OBSERVER
+			team = "observers"
+		else if(!job)
+			continue
+		else if(mob.faction == FACTION_MARINE || mob.faction == FACTION_SURVIVOR)
+			team = "humans"
+			var/mob/living/carbon/human/employed_human = mob
+			if(istype(employed_human))
+				var/squad = employed_human.assigned_squad?.name
+				if(squad in squad_job_stats)
+					squad_job_stats[squad][job] = (squad_job_stats[squad][job] || 0) + 1
+					continue // Defer to squad stats instead
+			// else: So you're in the USCM and have a job but aren't an human? Tell me more Dr Jones...
+		else if(ishuman(mob))
+			team = "humans_others"
+		else if(isxeno(mob))
+			var/mob/living/xeno_enabled_mob = mob
+			var/datum/hive_status/hive = GLOB.hive_datum[xeno_enabled_mob.hivenumber]
+			if(!hive)
+				team = "xenos_others"
+			else
+				team = "xenos_[hive.reporting_id]"
+		else
+			team = "others"
+		LAZYINITLIST(team_job_stats[team])
+		if(!team_job_stats[team][job])
+			team_job_stats[team][job] = 0
+		team_job_stats[team][job] += 1
+
+	for(var/team in team_job_stats)
+		for(var/job in team_job_stats[team])
+			SSinfluxdriver.enqueue_stats("job_stats", list("team" = team, "job" = job), list("count" = team_job_stats[team][job]))
+
+	for(var/squad in squad_job_stats)
+		for(var/job in squad_job_stats[squad])
+			SSinfluxdriver.enqueue_stats("job_stats", list("team" = "humans", "job" = job, "squad" = squad), list("count" = squad_job_stats[squad][job]))
diff --git a/code/datums/statistics/entities/panel_stats.dm b/code/datums/statistics/entities/panel_stats.dm
index 44f95f2d91d9..d6e391e1731f 100644
--- a/code/datums/statistics/entities/panel_stats.dm
+++ b/code/datums/statistics/entities/panel_stats.dm
@@ -741,7 +741,6 @@
 		"total_projectiles_hit_xeno" = total_projectiles_hit_xeno,
 		"total_slashes" = total_slashes,
 		"total_friendly_fire_instances" = total_friendly_fire_instances,
-		"total_friendly_fire_kills" = total_friendly_fire_kills,
 		"total_huggers_applied" = total_huggers_applied,
 		"total_larva_burst" = total_larva_burst,
 		"participants" = participants_list,
diff --git a/code/datums/statistics/entities/round_stats.dm b/code/datums/statistics/entities/round_stats.dm
index ec6aa4ac5bdc..0e1fb6e387db 100644
--- a/code/datums/statistics/entities/round_stats.dm
+++ b/code/datums/statistics/entities/round_stats.dm
@@ -20,7 +20,6 @@
 	var/total_projectiles_hit_human = 0
 	var/total_projectiles_hit_xeno = 0
 	var/total_friendly_fire_instances = 0
-	var/total_friendly_fire_kills = 0
 	var/total_slashes = 0
 
 	// untracked data
@@ -360,7 +359,6 @@
 
 	stats += "Total shots fired: [total_projectiles_fired]\n"
 	stats += "Total friendly fire instances: [total_friendly_fire_instances]\n"
-	stats += "Total friendly fire kills: [total_friendly_fire_kills]\n"
 
 	stats += "Marines remaining: [end_of_round_marines]\n"
 	stats += "Xenos remaining: [end_of_round_xenos]\n"
diff --git a/code/modules/mob/living/carbon/xenomorph/Embryo.dm b/code/modules/mob/living/carbon/xenomorph/Embryo.dm
index e03f225ccade..a470c3259a8f 100644
--- a/code/modules/mob/living/carbon/xenomorph/Embryo.dm
+++ b/code/modules/mob/living/carbon/xenomorph/Embryo.dm
@@ -255,6 +255,7 @@
 
 		if(round_statistics)
 			round_statistics.total_larva_burst++
+		GLOB.larva_burst_by_hive[hive] = (GLOB.larva_burst_by_hive[hive] || 0) + 1
 		burstcount++
 
 		if(!L.ckey && L.burrowable && loc && is_ground_level(loc.z) && (locate(/obj/structure/bed/nest) in loc) && hive.living_xeno_queen && hive.living_xeno_queen.z == loc.z)
diff --git a/code/modules/mob/living/carbon/xenomorph/xeno_defines.dm b/code/modules/mob/living/carbon/xenomorph/xeno_defines.dm
index b5431720e14a..1e991dc62e7c 100644
--- a/code/modules/mob/living/carbon/xenomorph/xeno_defines.dm
+++ b/code/modules/mob/living/carbon/xenomorph/xeno_defines.dm
@@ -239,6 +239,9 @@
 	// Used for the faction of the xenomorph. Not recommended to modify.
 	var/internal_faction
 
+	/// Short Hive ID as string used in stats reporting
+	var/reporting_id = "normal"
+
 	var/hivenumber = XENO_HIVE_NORMAL
 	var/mob/living/carbon/xenomorph/queen/living_xeno_queen
 	var/egg_planting_range = 15
@@ -1033,6 +1036,7 @@
 
 /datum/hive_status/corrupted
 	name = "Corrupted Hive"
+	reporting_id = "corrupted"
 	hivenumber = XENO_HIVE_CORRUPTED
 	prefix = "Corrupted "
 	color = "#80ff80"
@@ -1056,6 +1060,7 @@
 
 /datum/hive_status/alpha
 	name = "Alpha Hive"
+	reporting_id = "alpha"
 	hivenumber = XENO_HIVE_ALPHA
 	prefix = "Alpha "
 	color = "#ff4040"
@@ -1066,6 +1071,7 @@
 
 /datum/hive_status/bravo
 	name = "Bravo Hive"
+	reporting_id = "bravo"
 	hivenumber = XENO_HIVE_BRAVO
 	prefix = "Bravo "
 	color = "#ffff80"
@@ -1076,6 +1082,7 @@
 
 /datum/hive_status/charlie
 	name = "Charlie Hive"
+	reporting_id = "charlie"
 	hivenumber = XENO_HIVE_CHARLIE
 	prefix = "Charlie "
 	color = "#bb40ff"
@@ -1086,6 +1093,7 @@
 
 /datum/hive_status/delta
 	name = "Delta Hive"
+	reporting_id = "delta"
 	hivenumber = XENO_HIVE_DELTA
 	prefix = "Delta "
 	color = "#8080ff"
@@ -1096,6 +1104,7 @@
 
 /datum/hive_status/feral
 	name = "Feral Hive"
+	reporting_id = "feral"
 	hivenumber = XENO_HIVE_FERAL
 	prefix = "Feral "
 	color = "#828296"
@@ -1111,6 +1120,7 @@
 
 /datum/hive_status/forsaken
 	name = "Forsaken Hive"
+	reporting_id = "forsaken"
 	hivenumber = XENO_HIVE_FORSAKEN
 	prefix = "Forsaken "
 	color = "#cc8ec4"
@@ -1129,6 +1139,7 @@
 
 /datum/hive_status/yautja
 	name = "Hellhound Pack"
+	reporting_id = "hellhounds"
 	hivenumber = XENO_HIVE_YAUTJA
 	internal_faction = FACTION_YAUTJA
 
@@ -1145,6 +1156,7 @@
 
 /datum/hive_status/mutated
 	name = "Mutated Hive"
+	reporting_id = "mutated"
 	hivenumber = XENO_HIVE_MUTATED
 	prefix = "Mutated "
 	color = "#6abd99"
@@ -1155,6 +1167,7 @@
 
 /datum/hive_status/corrupted/tamed
 	name = "Tamed Hive"
+	reporting_id = "tamed"
 	hivenumber = XENO_HIVE_TAMED
 	prefix = "Tamed "
 	color = "#80ff80"
diff --git a/colonialmarines.dme b/colonialmarines.dme
index 54bb68ff5275..e5b64d86d023 100644
--- a/colonialmarines.dme
+++ b/colonialmarines.dme
@@ -239,6 +239,9 @@
 #include "code\controllers\subsystem\htmlui.dm"
 #include "code\controllers\subsystem\human.dm"
 #include "code\controllers\subsystem\inactivity.dm"
+#include "code\controllers\subsystem\influxdriver.dm"
+#include "code\controllers\subsystem\influxmcstats.dm"
+#include "code\controllers\subsystem\influxstats.dm"
 #include "code\controllers\subsystem\input.dm"
 #include "code\controllers\subsystem\interior.dm"
 #include "code\controllers\subsystem\item_cleanup.dm"
diff --git a/nano/templates/cm_stat_panel.tmpl b/nano/templates/cm_stat_panel.tmpl
index 97feebde5971..26de08f17054 100644
--- a/nano/templates/cm_stat_panel.tmpl
+++ b/nano/templates/cm_stat_panel.tmpl
@@ -159,9 +159,6 @@ Used in: /code/datums/statistics/entities/player_entity.dm
                 <div class="itemLabelClear">
                     Total Friendly Fire Kills:
                 </div>
-                <div class="itemContentSmallRight">
-                    {{:data.round.total_friendly_fire_kills}}
-                </div>
                 <div class="itemLabelClear">
                     Total Slashes:
                 </div>