AutoHotKey for KTL

[CSWinnall]

Hi All

I would like to share with you a little project I've just started for the KTL using Auto Hot Key. I only have a few done at the moment and as I add them I'll post them here.

It just uses shortcut keys to type out the keyword i.e. clst = _cls=[], [ktlTarget, $('#${viewId} ')]
The code will also put your cursor in the first square brackets and then pressing tab will put you after the ${viewId}.
The "Hotstrings" will only work in the Knack Builder windows of your browser.

#HotIf InStr(WinGetTitle("A"), "Knack Builder")
::ktlt:: {
    SendInput "{Raw}[ktlTarget, $('#${viewId} ')]"
    Send "{Left 3}"
    return
}

global activeHotstring := ""  ; Variable to track the active hotstring

::clst:: {
    global activeHotstring
    SendInput "{Raw}_cls=[], [ktlTarget, $('#${viewId} ')]"
    Send "{Left 32}"
    activeHotstring := "clst"  ; Track the active hotstring
    return
}

::styt:: {
    global activeHotstring
    SendInput "{Raw}_style=[], [ktlTarget, $('#${viewId} ')]"
    Send "{Left 32}"
    activeHotstring := "styt"  ; Track the active hotstring
    return
}

Tab:: {
    global activeHotstring
    if (activeHotstring = "clst") {
        Send "{Right 29}"  ; 
    } else if (activeHotstring = "styt") {
        Send "{Right 29}"  ;
    } else {
        Send "{Tab}"  ; Default Tab behaviour
    }
    activeHotstring := ""  ; Reset after Tab is pressed
    return
}

::cls:: {
    SendInput "{Raw}_cls=[]"
    Send "{Left}"
    return
}

::sty:: {
    SendInput "{Raw}_style=[]"
    Send "{Left}"
    return
}

Here are some examples but if you add your own share them here.

Craig

[cortexrd]

Hey Craig!!

I'm so happy to see that I'm not the only one using AutoHotkey with KTL. Actually I use AHK with everything! My script file has 1300+ lines of code in it.

I use it in the Builder a lot, saving me a ton of clicks all around the page. Begin an "ex-semi-professional" piano/keyboard player, I'd trade 100 mouse clicks for one keystroke anytime.

I will try to find some time and share my scripts with you.

Thanks for yours.

Norm

[CSWinnall]

That would be great. I am just rediscovering AHK after quite a few years away from it.

I'd love to see some of your scripts, based on the KTL and Knack, I am sure they are pretty spectacular and include things I would never have thought of.

Craig

[Greenlight88]

Nice thank you - big AHK fan - but I just do text shortcuts - would love to see what you can do with it re:KTL Norm has a script where he hits a few keys and money appears in his pocket 😂

…

On Wed, Oct 9, 2024 at 5:28 AM Craig Winnall ***@***.***> wrote: That would be great. I am just rediscovering AHK after quite a few years away from it. I'd love to see some of your scripts, based on the KTL and Knack, I am sure they are pretty spectacular and include things I would never have thought of. Craig — Reply to this email directly, view it on GitHub <#387 (reply in thread)>, or unsubscribe <https://github.com/notifications/unsubscribe-auth/BATZOYBVKGIDWH4LKVPRDETZ2QP3RAVCNFSM6AAAAABPOHYTQCVHI2DSMVQWIX3LMV43URDJONRXK43TNFXW4Q3PNVWWK3TUHMYTAOBYGM4DINQ> . You are receiving this because you are subscribed to this thread.Message ID: <cortexrd/Knack-Toolkit-Library/repo-discussions/387/comments/10883846 @github.com>

-- Kind Regards, [image: Greenlight Logo] <https://greenlightservices.com.au/> Michael Tierney *BE * Director | Occupational Hygienist Greenlight Environmental Services | www.greenlightservices.com.au [image: -] Office 24, 15 Cochranes Rd, MOORABBIN VIC 3189 [image: phone-green] <1300888001>1300 888 001 <1300888001> [image: -] <https://twitter.com/green_light_aus> [image: -] <https://www.facebook.com/pg/Greenlight.Melbourne> [image: -] <https://www.linkedin.com/company/greenlight-environmental-services/> Licensed Asbestos Assessor (LAA001018) This email and any attachments are proprietary and confidential and are intended solely for the use of the individual to whom it is addressed. Any views or opinions expressed are solely those of the author and do not necessarily reflect or represent those of Greenlight Environmental Services. If you have received this email in error, please let us know immediately by reply email and delete it from your system. You may not use, disseminate, distribute or copy this message nor disclose its contents to anyone. Greenlight Environmental Services – Office 24, 15 Cochranes Rd, MOORABBIN VIC 3189 – 88 497 145 734

