Check if there is interest in using highest random weight distribution strategy

[ruslandoga]

👋

I wonder if there is any interest in implementing the approach described in https://en.wikipedia.org/wiki/Rendezvous_hashing for one of the default Horde distribution strategies.

defmodule Horde.RendezvousDistribution do
  @moduledoc """
  Distributes processes to nodes uniformly using rendezvous hashing.

  Given the *same* set of members, it will always start the same process on the same node.
  """

  def choose_node(child_spec, members) do
    identifier = Map.drop(child_spec, [:id])
    
    case Enum.filter(members, &match?(%{status: :alive}, &1)) do
      [_ | _] = alive ->
        {:ok, Enum.max_by(alive, fn %{name: name} -> {:erlang.phash2({identifier, name}), name} end)}

      [] ->
        {:error, :no_alive_nodes}
    end
  end
  
  def has_quorum?(_members), do: true
end

[ruslandoga]

I wonder if there is any interest [...]

If there is, I'd be happy to contribute! :)

Btw it's also much faster

---

Horde.RendezvousDistribution here is a naive implementation from the OP. It can be made much more performant.

child_spec = %{id: Worker, start: {Worker, :start_link, [[some: :options]]}}

members = [
  %{name: :alice, status: :alive},
  %{name: :bob, status: :alive},
  %{name: :eve, status: :alive}
]

:timer.tc(fn -> Enum.each(1..10000, fn _ -> Horde.RendezvousDistribution.choose_node(child_spec, members) end) end)
# {16997, :ok}

:timer.tc(fn -> Enum.each(1..10000, fn _ -> Horde.UniformDistribution.choose_node(child_spec, members) end) end)
# {829810, :ok}

---