forked from vangelisv/thea
-
Notifications
You must be signed in to change notification settings - Fork 3
/
owl2_manchester_parser.pl
1081 lines (865 loc) · 37.9 KB
/
owl2_manchester_parser.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/* -*- Mode: Prolog -*- */
:- module(owl2_manchester_parser,
[
owl_parse_manchester_syntax_file/1,
owl_parse_manchester_syntax_file/2,
owl_parse_manchester_expression/2,
owl_parse_manchester_frame/2,
owl_parse_manchester_file_axioms/3 % File, Axioms, Options
]).
:- use_module(library(dcg/basics)).
:- use_module(library(lists)).
:- use_module(library(apply)).
:- use_module(library(error)).
:- use_module(library(debug)).
:- use_module(owl2_model,[assert_axiom/1]).
:- multifile owl2_io:load_axioms_hook/3.
owl2_io:load_axioms_hook(File,mansyn,Opts) :-
owl_parse_manchester_syntax_file(File,Opts).
owl2_io:load_axioms_hook(File,owlms,Opts) :-
owl_parse_manchester_syntax_file(File,Opts).
owl_parse_manchester_syntax_file(File) :-
owl_parse_manchester_syntax_file(File,[]).
owl_parse_manchester_syntax_file(File,_Opts) :-
read_file_to_codes(File,Codes,[]),
codes_tokens_filtered(Codes,Tokens),
phrase(ontologyDocument(Ont), Tokens),
process_ontdoc(Ont).
owl_parse_manchester_file_axioms(File, Axioms, _Opts) :-
read_file_to_codes(File,Codes,[]),
codes_tokens_filtered(Codes,Tokens),
phrase(ontologyDocument(Ont), Tokens),
ontdoc_axioms(Ont, Axioms).
%% owl_parse_manchester_expression(+DescAtom,?Desc) is semidet
owl_parse_manchester_expression(A,X) :-
atom_codes(A,L),
codes_tokens_filtered(L,Toks),
description(X,Toks,[]).
%% owl_parse_manchester_frame(+FrameAtom,?Axiom) is semidet
owl_parse_manchester_frame(A,Axioms) :-
atom_codes(A,L),
codes_tokens_filtered(L,Toks),
frame(X,Toks,[]),
process_frame('', X, Axioms).
/*******************************
* SYNTAX ERRORS *
*******************************/
%! mn_syntax_error(+Error)//
%
% Report a syntax error
mn_syntax_error(Error) -->
here(Rest),
{ exception_term(Error, Rest, Exception),
throw(error(Exception, _))
}.
exception_term(expected(What), Rest, thea(expected(What, Rest))).
:- multifile prolog:error_message//1.
prolog:error_message(thea(expected(What, Tokens))) -->
[ 'Syntax error. Expected a "~p" but found'-[What], nl,
'... '-[]
],
error_tokens(10, Tokens).
error_tokens(_, []) --> !.
error_tokens(0, _) -->
[ ' ...'-[] ].
error_tokens(N, [H|T]) -->
error_token(H),
{ N2 is N - 1 },
error_tokens(N2, T).
error_token(T) -->
[ ' ~p'-[T] ].
/*******************************
* AST TO AXIOM *
*******************************/
process_ontdoc(Ontology) :-
ontdoc_axioms(Ontology, Axioms),
maplist(assert_axiom,Axioms).
%! ontdoc_axioms(+OntDOc, -Axioms) is det.
%
% Translate the parser AST into a list of axioms.
ontdoc_axioms(NSL-ontology(O,_L1,_L2,Frames), [ontology(O)|Axioms]) :-
nb_setval(current_ontology, O),
maplist(process_frame(O-NSL), Frames, NestedAxioms),
append(NestedAxioms, Axioms).
%% process_frame(+Ont, +FrameParseTree, -Axioms)
%
% translate the parse tree for a frame into axioms and declarations
%
% e.g. frame(class, foo, [subClassOf=[bar]]),
process_frame(O, frame(Type,Name,Props),[Unary|Axioms]) :-
!,
expand_curie(Name,O,IRI),
Unary =.. [Type,IRI],
maplist(process_property_(IRI,Type,O), Props, NestedAxioms),
append(NestedAxioms, Axioms).
process_frame(O, AV,[V]) :-
value_annotations(AV, V0, _Annotations),
V0 =.. [Misc,Values0],
!,
maplist(expand_curie_o(O), Values0, Values),
V =.. [Misc,Values].
process_frame(_, AV,[]) :-
debug(man(axioms), 'Skipped (not a frame) ~p', [AV]).
process_property_(IRI,Type,O,Prop,Axioms) :-
process_property(Prop,IRI,Type,O,Axioms).
process_property(annotation=AL,IRI,Type,O,Axioms) :-
!,
maplist(process_annotation(IRI,Type,O), AL, Axioms).
process_property(characteristics=CL,IRI,Type,O,Axioms) :-
!,
findall(Axiom,(member(C,CL),
process_characteristic(C,IRI,Type,O,Axiom)),
Axioms).
process_property(P=VL0,IRI,Type,O,[Axiom]) :-
list_slot_axiom(P, Type, O, IRI, VL, Axiom),
!,
maplist(expand_value(O), VL0, VL).
process_property(P=VL,IRI,Type,O,Axioms) :-
!,
findall(Axiom,(member(V,VL),
process_slot_value(P,V,IRI,Type,O,Axiom)),
Axioms).
process_annotation(IRI,_Type,O,
Name-Value,
annotationAssertion(PropertyIRI,IRI,OwlValue)) :-
expand_curie(Name, O, PropertyIRI),
expand_curie(Value, O, OwlValue).
process_characteristic(C,IRI,_Type,_,Unary) :-
slot_predicate(C,P),
Unary =.. [P,IRI].
process_slot_value(S,V0,IRI,T,O,Ax) :-
value_annotations(V0, V1, _Annotations),
expand_curie(V1,O,V),
( slot_axiom(S, T, O, IRI, V, Ax)
-> true
; slot_axiom(S, T)
-> Ax =.. [S,IRI,V]
; debug(man(axioms), 'guessing for: ~p', [S-T]),
Ax =.. [S,IRI,V]
).
%! list_slot_axiom(+Attribute, +IRIType, +O, +IRI, +Value, -Axiom)
list_slot_axiom(disjointWith, objectProperty, _,
IRI, V, disjointProperties([IRI|V])).
list_slot_axiom(equivalentTo, objectProperty, _,
IRI, V, equivalentProperties([IRI|V])).
list_slot_axiom(equivalentTo, dataProperty, _,
IRI, V, equivalentProperties([IRI|V])).
list_slot_axiom(equivalentTo, class, _,
IRI, V, equivalentClasses([IRI|V])).
list_slot_axiom(disjointWith, objectProperty, _,
IRI, V, disjointProperties([IRI|V])).
list_slot_axiom(disjointWith, dataProperty, _,
IRI, V, disjointProperties([IRI|V])).
list_slot_axiom(disjointWith, class, _,
IRI, V, disjointClasses([IRI|V])).
list_slot_axiom(sameAs, namedIndividual, _,
IRI, V, sameIndividual([IRI|V])).
list_slot_axiom(differentFrom, namedIndividual, _,
IRI, V, differentIndividuals([IRI|V])).
list_slot_axiom(disjointUnionOf, class, _,
IRI, V, disjointUnion(IRI, V)).
%! slot_axiom(+Attribute, +IRIType, +O, +IRI, +Value, -Axiom)
slot_axiom(inverseOf, _, _,
IRI, V, inverseProperties(IRI,V)).
slot_axiom(domain, _, _,
IRI, V, propertyDomain(IRI,V)).
slot_axiom(range, _, _,
IRI, V, propertyRange(IRI,V)).
slot_axiom(types, _, _,
IRI, V, classAssertion(V,IRI)).
slot_axiom(facts, _, O,
IRI, P0-V0, propertyAssertion(P,IRI,V)) :-
expand_curie(P0,O,P),
expand_curie(V0,O,V).
slot_axiom(facts, _, O,
IRI, not(P0-V0), negativePropertyAssertion(P,IRI,V)) :-
expand_curie(P0,O,P),
expand_curie(V0,O,V).
%! slot_axiom(+Attribute, +IRIType) is semidet.
%
% Indicates that the generic translation is correct.
slot_axiom(subClassOf, class).
slot_axiom(subPropertyOf, objectProperty).
slot_axiom(subPropertyOf, dataProperty).
slot_axiom(subPropertyOf, annotationProperty).
%! expand_value(+O, +V0, -V)
expand_value(O, V0, V) :-
value_annotations(V0, V1, _),
expand_curie(V1, O, V).
%! value_annotations(+Value0, -Value, -Annotations) is det.
%
% Split the annotations from the value.
% @see annotated//2.
value_annotations(annotated(Value, Annotations), Value, Annotations) :- !.
value_annotations(Value, Value, []).
%! expand_curie(+ASTValue, +Ontology, -RDFValue)
expand_curie(IRI, _O-NSL, FullIRI) :-
atom(IRI),
atomic_list_concat([NS,Name], :, IRI),
xml_name(Name, utf8),
( memberchk(NS-Prefix, NSL)
; predefined_prefix(NS, Prefix)
),
!,
atom_concat(Prefix,Name,FullIRI).
expand_curie(IRI, _, IRI) :-
atom(IRI),
uri_is_global(IRI), !.
expand_curie(Name,_O-NSL,IRI) :-
atom(Name),
memberchk(''-Prefix, NSL),
!,
atom_concat(Prefix,Name,IRI).
expand_curie(inverseOf(X0), O, inverseOf(X)) :- !,
expand_curie(X0, O, X).
expand_curie(oneOf(L0), O, oneOf(L)) :- !,
maplist(expand_curie_o(O), L0, L).
expand_curie(exactCardinality(C, X0), O, exactCardinality(C, X)) :- !,
expand_curie(X0, O, X).
expand_curie(intersectionOf(L0), O, intersectionOf(L)) :- !,
maplist(expand_curie_o(O), L0, L).
expand_curie(allValuesFrom(P0, CE0), O, allValuesFrom(P,CE)) :- !,
expand_curie(P0, O, P),
expand_curie(CE0, O, CE).
expand_curie(List0, O, List) :-
is_list(List0), !,
maplist(expand_curie_o(O), List0, List).
expand_curie(X,_,X).
predefined_prefix(rdfs, 'http://www.w3.org/2000/01/rdf-schema#').
predefined_prefix(owl, 'http://www.w3.org/2002/07/owl#').
expand_curie_o(O,AST,RDF) :-
expand_curie(AST,O,RDF).
%! slot_predicate(+Characteristic, -AxiomName)
slot_predicate('Functional', functionalProperty).
slot_predicate('InverseFunctional', inverseFunctionalProperty).
slot_predicate('Reflexive', reflexiveProperty).
slot_predicate('Irreflexive', irreflexiveProperty).
slot_predicate('Symmetric', symmetricProperty).
slot_predicate('Asymmetric', asymmetricProperty).
slot_predicate('Transitive', transitiveProperty).
% ----------------------------------------
% Tokenization
% ----------------------------------------
codes_tokens_filtered(Codes,Tokens) :-
phrase(tokens(Tokens), Codes).
tokens(Tokens) -->
blanks_and_comments,
tokens2(Tokens).
blanks_and_comments -->
blanks,
( "#", string(_), "\n"
-> blanks_and_comments
; "#", string(_), eos
-> ""
; ""
).
tokens2([]) -->
eos, !.
tokens2([H|T]) -->
sep(H),
!,
tokens(T).
tokens2([H|T]) -->
token(H),
tokens(T).
token(String) --> quotedString(String), !.
token(IRI) --> iri_token(IRI), !.
token(NodeID) --> node_id_token(NodeID), !.
token(Float) --> floatingPointLiteral(Float), !.
token(Float) --> decimalLiteral(Float), !.
token(Float) --> integerLiteral(Float), !.
token(^^) --> "^^", !.
token(@) --> "@", !.
token(<=) --> "<=", !.
token(<) --> "<", !.
token(>=) --> ">=", !.
token(>) --> ">", !.
token(Keyword) --> keyword(Keyword), !.
token(H) --> token_chars(L), { atom_codes(H,L) }.
token_chars([H|T]) -->
[H],
\+ { split(H) },
!,
token_chars(T).
token_chars([]) -->
[].
split(0'\s).
split(0'\n).
split(0'\r).
split(0',).
split(0'().
split(0')).
split(0'[).
split(0']).
split(0'{).
split(0'}).
split(0'<).
split(0'>).
split(0'@).
split(0'^).
sep(',') --> ",".
sep('(') --> "(".
sep(')') --> ")".
sep('[') --> "[".
sep(']') --> "]".
sep('{') --> "{".
sep('}') --> "}".
keyword(Keyword) -->
[C], { between(0'A, 0'Z, C) },
letters(L),
":", !,
{ string_codes(KwdU, [C|L]),
downcase_atom(KwdU, Kwd),
Keyword = keyword(Kwd)
}.
letters([H|T]) --> letter(H), !, letters(T).
letters([]) --> [].
letter(C) --> [C], { between(0'a, 0'z, C) -> true ; between(0'A, 0'Z, C) }.
% floatingPointLiteral ::= [ '+' | '-'] ( digits ['.'digits] [exponent] | '.' digits[exponent]) ( 'f' | 'F' )
floatingPointLiteral(float(Value)) -->
here(Start),
opt_sign,
( digits
-> ( "."
-> digits
; ""
),
{ Convert = Chars }
; ".",
digits,
{ Convert = [0'0|Chars] }
),
opt_exponent,
capture(Start, Chars),
f, !,
{ number_codes(Value, Convert) }.
here(Start, Start, Start).
capture(Start, [], Left, Left) :-
same_term(Start, Left), !.
capture([H|T0], [H|T], Left, Left) :-
capture(T0, T, Left, Left).
f --> "f".
f --> "F".
% exponent ::= ('e' | 'E') ['+' | '-'] digits
opt_exponent --> exponent, !.
opt_exponent --> "".
exponent --> e, opt_sign, digits.
e --> "e", !.
e --> "E".
opt_sign --> "+", !.
opt_sign --> "-", !.
opt_sign --> "".
digits --> digit, digits0.
digits0 --> digit, !, digits0.
digits0 --> "".
digit --> "0".
digit --> "1".
digit --> "2".
digit --> "3".
digit --> "4".
digit --> "5".
digit --> "6".
digit --> "7".
digit --> "8".
digit --> "9".
% decimalLiteral ::= ['+' | '-'] digits '.' digits
decimalLiteral(decimal(Float)) -->
here(Start), opt_sign, digits, ".", digits, !, capture(Start, Codes),
{ number_codes(Float, Codes) }.
% integerLiteral ::= ['+' | '-'] digits
integerLiteral(integer(Int)) -->
here(Start), opt_sign, digits, !, capture(Start, Codes),
{ number_codes(Int, Codes) }.
% quotedString := 'a finite sequence of characters in which " (U+22) and
% \ (U+5C) occur only in pairs of the form \" (U+22, U+5C) and \\
% (U+22, U+22), enclosed in a pair of " (U+22) characters'
quotedString(string(String)) -->
"\"", quotedStringChars(Codes), "\"", !,
{ atom_codes(String, Codes) }.
quotedStringChars([]) --> "".
quotedStringChars([H|T]) -->
quotedStringChar(H),
quotedStringChars(T).
quotedStringChar(0'\") --> "\\\"", !.
quotedStringChar(0'\\) --> "\\\\", !.
quotedStringChar(C) --> [C], { C \== 0'\\, C \== 0'\"
-> true
; syntax_error(owl_manchester_string)
}.
iri_token(iri(IRI)) -->
"<", iri_chars(Codes), ">", !,
{ atom_codes(IRI, Codes) }.
iri_chars([]) --> [].
iri_chars([H|T]) --> iri_char(H), iri_chars(T).
iri_char(H) --> [H], { \+ ws(H) }.
ws(0'\s).
ws(0'\n).
ws(0'\r).
node_id_token(nodeID(NodeID)) --> "_:", token_chars(L), { atom_codes(NodeID,L) }.
% Documents in the Manchester OWL syntax consist of sequences of Unicode characters [UNICODE] and are encoded in UTF-8 [RFC3829].
% The grammar for the Manchester syntax does not explicitly show white
% space. White space is allowed between any two terminals or
% non-terminals except inside nonNegativeInteger, prefix, reference,
% full-IRI, lexicalValue, integerLiteral, decimalLiteral,
% floatingPointLiteral, and languageTag. White space is required
% between two terminals or non-terminals if its removal could cause
% ambiguity. Generally this means requiring white space except before
% and after punctuation (e.g., commas, parentheses, braces, and
% brackets).
% White space is a sequence of blanks (U+20), tabs (U+9), line feeds
% (U+A), carriage returns (U+D), and comments. Comments are maximal
% sequences of Unicode characters starting with a '#' and not
% containing a line feed or a carriage return. Note that comments are
% only recognized where white space is allowed, and thus not inside
% the above non-terminals.
% The syntax uses the keywords 'and', 'or', and 'not', which are used
% in descriptions, that can be confused with their use as IRIs. When
% there is an ambiguity the keyword use is to be used.
% TODO!
% ----------------------------------------
% Meta-productions
% ----------------------------------------
:- meta_predicate
zeroOrMore(3,?,+,?),
zeroOrMore(+,3,?,+,?),
oneOrMore(+,3,?,+,?),
annotated(3,-,+,?).
% <NT>List ::= <NT> { , <NT> }
%% zeroOrMore( +F, ?List, +InToks, ?Rest )
zeroOrMore(F,[X|L],In,Rest):-
call(F, X, In, Rest1),
!,
zeroOrMore(F,L,Rest1,Rest).
zeroOrMore(_,[],In,In):- !.
% e.g. zeroOrMore(or,description,L)
zeroOrMore(Delim,F,[X|L],In,Rest):-
call(F,X,In,Rest1),
!,
( Rest1 = [Delim|Rest2]
-> zeroOrMore(Delim,F,L,Rest2,Rest)
; Rest = Rest1,
L = []
).
zeroOrMore(_,_,[],In,In):- !.
% <NT>2List ::= <NT> , <NT>List
oneOrMore(Delim,F,[X|L],In,Rest):-
call(F,X,In,Rest1),
!,
( Rest1 = [Delim|Rest2]
-> oneOrMore(Delim,F,L,Rest2,Rest)
; Rest = Rest1,
L = []
).
%! annotated(:F, -Annotated)//
annotated(F, Result) -->
annotations(A),
!,
call(F, R0),
{ Result = annotated(R0, A) }.
annotated(F, Result) -->
call(F, Result).
% <NT>AnnotatedList ::= [annotations] <NT> { , [annotations]<NT> }
% ----------------------------------------
% 2.1 IRIs, Integers, Literals, and Entities
% ----------------------------------------
% full-IRI := 'IRI as defined in [RFC3987], enclosed in a pair of < (U+3C) and > (U+3E) characters'
full_IRI(IRI) --> [iri(IRI)].
% NCName := 'as defined in [XML Namespaces]'
% TODO
% irelative-ref := 'as defined in [RFC3987]'
% TODO
% namespace := full-IRI
% ?namespace(X) --> full_IRI(X).
% prefixName := NCName
prefixName(NS) --> [P], {atom(P), atom_concat(NS, :, P)}.
% reference := irelative-ref
% curie := [ [ prefix ] ':' ] reference
curie(X) --> [X], { atom(X), \+ reserved(X), \+ phrase(sep(X),_,_) }.
% TODO
reserved(and). % logical connectors
reserved(or).
reserved(not).
reserved(some). % restrictions
reserved(only).
reserved(value).
reserved(min).
reserved(max).
reserved(exactly).
reserved('Self').
reserved(integer). % datatypes
reserved(decimal).
reserved(float).
reserved(string).
% IRI := full-IRI | curie
iri(X) --> full_IRI(X).
iri(X) --> curie(X).
% nonNegativeInteger ::= zero | positiveInteger positiveInteger ::= nonZero { digit } digits ::= digit { digit } digit ::= zero | nonZero nonZero := '1' | '2' | '3' | '4' | '5' | '6' | '7' | '8' | '9' zero ::= '0'
% TODO: this allows for +42
nonNegativeInteger(N) --> [integer(N)], { N >= 0 }.
% classIRI ::= IRI
classIRI(X) --> iri(X).
% Datatype ::= datatypeIRI | 'integer' | 'decimal' | 'float' | 'string'
datatype(X) --> datatypeIRI(X).
datatype('http://www.w3.org/2001/XMLSchema#integer') --> [integer].
datatype('http://www.w3.org/2001/XMLSchema#decimal') --> [decimal].
datatype('http://www.w3.org/2001/XMLSchema#float') --> [float].
datatype('http://www.w3.org/2001/XMLSchema#string') --> [string].
% datatypeIRI ::= IRI
datatypeIRI(X) --> iri(X).
% objectPropertyIRI ::= IRI
objectPropertyIRI(X) --> iri(X).
% dataPropertyIRI ::= IRI
dataPropertyIRI(X) --> iri(X).
% annotationPropertyIRI ::= IRI
annotationPropertyIRI(X) --> iri(X).
% individual ::= individualIRI | nodeID
individual(X) --> individual(X, _).
individual(X, namedIndividual) --> individualIRI(X).
individual(X, anonymousIndividual) --> nodeID(X).
% individualIRI ::= IRI
individualIRI(X) --> iri(X).
% nodeID := 'a node ID of the form _:name as specified in the N-Triples specification [RDF Test Cases]'
nodeID(X) --> [nodeID(X)].
% all the following are TODO
% literal ::= typedLiteral | abbreviatedXSDStringLiteral | abbreviatedRDFTextLiteral | integerLiteral | decimalLiteral | floatingPointLiteral
literal(X) --> typedLiteral(X), !.
literal(X) --> abbreviatedRDFTextLiteral(X), !.
literal(X) --> abbreviatedXSDStringLiteral(X), !.
literal(X) --> [integer(X)], !.
literal(X) --> [decimal(X)], !.
literal(X) --> [float(X)], !.
% typedLiteral ::= lexicalValue '^^' Datatype
typedLiteral(literal(type(Type,Lexical))) -->
[string(Lexical),'^^'],datatype(Type).
% abbreviatedXSDStringLiteral ::= quotedString
abbreviatedXSDStringLiteral(literal(type(Type,Lexical))) -->
[string(Lexical)],
{ Type = 'http://www.w3.org/2001/XMLSchema#string' }.
% abbreviatedRDFTextLiteral ::= quotedString '@' languageTag
% languageTag := 'a nonempty (not quoted) string defined as specified in BCP 47 [BCP 47]'
abbreviatedRDFTextLiteral(literal(lang(Lang,Lexical))) -->
[string(Lexical),'@',Lang], {atom(Lang)}.
% lexicalValue ::= quotedString
% entity ::= 'Datatype' '(' datatypeIRI ')' | 'Class' '(' classIRI ')' | 'ObjectProperty' '(' objectPropertyIRI ')' | 'DataProperty' '('dataPropertyIRI ')' | 'AnnotationProperty' '(' annotationPropertyIRI ')' | 'NamedIndividual' '(' individualIRI ')'
% ----------------------------------------
% 2.2 Ontologies and Annotations
% ----------------------------------------
% annotations ::= 'Annotations:' annotationAnnotatedList
annotations(L) --> [keyword(annotations)], annotationAnnotatedList(L).
% annotation ::= annotationPropertyIRI annotationTarget
annotation(P-T) --> annotationPropertyIRI(P),annotationTarget(T).
% annotationTarget ::= nodeID | IRI | literal
annotationTarget(T) --> nodeID(T) ; iri(T) ; literal(T).
% ontologyDocument ::= { namespace } ontology
ontologyDocument( NSL-O ) --> zeroOrMore(prefixDeclaration,NSL),ontology(O).
% prefixDeclaration ::= 'Prefix:' [ prefixName ] full-IRI
prefixDeclaration(P-NS) --> [keyword(prefix)], prefixName(P), full_IRI(NS).
% ontology ::= 'Ontology:' [ ontologyIRI [ versionIRI ] ] { import } { annotations } { frame }
ontology(ontology(X,Imports,AL,Frames)) -->
[keyword(ontology)], ontologyIRI(X), !,
zeroOrMore(import,Imports),
zeroOrMore(annotations,AL),
zeroOrMore(frame,Frames).
ontology(ontology(Imports,AL,Frames)) -->
[keyword(ontology)], !,
zeroOrMore(import,Imports),
zeroOrMore(annotations,AL),
zeroOrMore(frame,Frames).
ontologyIRI(X-V) --> iri(X),versionIRI(V). % TODO
ontologyIRI(X) --> iri(X).
% ontologyIRI ::= IRI
ontologyIRI(X) --> iri(X).
% versionIRI ::= IRI
versionIRI( X) --> iri(X).
% import ::= 'Import:' IRI
import(X) --> [keyword(import)], iri(X).
% frame ::= datatypeFrame | classFrame | objectPropertyFrame | dataPropertyFrame |
% annotationPropertyFrame | individualFrame | misc
frame(X) --> ( datatypeFrame(X)
; classFrame(X)
; objectPropertyFrame(X)
; dataPropertyFrame(X)
; annotationPropertyFrame(X)
; individualFrame(X)
; misc(X)
; \+ eos,
mn_syntax_error(expected(frame))
), !.
% ----------------------------------------
% 2.3 Property and Datatype Expressions
% ----------------------------------------
% objectPropertyExpression ::= objectPropertyIRI | 'inverse' objectPropertyIRI
objectPropertyExpression(OPE) -->
( [inverse]
-> objectPropertyIRI(IRI),
{ OPE = inverseOf(IRI) }
; objectPropertyIRI(OPE)
).
% dataPropertyExpression ::= dataPropertyIRI
dataPropertyExpression(P) --> dataPropertyIRI(P).
% dataRange ::= dataConjunction 'or' dataConjunction { 'or' dataConjunction } | dataConjunction
dataRange(DR) -->
dataConjunction(C1),
( [or]
-> dataConjunction(C2),
zeroOrMore(or,dataConjunction,CL),
{ DR = unionOf([C1,C2|CL]) }
; { DR = C1 }
).
%dataConjunction ::= dataPrimary 'and' dataPrimary { 'and' dataPrimary } | dataPrimary
dataConjunction(D) -->
dataPrimary(D1),
( [and]
-> dataPrimary(D2),
zeroOrMore(dataPrimary,DL),
{ D = intersectionOf([D1,D2|DL]) }
; { D = D1 }
).
% dataPrimary ::= [ 'not' ] dataAtomic
dataPrimary(complementOf(A)) --> [not], !, dataAtomic(A).
dataPrimary(A) --> dataAtomic(A).
% dataAtomic ::= Datatype | '{' literal { ',' literal } '}' |
% datatypeRestriction | '(' dataRange ')'
dataAtomic([X1|XL]) --> ['{'],!, literal(X1),zeroOrMore(',',literal,XL),['}'].
dataAtomic(A) --> ['('],dataRange(A),[')'].
dataAtomic(A) --> datatypeRestriction(A).
dataAtomic(A) --> datatype(A).
% datatypeRestriction ::= Datatype '[' facet restrictionValue { ',' facet restrictionValue } ']'
datatypeRestriction(datatypeRestriction(X,[F-V|FVs])) -->
datatype(X),['['],!, facet(F),restrictionValue(V),
zeroOrMore(',',facetRestrictionValue, FVs),[']'].
facetRestrictionValue(F-V) --> facet(F),restrictionValue(V).
% facet ::= 'length' | 'minLength' | 'maxLength' | 'pattern' | 'langRange' | '<=' | '<' | '>=' | '>'
facet(length) --> [length].
facet(minLength) --> [minLength].
facet(maxLength) --> [maxLength].
facet(pattern) --> [pattern].
facet(langRange) --> [langRange].
facet(<=) --> [<=].
facet(<) --> [<].
facet(>=) --> [>=].
facet(>) --> [>].
% restrictionValue ::= literal
restrictionValue(V) --> literal(V).
% ----------------------------------------
% 2.4 Descriptions
% ----------------------------------------
% description ::= conjunction 'or' conjunction { 'or' conjunction } | conjunction
description(D) -->
conjunction(C1),
( [or]
-> conjunction(C2),
zeroOrMore(or, conjunction,CL),
{ D = unionOf([C1,C2|CL]) }
; { D = C1 }
).
% conjunction ::= classIRI 'that' [ 'not' ] restriction { 'and' [ 'not' ] restriction } | primary 'and' primary { 'and' primary }| primary
conjunction(intersectionOf([Genus|DL])) --> classIRI(Genus), [that], !, oneOrMore(and, optNegRestriction,DL).
conjunction(D) -->
primary(P),
( [and]
-> oneOrMore(and, primary, DL),
{ D = intersectionOf([P|DL]) }
; { D = P }
).
% primary ::= [ 'not' ] ( restriction | atomic )
primary(R) --> optNegRestriction(R).
primary(complementOf(A)) --> [not],!,atomic(A).
primary(A) --> atomic(A).
optNegRestriction(complementOf(R)) --> [not],!,restriction(R).
optNegRestriction(R) --> restriction(R).
% restriction ::= objectPropertyExpression 'some' primary |
% objectPropertyExpression 'only' primary | objectPropertyExpression
% 'value' individual | objectPropertyExpression 'Self' |
% objectPropertyExpression 'min' nonNegativeInteger [ primary ] |
% objectPropertyExpression 'max' nonNegativeInteger [ primary ] |
% objectPropertyExpression 'exactly' nonNegativeInteger [ primary ] |
% dataPropertyExpression 'some' dataPrimary | dataPropertyExpression
% 'only' dataPrimary | dataPropertyExpression 'value' literal |
% dataPropertyExpression 'min' nonNegativeInteger [ dataPrimary ] |
% dataPropertyExpression 'max' nonNegativeInteger [ dataPrimary ] |
% dataPropertyExpression 'exactly' nonNegativeInteger [ dataPrimary ]
restriction(Restriction) --> objectPropertyExpression(OPE), [Type], objectRestriction(Type, OPE, Restriction), !.
restriction(Restriction) --> dataPropertyExpression(OPE), [Type], dataRestriction(Type, OPE, Restriction), !.
objectRestriction(some, OPE, someValuesFrom(OPE,C)) --> primary(C).
objectRestriction(only, OPE, allValuesFrom(OPE,C)) --> primary(C).
objectRestriction(value, OPE, hasValue(OPE,I)) --> individual(I).
objectRestriction('Self', OPE, hasSelf(OPE)) --> [].
objectRestriction(min, OPE, minCardinality(Card,OPE,CE)) --> nni(Card),primary(CE), !.
objectRestriction(min, OPE, minCardinality(Card,OPE)) --> nni(Card).
objectRestriction(max, OPE, maxCardinality(Card,OPE,CE)) --> nni(Card),primary(CE), !.
objectRestriction(max, OPE, maxCardinality(Card,OPE)) --> nni(Card).
objectRestriction(exactly, OPE, exactCardinality(Card,OPE,CE)) --> nni(Card),primary(CE), !.
objectRestriction(exactly, OPE, exactCardinality(Card,OPE)) --> nni(Card).
dataRestriction(some, OPE, someValuesFrom(OPE,C)) --> dataPrimary(C).
dataRestriction(only, OPE, allValuesFrom(OPE,C)) --> dataPrimary(C).
dataRestriction(value, OPE, hasValue(OPE,L)) --> literal(L).
dataRestriction('Self', OPE, hasSelf(OPE)) --> [].
dataRestriction(min, OPE, minCardinality(Card,OPE,CE)) --> nni(Card),dataPrimary(CE), !.
dataRestriction(min, OPE, minCardinality(Card,OPE)) --> nni(Card).
dataRestriction(max, OPE, maxCardinality(Card,OPE,CE)) --> nni(Card),dataPrimary(CE), !.
dataRestriction(max, OPE, maxCardinality(Card,OPE)) --> nni(Card).
dataRestriction(exactly, OPE, exactCardinality(Card,OPE,CE)) --> nni(Card),dataPrimary(CE), !.
dataRestriction(exactly, OPE, exactCardinality(Card,OPE)) --> nni(Card).
nni(N) --> nonNegativeInteger(N).
% atomic ::= classIRI | '{' individual { ',' individual } '}' | '(' description ')'
atomic(X) --> classIRI(X).
atomic(oneOf(L)) --> ['{'], !, oneOrMore(',',individual,L),['}'].
atomic(X) --> ['('], !, description(X), [')'].
% <NT>AnnotatedList ::= [annotations] <NT> { , [annotations] <NT> }
annotationAnnotatedList(L) --> oneOrMore(',', annotation,L).
descriptionAnnotatedList(L) --> oneOrMore(',',annotatedDescription,L). % TODO
objectPropertyCharacteristicAnnotatedList(L) --> oneOrMore(',',annotatedObjectPropertyCharacteristic,L).
objectPropertyExpressionAnnotatedList(L) --> oneOrMore(',',annotatedObjectPropertyExpression,L).
annotatedObjectPropertyCharacteristic(X) --> objectPropertyCharacteristic(X). % TODO
annotatedObjectPropertyExpression(X) --> objectPropertyExpression(X). % TODO
% <NT>2List ::= <NT> , <NT>List
description2List(L) --> oneOrMore(',',description,L).
annotatedDescription(D) --> annotated(description, D).
objectProperty2List(L) --> oneOrMore(',', objectPropertyExpression, L).
dataProperty2List(L) --> oneOrMore(',', dataPropertyExpression, L).
individual2List(L) --> oneOrMore(',', individual, L).
% ----------------------------------------
% 2.5 Frames and Miscellaneous
% ----------------------------------------
% classFrame ::= 'Class:' classIRI { 'Annotations:'
% annotationAnnotatedList | 'SubClassOf:' descriptionAnnotatedList |
% 'EquivalentTo:' descriptionAnnotatedList | 'DisjointWith:'
% descriptionAnnotatedList | 'DisjointUnionOf:' annotations
% description2List }
datatypeFrame(frame(datatype,C,EL)) --> [keyword(datatype)],!,classIRI(C),zeroOrMore(datatypeFrameElement,EL).
datatypeFrameElement(annotation=AL) --> [keyword(annotations)],!,annotationAnnotatedList(AL).
datatypeFrameElement(equivalentTo=(DR)) --> [keyword(equivalentto)], !, annotated(dataRange, DR).
classFrame( frame(class,C,EL) ) --> [keyword(class)],!,classIRI(C),zeroOrMore(classFrameElement,EL).
classFrameElement(annotation=AL) --> [keyword(annotations)],!,annotationAnnotatedList(AL).
classFrameElement(subClassOf=AL) --> [keyword(subclassof)],!,descriptionAnnotatedList(AL).
classFrameElement(equivalentTo=AL) --> [keyword(equivalentto)],!,descriptionAnnotatedList(AL).
classFrameElement(disjointWith=AL) --> [keyword(disjointwith)],!,descriptionAnnotatedList(AL).
classFrameElement(disjointUnionOf=AL) --> [keyword(disjointunionof)],!,descriptionAnnotatedList(AL).
classFrameElement(hasKey=AL) --> [keyword(haskey)],!, annotated(hasKey, AL).
hasKey(K) --> objectPropertyExpression(K), !.
hasKey(K) --> dataPropertyExpression(K), !.
% objectPropertyFrame ::= 'ObjectProperty:' objectPropertyIRI {
%'Annotations:' annotationAnnotatedList | 'Domain:'
%descriptionAnnotatedList | 'Range:' descriptionAnnotatedList |
%'Characteristics:' objectPropertyCharacteristicAnnotatedList |
%'SubPropertyOf:' objectPropertyExpressionAnnotatedList |
%'EquivalentTo:' objectPropertyExpressionAnnotatedList |
%'DisjointWith:' objectPropertyExpressionAnnotatedList | 'InverseOf:'
%objectPropertyExpressionAnnotatedList | 'SubPropertyChain:'
%annotations objectPropertyExpression 'o' objectPropertyExpression {
%'o' objectPropertyExpression } }
objectPropertyFrame( frame(objectProperty,C,EL) ) --> [keyword(objectproperty)],!,objectPropertyIRI(C),zeroOrMore(objectPropertyFrameElement,EL).
objectPropertyFrameElement(annotation=AL) --> [keyword(annotations)],!,annotationAnnotatedList(AL).
objectPropertyFrameElement(domain=AL) --> [keyword(domain)],!,descriptionAnnotatedList(AL).
objectPropertyFrameElement(range=AL) --> [keyword(range)],!,descriptionAnnotatedList(AL).
objectPropertyFrameElement(characteristics=AL) --> [keyword(characteristics)],!,objectPropertyCharacteristicAnnotatedList(AL).
objectPropertyFrameElement(subPropertyOf=AL) --> [keyword(subpropertyof)],!,objectPropertyExpressionAnnotatedList(AL).
objectPropertyFrameElement(equivalentTo=AL) --> [keyword(equivalentto)],!,objectPropertyExpressionAnnotatedList(AL).
objectPropertyFrameElement(disjointWith=AL) --> [keyword(disjointwith)],!,objectPropertyExpressionAnnotatedList(AL).
objectPropertyFrameElement(inverseOf=AL) --> [keyword(inverseof)],!,objectPropertyExpressionAnnotatedList(AL).
objectPropertyFrameElement(subPropertyChain=Chain) --> [keyword(subpropertychain)],!,annotated(subPropertyChain, Chain).
subPropertyChain([OPE1,OPE2|OPEs]) -->
objectPropertyExpression(OPE1),[o],objectPropertyExpression(OPE2),[o],zeroOrMore(o,objectPropertyExpression,OPEs).
% objectPropertyCharacteristic ::= 'Functional' | 'InverseFunctional'
%| 'Reflexive' | 'Irreflexive' | 'Symmetric' | 'Asymmetric' |
%'Transitive'
objectPropertyCharacteristic(P) --> [P],{objectPropertyCharacteristic(P)}.
objectPropertyCharacteristic('Functional').
objectPropertyCharacteristic('InverseFunctional').
objectPropertyCharacteristic('Reflexive').
objectPropertyCharacteristic('Irreflexive').
objectPropertyCharacteristic('Symmetric').
objectPropertyCharacteristic('Asymmetric').
objectPropertyCharacteristic('Transitive').
% dataPropertyFrame ::= 'DataProperty:' dataPropertyIRI {
% 'Annotations:' annotationAnnotatedList | 'Domain:'
% descriptionAnnotatedList | 'Range:' dataRangeAnnotatedList |
% 'Characteristics:' annotations 'Functional' | 'SubPropertyOf:'
% dataPropertyExpressionAnnotatedList | 'EquivalentTo:'
% dataPropertyExpressionAnnotatedList | 'DisjointWith:'
% dataPropertyExpressionAnnotatedList }
dataPropertyFrame( frame(dataProperty,C,EL) ) --> [keyword(dataproperty)],!,dataPropertyIRI(C),zeroOrMore(dataPropertyFrameElement,EL).
dataPropertyFrameElement(annotation=AL) --> [keyword(annotations)],!,annotationAnnotatedList(AL).
dataPropertyFrameElement(domain=AL) --> [keyword(domain)],!,descriptionAnnotatedList(AL).
dataPropertyFrameElement(range=AL) --> [keyword(range)],!,dataRangeAnnotatedList(AL).
dataPropertyFrameElement(characteristics=AL) --> [keyword(characteristics)],!,dataPropertyCharacteristicAnnotatedList(AL).
dataPropertyFrameElement(subPropertyOf=AL) --> [keyword(subpropertyof)],!,dataPropertyExpressionAnnotatedList(AL).
dataPropertyFrameElement(equivalentTo=AL) --> [keyword(equivalentto)],!,dataPropertyExpressionAnnotatedList(AL).
dataPropertyFrameElement(disjointWith=AL) --> [keyword(disjointwith)],!,dataPropertyExpressionAnnotatedList(AL).
dataRangeAnnotatedList(AL) --> oneOrMore(',', dataRangeAnnotated, AL).
dataRangeAnnotated(R) --> annotated(dataRange, R).
dataPropertyCharacteristicAnnotatedList(P) --> [P],{dataPropertyCharacteristic(P)}.
dataPropertyCharacteristic('Functional').
dataPropertyExpressionAnnotatedList(AL) --> oneOrMore(',', annotatedDataPropertyExpression, AL).
annotatedDataPropertyExpression(E) --> annotated(dataPropertyExpression, E).
% annotationPropertyFrame ::= 'AnnotationProperty:'
%annotationPropertyIRI { 'Annotations:' annotationAnnotatedList } |
%'Domain:' IRIAnnotatedList | 'Range:' IRIAnnotatedList |
%'SubPropertyOf:' annotationPropertyIRIAnnotatedList
annotationPropertyFrame( frame(annotationProperty,C,EL) ) --> [keyword(annotationproperty)],!,annotationPropertyIRI(C),zeroOrMore(annotationPropertyFrameElement,EL).
annotationPropertyFrameElement(annotation=AL) --> [keyword(annotations)],!,annotationAnnotatedList(AL).
annotationPropertyFrameElement(domain=AL) --> [keyword(domain)],!,iriAnnotatedList(AL).
annotationPropertyFrameElement(range=AL) --> [keyword(range)],!,iriAnnotatedList(AL).
annotationPropertyFrameElement(subPropertyOf=AL) --> [keyword(subpropertyof)],!,annotationPropertyIRIAnnotatedList(AL).
%! iriAnnotatedList(-List)//
%
% This is not defined in the syntax. It suggests a list if IRIs, but the example
% shows `integer`. We therefore use datatype//1.