[cortexrd]

Not yet, but working on it !!!

[cortexrd]

Here are a bunch of utilities I've created. Since they date back to more than a decade, they are still in V1. But they can be converted to V2 easily.

They are used in various contexts.

1. In the Builder
2. In your favorite code editor
3. In the app's development console (DevTools)
4. See the attached files for the PNG files. I don't have the KnackLargeXButton.png anymore. Can't remember where it was used...

Note that they are tuned for a 4K monitor, but I think they should work with any resolution since the coords are relative to the window's top-left pixel (0,0).

Have fun!

#if winactive("- builder") or winactive("- Knack Builder")
{
	!s:: ;Alt+S  Save Changes
		{
			MouseGetPos, X, Y

			ImageSearch, FoundX, FoundY, 10, 10, 3700, 2100, *30 c:\code\Knack\Save.png
			if (ErrorLevel = 0) ;Found
			{
				MouseClick, left, FoundX+10, FoundY+10
				mousemove, X, Y
			}

			return
		}
	^s:: ;Ctrl+S  Save Changes for Javascript and CSS
		{
			send {F1}save{enter}
			return
		}
	!q:: ;Cancel
		{
			MouseGetPos, X, Y

			;Try to find Save first, and if found click to its left to get Cancel in all cases.
			ImageSearch, FoundX, FoundY, 30, 30, 2050, 2100, *30 c:\code\Knack\Save.png
			if (ErrorLevel = 0) ;Found
			{
				;Mousemove, FoundX-100, FoundY+10
				MouseClick, left, FoundX-100, FoundY+10
			}
			else ;If not found then try small X
			{
				ImageSearch, FoundX, FoundY, 200, 20, 2550, 1400, *50 c:\code\Knack\KnackSmallXButton.png
				if (ErrorLevel = 0) ;Found
				{
					MouseClick, left, FoundX+10, FoundY+10
				}
				else ;If not found then try large X
				{
					ImageSearch, FoundX, FoundY, 200, 70, 2500, 1400, *50 c:\code\Knack\KnackLargeXButton.png
					if (ErrorLevel = 0) ;Found
					{
						MouseClick, left, FoundX+10, FoundY+10
					}
				}
			}

			mousemove, X, Y
			return
		}

	!`:: ;Back arrow at top left  (ImageSearch doesn't work with too small images)
		{
			MouseGetPos, X, Y				
			MouseClick, left, 141, 282, 1
			sleep 200				
			MouseClick, left, 141, 250, 1				
			mousemove, X, Y
			return
		}
	!2:: ;Records
		{
			MouseGetPos, X, Y
			mouseclick, left, 62, 347, 1
			sleep 100
			mousemove, X, Y
			return
		}
	!3:: ;Pages
		{
			MouseGetPos, X, Y
			mouseclick, left, 71, 536, 1
			sleep 100
			mousemove, X, Y
			return
		}
	}
#ifwinactive

;Use in console
::dqs::
{
	send document.querySelector('')
	send {left}{left}
	return
}

;Use in console
::dqa::
{
	send document.querySelectorAll('')
	send {left}{left}
	return
}

;Use in code to add a console log, ready to type whatever you want.
::csl::
{
	send console.log();
	send {left}{left}
	return
}

;Use in code to add a console log, but will paste the variable that you currently have in clipboard.
::cs=::
{
	send {end}+{home}^xconsole.log('
	sleep 300
	send ^v =',{space}
	sleep 400
	send ^v);
	return
}

;Same as csl but stringified and formatted.  Use with objects.
::jcsl::
{
	send console.log('^v =', JSON.stringify(^v, null, 4));
	send {left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}
	return
}

;Use in code to add a colorized log.  Accepts multiple params.
::clog::
{
	send ktl.log.clog('purple', '
	return
}

;To add a local storage log for embedded devices that don't have a console.
::lsl::
{
	send ktl.debugWnd.lsLog('');
	send {left}{left}{left}
	return
}