build.gradle

buildscript {
    ext {
        versions = [
            jApiCmp: '0.2.8',
            kotlin: '1.3.72',
            rxJava: '3.0.2'
        ]
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:3.6.3'

        classpath "me.champeau.gradle:japicmp-gradle-plugin:$versions.jApiCmp"

        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$versions.kotlin"
        classpath "org.jetbrains.dokka:dokka-android-gradle-plugin:0.9.18"
    }

    repositories {
        google()
        mavenCentral()
        gradlePluginPortal()
        jcenter()
    }
}

apply from: 'compatibility.gradle'

allprojects { project ->
    repositories {
        google()
        mavenCentral()
        jcenter()
    }

    //noinspection UnnecessaryQualifiedReference
    project.plugins.withType(com.android.build.gradle.LibraryPlugin) {
        project.android.libraryVariants.all { variant ->
            // TODO WORKAROUND: replace with https://issuetracker.google.com/issues/72050365 once released.
            variant.generateBuildConfigProvider.get().enabled = false
        }
    }
}

ext {
    libraryVersion = '3.0.0'

    targetSdk = 29
    minSdk = 14

    keystore = project.hasProperty('personalKeystore') ? personalKeystore : 'x'
    keystorePassword = project.hasProperty('personalKeystorePassword') ? personalKeystorePassword : 'x'
    keyAlias = project.hasProperty('personalKeyAlias') ? personalKeyAlias : 'x'
    keyPassword = project.hasProperty('personalKeyPassword') ? personalKeyPassword : 'x'
}

task clean(type: Delete) {
    delete rootProject.buildDir
}