forked from rejoe2/FHEM
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy path98_WeekdayTimer.pm
1743 lines (1474 loc) · 69.5 KB
/
98_WeekdayTimer.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
# $Id: 98_WeekdayTimer.pm 24285 2021-04-29 Test single instance hash timer in the past array Beta-User $
#############################################################################
#
# 98_WeekdayTimer.pm
# written by Dietmar Ortmann
# modified by Tobias Faust
# Maintained by Beta-User since 11-2019
# Thanks Dietmar for all you did for FHEM, RIP
#
# This file is part of fhem.
#
# Fhem is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 2 of the License, or
# (at your option) any later version.
#
# Fhem is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with fhem. If not, see <http://www.gnu.org/licenses/>.
#
##############################################################################
##############################################################################
package FHEM::WeekdayTimer; ## no critic 'Package declaration'
use strict;
use warnings;
use Time::Local qw( timelocal_nocheck );
use Data::Dumper;
$Data::Dumper::Sortkeys = 1;
use Scalar::Util qw( weaken );
use GPUtils qw(GP_Import);
## Import der FHEM Funktionen
#-- Run before package compilation
BEGIN {
# Import from main context
GP_Import(
qw(
defs
modules
attr
init_done
DAYSECONDS
MINUTESECONDS
readingFnAttributes
readingsSingleUpdate
readingsBulkUpdate
readingsBeginUpdate
readingsEndUpdate
AttrVal
ReadingsVal
ReadingsNum
InternalVal
Value
IsWe
Log3
InternalTimer
RemoveInternalTimer
CommandAttr
CommandDeleteAttr
CommandGet
getAllSets
AnalyzeCommandChain
AnalyzePerlCommand
EvalSpecials
perlSyntaxCheck
devspec2array
addToDevAttrList
FmtDateTime
sunrise_abs
sunset_abs
trim
stacktrace
decode_json
looks_like_number
)
);
}
sub ::WeekdayTimer_Initialize { goto &Initialize }
sub ::WeekdayTimer_SetParm { goto &WeekdayTimer_SetParm }
sub ::WeekdayTimer_SetAllParms { goto &WeekdayTimer_SetAllParms }
################################################################################
sub Initialize {
my $hash = shift // return;
# Consumer
$hash->{SetFn} = \&WeekdayTimer_Set;
$hash->{DefFn} = \&WeekdayTimer_Define;
$hash->{UndefFn} = \&WeekdayTimer_Undef;
$hash->{GetFn} = \&WeekdayTimer_Get;
$hash->{AttrFn} = \&WeekdayTimer_Attr;
$hash->{UpdFn} = \&WeekdayTimer_Update;
$hash->{AttrList}= "disable:0,1 delayedExecutionCond WDT_delayedExecutionDevices WDT_Group switchInThePast:0,1 commandTemplate WDT_eventMap:textField-long WDT_sendDelay:slider,0,1,300,1 $readingFnAttributes";
return;
}
################################################################################
sub WeekdayTimer_Define {
my $hash = shift;
my $def = shift // return;
WeekdayTimer_InitHelper($hash);
my @arr = split m{\s+}xms, $def;
return "Usage: define <name> $hash->{TYPE} <device> <language> <switching times> <condition|command>"
if(@arr < 4);
#fuer den modify Altlasten bereinigen
delete $hash->{helper};
my $name = shift @arr;
my $type = shift @arr;
my $device = shift @arr;
WeekdayTimer_DeleteTimer($hash);
my $delVariables = "(CONDITION|COMMAND|profile|Profil)";
map { delete $hash->{$_} if m{\A$delVariables.*}xms } keys %{$hash};
$hash->{NAME} = $name;
$hash->{DEVICE} = $device;
my $language = getWDTLanguage ($hash, \@arr);
my $idx = 0;
$hash->{'.dayNumber'} = {map {$_ => $idx++} @{$hash->{'.shortDays'}{$language}}};
$hash->{helper}{daysRegExp} = '(' . join (q{|}, @{$hash->{'.shortDays'}{$language}}) . ")";
$hash->{helper}{daysRegExpMessage} = $hash->{helper}{daysRegExp};
$hash->{helper}{daysRegExp} =~ s{\$}{\\\$}gxms;
$hash->{helper}{daysRegExp} =~ s{\!}{\\\!}gxms;
$hash->{CONDITION} = q{};
$hash->{COMMAND} = q{};
addToDevAttrList($name, 'weekprofile') if $def =~ m{weekprofile}xms;
if (!$init_done) {
InternalTimer(time, \&WeekdayTimer_Start,$hash,0) ;
return;
}
WeekdayTimer_Start($hash);
return;
}
################################################################################
sub WeekdayTimer_Undef {
my $hash = shift;
my $arg = shift // return;
for my $idx (keys %{$hash->{profil}}) {
deleteSingleRegisteredInternalTimer($idx, $hash);
}
deleteSingleRegisteredInternalTimer($hash->{VERZOEGRUNG_IDX},$hash) if defined $hash->{VERZOEGRUNG_IDX};
delete $modules{$hash->{TYPE}}{defptr}{$hash->{NAME}};
return deleteSingleRegisteredInternalTimer("SetTimerOfDay", $hash);
}
################################################################################
sub WeekdayTimer_Start {
my $hash = shift // return;
my $name = $hash->{NAME};
my $def = $hash->{DEF};
deleteSingleRegisteredInternalTimer($hash->{VERZOEGRUNG_IDX},$hash) if defined ($hash->{VERZOEGRUNG_IDX});
my @arr = split m{\s+}xms, $def;
my $device = shift @arr;
my $language = getWDTLanguage ($hash, \@arr);
WeekdayTimer_GlobalDaylistSpec ($hash, \@arr);
my @switchingtimes = gatherSwitchingTimes ($hash, \@arr);
my $conditionOrCommand = join q{ }, @arr;
my @errors;
# test if device is defined
if ( !$defs{$device} ) {
Log3( $hash, 3, "[$name] device <$device> in fhem not defined, but accepted") ;
if ( $init_done ) { push @errors, qq(device <$device> in fhem not defined) };
}
# wenn keine switchintime angegeben ist, dann Fehler
if (@switchingtimes == 0) {
Log3( $hash, 3, "[$name] no valid Switchingtime found in <$conditionOrCommand>, check parameters or make sure weekprofile device exists and returns valid data." ) ;
if($init_done) { push @errors, qq(no valid switchingtime found in <$conditionOrCommand>, check parameters or make sure weekprofile device exists and returns valid data.) };
}
$hash->{STILLDONETIME} = 0;
$hash->{SWITCHINGTIMES} = \@switchingtimes;
$attr{$name}{verbose} = 5 if !defined $attr{$name}{verbose} && $name =~ m{\Atst.*}xms;
$defs{$device}{STILLDONETIME} = 0 if $defs{$device};
$modules{$hash->{TYPE}}{defptr}{$hash->{NAME}} = $hash;
if ( $conditionOrCommand =~ m{\A\(.*\)\z}xms ) { #condition (*)
$hash->{CONDITION} = $conditionOrCommand;
my %specials = ( "%NAME" => $hash->{DEVICE}, "%EVENT" => "0");
my $r = perlSyntaxCheck(qq({$conditionOrCommand}),%specials);
if ( $r ) {
Log3( $hash, 2, "[$name] check syntax of CONDITION <$conditionOrCommand>" ) ;
if ( $init_done ) { push @errors, qq(check syntax of CONDITION <$conditionOrCommand>: $r) };
}
} elsif ( length($conditionOrCommand) > 0 ) {
$hash->{COMMAND} = $conditionOrCommand;
}
WeekdayTimer_Profile ($hash);
delete $hash->{VERZOEGRUNG};
delete $hash->{VERZOEGRUNG_IDX};
$attr{$name}{commandTemplate} =
'set $NAME '. checkIfDeviceIsHeatingType($hash) .' $EVENT' if !defined $attr{$name}{commandTemplate};
WeekdayTimer_SetTimerOfDay({ HASH => $hash});
return if !$init_done;
return join('\n', @errors) if (@errors);
return;
}
################################################################################
sub WeekdayTimer_Set {
my ($hash,@arr) = @_;
return "no set value specified" if int(@arr) < 2;
return "Unknown argument $arr[1], choose one of enable:noArg disable:noArg WDT_Params:single,WDT_Group,all weekprofile" if $arr[1] eq '?';
my $name = shift @arr;
my $v = join q{ }, @arr;
if ($v eq 'enable') {
Log3( $hash, 3, "[$name] set $name $v" );
if (AttrVal($name, "disable", 0)) {
CommandAttr(undef, "$name disable 0");
} else {
WeekdayTimer_SetTimerOfDay({ HASH => $hash});
}
return;
}
if ($v eq 'disable') {
Log3( $hash, 3, "[$name] set $name $v" );
return CommandAttr(undef, "$name disable 1");
}
if ($v =~ m{\AWDT_Params}xms) {
if ($v =~ m{single}xms) {
Log3( $hash, 4, "[$name] set $name $v called" );
return WeekdayTimer_SetParm($name);
}
if ($v =~ m{WDT_Group}xms) {
my $group = AttrVal($hash->{NAME},"WDT_Group",undef) // return Log3( $hash, 3, "[$name] set $name $v cancelled: group attribute not set for $name!" );
return WeekdayTimer_SetAllParms($group);
} elsif ($v =~ m{all}xms){
Log3( $hash,3, "[$name] set $name $v called; params in all WeekdayTimer instances will be set!" );
return WeekdayTimer_SetAllParms('all');
}
return;
}
if ($v =~ m{\Aweekprofile[ ]([^: ]+):([^:]+):([^: ]+)\b}xms) {
Log3( $hash, 3, "[$name] set $name $v" );
return if !updateWeekprofileReading($hash, $1, $2, $3);
WeekdayTimer_DeleteTimer($hash);
return WeekdayTimer_Start($hash);
}
return;
}
################################################################################
sub WeekdayTimer_Get {
my ($hash, @arr) = @_;
return "argument is missing" if int(@arr) != 2;
$hash->{LOCAL} = 1;
delete $hash->{LOCAL};
my $reading= $arr[1];
my $value;
if ( defined $hash->{READINGS}{$reading} ) {
$value= $hash->{READINGS}{$reading}{VAL};
} else {
return "no such reading: $reading";
}
return "$arr[0] $reading => $value";
}
################################################################################
sub resetRegisteredInternalTimer {
my ( $modifier, $tim, $callback, $hash, $waitIfInitNotDone ) = @_;
deleteSingleRegisteredInternalTimer( $modifier, $hash, $callback );
return setRegisteredInternalTimer ( $modifier, $tim, $callback, $hash, $waitIfInitNotDone );
}
################################################################################
sub setRegisteredInternalTimer {
my ( $modifier, $tim, $callback, $hash, $waitIfInitNotDone ) = @_;
my $timerName = "$hash->{NAME}_$modifier";
my $fnHash = {
HASH => $hash,
NAME => $timerName,
MODIFIER => $modifier
};
weaken($fnHash->{HASH});
if ( defined $hash->{TIMER}{$timerName} ) {
Log3( $hash, 1, "[$hash->{NAME}] possible overwriting of timer $timerName - please delete it first" );
stacktrace();
}
else {
$hash->{TIMER}{$timerName} = $fnHash;
}
Log3( $hash, 5, "[$hash->{NAME}] setting Timer: $timerName " . FmtDateTime($tim) );
InternalTimer( $tim, $callback, $fnHash, $waitIfInitNotDone );
return $fnHash;
}
################################################################################
sub deleteSingleRegisteredInternalTimer {
my $modifier = shift;
my $hash = shift // return;
my $callback = shift;
my $timerName = "$hash->{NAME}_$modifier";
my $fnHash = $hash->{TIMER}{$timerName};
if ( defined $fnHash ) {
Log3( $hash, 5, "[$hash->{NAME}] removing Timer: $timerName" );
RemoveInternalTimer($fnHash);
delete $hash->{TIMER}{$timerName};
}
return;
}
################################################################################
sub deleteAllRegisteredInternalTimer {
my $hash = shift // return;
for my $key ( keys %{ $hash->{TIMER} } ) {
deleteSingleRegisteredInternalTimer( $hash->{TIMER}{$key}{MODIFIER}, $hash );
}
return;
}
################################################################################
sub WeekdayTimer_InitHelper {
my $hash = shift // return;
delete $hash->{setModifier};
$hash->{'.longDays'} = { de => ["Sonntag", "Montag","Dienstag","Mittwoch", "Donnerstag","Freitag", "Samstag", "Wochenende", "Werktags" ],
en => ["Sunday", "Monday","Tuesday", "Wednesday", "Thursday", "Friday", "Saturday", "weekend", "weekdays" ],
fr => ["Dimanche", "Lundi", "Mardi", "Mercredi", "Jeudi", "Vendredi","Samedi", "weekend", "jours de la semaine"],
nl => ["Zondag", "Maandag", "Dinsdag", "Woensdag", "Donderdag", "Vrijdag", "Zaterdag", "weekend", "werkdagen"]};
$hash->{'.shortDays'} = { de => ["so","mo","di","mi","do","fr","sa",'$we','!$we'],
en => ["su","mo","tu","we","th","fr","sa",'$we','!$we'],
fr => ["di","lu","ma","me","je","ve","sa",'$we','!$we'],
nl => ["zo","ma","di","wo","do","vr","za",'$we','!$we']};
return;
}
################################################################################
sub WeekdayTimer_Profile {
my $hash = shift // return;
my $language = $hash->{LANGUAGE};
my %longDays = %{$hash->{'.longDays'}};
delete $hash->{profil};
my $now = time;
my($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst)=localtime($now);
# ---- Zeitpunkte den Tagen zuordnen -----------------------------------
my $idx = 0;
for my $st ( @{$hash->{SWITCHINGTIMES}} ) {
my ($tage,$time,$parameter,$overrulewday) = WeekdayTimer_SwitchingTime ($hash, $st);
$idx++;
for my $d (@{$tage}) {
my @listeDerTage = ($d);
push (@listeDerTage, WeekdayTimer_getListeDerTage($hash, $d, $time)) if ($d>=7);
for my $day (@listeDerTage) {
my $dayOfEchteZeit = $day;
#####
if ($day < 7) {
my $relativeDay = ($day - $wday ) % 7;
#my $relativeDay = $day - $wday;
#$relativeDay = $relativeDay + 7 if $relativeDay < 0 ;
$dayOfEchteZeit = undef if ($hash->{helper}{WEDAYS}{$relativeDay} && $overrulewday);
}
$dayOfEchteZeit = ($wday>=1&&$wday<=5) ? 6 : $wday if ($day==7); # ggf. Samstag $wday ~~ [1..5]
$dayOfEchteZeit = ($wday==0||$wday==6) ? 1 : $wday if ($day==8); # ggf. Montag $wday ~~ [0, 6]
if (defined $dayOfEchteZeit) {
my $echtZeit = WeekdayTimer_EchteZeit($hash, $dayOfEchteZeit, $time);
$hash->{profile} {$day}{$echtZeit} = $parameter;
$hash->{profile_IDX}{$day}{$echtZeit} = $idx;
}
};
}
}
# ---- Zeitpunkte des aktuellen Tages mit EPOCH ermitteln --------------
$idx = 0;
for my $st (@{$hash->{SWITCHINGTIMES}}) {
my ($tage,$time,$parameter,$overrulewday) = WeekdayTimer_SwitchingTime ($hash, $st);
my $echtZeit = WeekdayTimer_EchteZeit ($hash, $wday, $time);
my ($stunde, $minute, $sekunde) = split m{:}xms, $echtZeit;
$idx++;
$hash->{profil}{$idx}{TIME} = $time;
$hash->{profil}{$idx}{PARA} = $parameter;
$hash->{profil}{$idx}{EPOCH} = getSwitchtimeEpoch ($now, $stunde, $minute, $sekunde, 0);
$hash->{profil}{$idx}{TAGE} = $tage;
$hash->{profil}{$idx}{WE_Override} = $overrulewday;
}
# ---- Texte Readings aufbauen -----------------------------------------
Log3( $hash, 4, "[$hash->{NAME}] " . sunrise_abs() . " " . sunset_abs() . " " . $longDays{$language}[$wday] );
for my $d (sort keys %{$hash->{profile}}) {
my $profiltext = q{};
for my $t (sort keys %{$hash->{profile}{$d}}) {
$profiltext .= "$t " . $hash->{profile}{$d}{$t} . ", ";
}
my $profilKey = "Profil $d: $longDays{$language}[$d]";
$profiltext =~ s{, $}{}xms;
$hash->{$profilKey} = $profiltext;
Log3( $hash, 4, "[$hash->{NAME}] $profiltext ($profilKey)" );
}
# für logProxy umhaengen
$hash->{helper}{SWITCHINGTIME} = $hash->{profile};
delete $hash->{profile};
return;
}
################################################################################
sub WeekdayTimer_getListeDerTage {
my ($hash, $d, $time) = @_;
my %hdays=();
if (AttrVal('global', 'holiday2we', '') !~ m{\bweekEnd\b}xms) {
@hdays{(0, 6)} = undef if ($d==7); # sa,so ( $we)
@hdays{(1..5)} = undef if ($d==8); # mo-fr (!$we)
} else {
@hdays{(0..6)} = undef if ($d==8); # mo-fr (!$we)
}
my ($sec,$min,$hour,$mday,$mon,$year,$nowWday,$yday,$isdst) = localtime(time);
for (0..6) {
my $relativeDay = ( $_ - $nowWday ) % 7;
if ($hash->{helper}{WEDAYS}{$relativeDay}) {
$hdays{$_} = undef if ($d==7); # $we Tag aufnehmen
delete $hdays{$_} if ($d==8); # !$we Tag herausnehmen
}
}
#Log 3, "result------------>" . join (" ", sort keys %hdays);
return keys %hdays;
}
################################################################################
sub WeekdayTimer_SwitchingTime {
my $hash = shift;
my $switchingtime = shift // return;
my $name = $hash->{NAME};
my $globalDaylistSpec = $hash->{GlobalDaylistSpec};
my @tageGlobal = @{WeekdayTimer_daylistAsArray($hash, $globalDaylistSpec)};
my (@st, $daylist, $time, $timeString, $para);
@st = split m{\|}xms, $switchingtime;
my $overrulewday = 0;
if ( @st == 2 || @st == 3 && $st[2] eq 'w') {
$daylist = ($globalDaylistSpec ne '') ? $globalDaylistSpec : '0123456';
$time = $st[0];
$para = $st[1];
$overrulewday = 1 if defined $st[2] && $st[2] eq 'w';
} elsif ( @st == 3 || @st == 4) {
$daylist = $st[0];
$time = $st[1];
$para = $st[2];
$overrulewday = 1 if defined $st[3] && $st[3] eq 'w';
}
my @tage = @{WeekdayTimer_daylistAsArray($hash, $daylist)};
#my $tage=@tage;
Log3( $hash, 1, "[$name] invalid daylist in $name <$daylist> use one of 012345678 or $hash->{helper}{daysRegExpMessage}" ) if !(@tage);
my %hdays=();
@hdays{@tageGlobal} = undef;
@hdays{@tage} = undef;
#@tage = sort keys %hdays;
#Log3 $hash, 3, "Tage: " . Dumper \@tage;
#return (\@tage,$time,$para,$overrulewday);
return ([sort keys %hdays], $time, $para, $overrulewday);
}
################################################################################
sub WeekdayTimer_daylistAsArray {
my ($hash, $daylist) = @_;
my $name = $hash->{NAME};
my @days;
my %hdays=();
$daylist = lc($daylist);
# Analysis of daylist setting by user
# first replace textual settings by numbers
if ( $daylist =~ m{\A($hash->{helper}{daysRegExp}(,|-|$)){0,7}\z}gxms ) {
my @subDays;
my @aufzaehlungen = split m{,}xms, $daylist;
for my $einzelAufzaehlung (@aufzaehlungen) {
@days = split m{-}xms, $einzelAufzaehlung;
if (@days == 1) {
#einzelner Tag: Sa
$hdays{$hash->{'.dayNumber'}{$days[0]}} = undef;
} else {
# von bis Angabe: Mo-Di
my $von = $hash->{'.dayNumber'}{$days[0]};
my $bis = $hash->{'.dayNumber'}{$days[1]};
if ($von <= $bis) {
@subDays = ($von .. $bis);
} else {
#@subDays = ($dayNumber{so} .. $bis, $von .. $dayNumber{sa});
# was until percritic: @subDays = ( 00 .. $bis, $von .. 06);
@subDays = ( 0 .. $bis, $von .. 6);
}
@hdays{@subDays}=undef;
}
}
if ($daylist =~ m{\$we.+\$we}xms && $daylist =~ m{\!\$we}xms) {
Log3( $hash, 4, "[$name] useless double setting of textual \$we and !\$we found" );
delete $hdays{8};
delete $hdays{7};
@subDays = (0..6);
@hdays{@subDays}=undef;
}
#replace all text in $daylist by numbers
$daylist = join q{}, sort keys %hdays;
}
# Angaben der Tage verarbeiten
# Aufzaehlung 1234 ...
if ( $daylist =~ m{\A[0-8]{0,9}\z}xms ) {
#avoid 78 settings:
if ($daylist =~ m{[7]}xms && $daylist =~ m{[8]}xms) {
Log3( $hash, 4, "[$name] useless double setting of \$we and !\$we found" );
$daylist = '0123456';
}
@days = split m{}x, $daylist;
@hdays{@days} = undef;
}
my @tage = sort keys %hdays;
return \@tage;
}
################################################################################
sub WeekdayTimer_EchteZeit {
my ($hash, $d, $time) = @_;
my $name = $hash->{NAME};
my $now = time;
my($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst)=localtime($now);
my $listOfDays = q{};
# Zeitangabe verarbeiten.
$time = qq{"$time"} if $time !~ m{\A\{.*\}\z}xms;
my $date = $now+($d-$wday)*DAYSECONDS;
my $timeString = '{ my $date='."$date;" .$time."}";
my $eTimeString = AnalyzePerlCommand( $hash, $timeString ); # must deliver HH:MM[:SS]
if ($@) {
$@ =~ s{\n}{ }gxms;
Log3( $hash, 3, "[$name] " . $@ . ">>>$timeString<<<" );
$eTimeString = "00:00:00";
}
if ($eTimeString =~ m{\A[0-2][0-9]:[0-5][0-9]\z}xms) { # HH:MM
$eTimeString .= ":00"; # HH:MM:SS erzeugen
} elsif ($eTimeString !~ m{\A[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\z}xms) { # not HH:MM:SS
Log3( $hash, 1, "[$name] invalid time <$eTimeString> HH:MM[:SS]" );
$eTimeString = "00:00:00";
}
return $eTimeString;
}
################################################################################
sub getSwitchtimeEpoch {
my ($now, $hour, $min, $sec, $days) = @_;
my @jetzt_arr = localtime($now);
#Stunden Minuten Sekunden
$jetzt_arr[2] = $hour; $jetzt_arr[1] = $min; $jetzt_arr[0] = $sec;
$jetzt_arr[3] += $days;
my $next = timelocal_nocheck(@jetzt_arr);
return $next;
}
################################################################################
sub gatherSwitchingTimes {
my $hash = shift;
my $arr = shift // return;
my $name = $hash->{NAME};
my @switchingtimes = ();
my $conditionOrCommand;
# switchingtime einsammeln
while ( @{ $arr } > 0 ) {
#pruefen auf Angabe eines Schaltpunktes
my $element = q{};
my @restoreElements = ();
E: while ( @{ $arr } > 0 ) {
my $actualElement = shift @{ $arr };
push @restoreElements, $actualElement;
#$element = $element . $actualElement . " ";
$element .= "$actualElement ";
Log3( $hash, 5, "[$name] $element - trying to accept as a switchtime" );
my $balancedSign1 = $element =~ tr/'//; #'
my $balancedSign2 = $element =~ tr/"//; #"
if ( $balancedSign1 % 2 || $balancedSign2 % 2 ) { # ungerade Anzahl quotes, dann verlängern
Log3( $hash, 5, "[$name] $element - unbalanced quotes: $balancedSign1 single and $balancedSign2 double quotes found" );
next E;
}
my $balancedSignA1 = $element =~ tr/(//;
my $balancedSignA2 = $element =~ tr/)//;
my $balancedSignB1 = $element =~ tr/{//;
my $balancedSignB2 = $element =~ tr/}//;
my $balancedSignA = $balancedSignA1 - $balancedSignA2;
my $balancedSignB = $balancedSignB1 - $balancedSignB2;
if ( $balancedSignA || $balancedSignB ) { # öffnende/schließende Klammern nicht gleich, dann verlängern
Log3( $hash, 5, "[$name] $element - unbalanced brackets (: $balancedSignA1 ): $balancedSignA2 {: $balancedSignB1 }: $balancedSignB2" );
next E;
}
last;
}
# ein space am Ende wieder abschneiden
chop $element;
my @t = split m{\|}xms, $element;
if ( (@t > 1 && @t < 5) && $t[0] ne '' && $t[1] ne '' ) {
Log3( $hash, 4, "[$name] $element - accepted");
#transform daylist to pure nummeric notation
if ( @t > 2) {
$t[0] = join q{}, @{WeekdayTimer_daylistAsArray($hash, $t[0])};
if ( $t[0] eq '' ) {
$t[0] = '0123456' ;
Log3( $hash, 2, "[$name] $element seems to be not valid and has been replaced by all days!");
}
$element = join q{|}, @t;
}
push(@switchingtimes, $element);
} elsif ($element =~ m{\Aweekprofile}xms ) {
my @wprof = split m{:}xms, $element;
my $wp_name = $wprof[1];
my ($unused,$wp_profile) = split m{:}xms, getWeekprofileReadingTriplett($hash, $wp_name, $wprof[2]),2;
($unused,$wp_profile) = split m{:}xms, getWeekprofileReadingTriplett($hash, $wp_name, 'default'),2 if !$wp_profile && $wprof[2] ne 'default';
return if !$wp_profile;
my $wp_sunaswe = $wprof[2] // 0;
my $wp_profile_data = CommandGet(undef,"$wp_name profile_data $wp_profile 0");
if ($wp_profile_data =~ m{(profile.*not.found|usage..profile_data..name)}xms ) {
Log3( $hash, 3, "[$name] weekprofile $wp_name: no profile named \"$wp_profile\" available" );
return;
}
my $wp_profile_unpacked = decode_json($wp_profile_data);
$hash->{weekprofiles}{$wp_name} = {'PROFILE'=>$wp_profile,'PROFILE_JSON'=>$wp_profile_data,'SunAsWE'=>$wp_sunaswe,'PROFILE_DATA'=>$wp_profile_unpacked };
my %wp_shortDays = ("Mon"=>1,"Tue"=>2,"Wed"=>3,"Thu"=>4,"Fri"=>5,"Sat"=>6,"Sun"=>0);
for my $wp_days (sort keys %{$hash->{weekprofiles}{$wp_name}{PROFILE_DATA}}) {
my $wp_times = $hash->{weekprofiles}{$wp_name}{PROFILE_DATA}{$wp_days}{time};
my $wp_temps = $hash->{weekprofiles}{$wp_name}{PROFILE_DATA}{$wp_days}{temp};
my $wp_shortDay = $wp_shortDays{$wp_days};
for ( 0..@{ $wp_temps }-1 ) {
my $itime = $_ ? $hash->{weekprofiles}{$wp_name}{PROFILE_DATA}{$wp_days}{time}[$_-1]
: '00:10';
my $itemp = $hash->{weekprofiles}{$wp_name}{PROFILE_DATA}{$wp_days}{temp}[$_];
my $wp_dayprofile = "$wp_shortDay"."|$itime" . "|$itemp";
$wp_dayprofile .= "|w" if $wp_sunaswe eq "true";
push(@switchingtimes, $wp_dayprofile);
if ($wp_sunaswe eq "true" && !$wp_shortDay) {
$wp_dayprofile = "7|$itime" . "|$itemp";
push(@switchingtimes, $wp_dayprofile);
}
}
}
} else {
Log3( $hash, 4, "[$name] $element - NOT accepted, must be command or condition" );
unshift @{ $arr }, @restoreElements;
last;
}
}
return (@switchingtimes);
}
################################################################################
sub getWDTLanguage {
my ($hash, $arr) = @_;
my $name = $hash->{NAME};
# ggf. language optional Parameter
my $langRegExp = "(" . join ( q{|}, keys(%{$hash->{'.shortDays'}})) . ")";
my $language = shift @{ $arr };
if ( $language !~ m{\A$langRegExp\z}xms ) {
Log3( $hash, 3, "[$name] language: $language not recognized, use one of $langRegExp" ) if ( length($language) == 2 && $language !~ m{\A[0-9]+\z}gmx );
unshift @{ $arr }, $language;
$language = lc(AttrVal('global','language','en'));
$language = $language =~ m{\A$langRegExp\z}xms ? $language : 'en';
}
$hash->{LANGUAGE} = $language;
return ($langRegExp, $language);
}
################################################################################
sub WeekdayTimer_GlobalDaylistSpec {
my ($hash, $arr) = @_;
my $daylist = shift @{ $arr };
my @tage = @{ WeekdayTimer_daylistAsArray( $hash, $daylist ) };
unshift @{ $arr }, $daylist if !@tage;
$hash->{GlobalDaylistSpec} = join q{}, @tage;
return;
}
################################################################################
sub WeekdayTimer_SetTimerForMidnightUpdate {
my $fnHash = shift;
my $hash = $fnHash->{HASH} // $fnHash;
return if !defined $hash;
my $now = time;
my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime($now);
my $midnightPlus5Seconds = getSwitchtimeEpoch ($now, 0, 0, 5, 1);
RemoveInternalTimer($hash,\&WeekdayTimer_SetTimerOfDay);
InternalTimer($midnightPlus5Seconds, \&WeekdayTimer_SetTimerOfDay, $hash, 0) if !AttrVal($hash->{NAME},'disable',0);
$hash->{SETTIMERATMIDNIGHT} = 1;
return;
}
################################################################################
sub WeekdayTimer_SetTimerOfDay {
my $fnHash = shift // return;
my $hash = $fnHash->{HASH} // $fnHash;
return if (!defined($hash));
my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime(time);
my $secSinceMidnight = 3600*$hour + 60*$min + $sec;
my %wedays =();
my $iswe = IsWe();
$wedays{(0)} = $iswe if $iswe;
$iswe = IsWe('tomorrow');
$wedays{(1)} = $iswe if $iswe;
for (2..6) {
my $noWeekEnd = 0;
my $ergebnis = 'none';
my $izeit = time + DAYSECONDS * $_;
my ($isec,$imin,$ihour,$imday,$imon,$iyear,$iwday,$iyday,$iisdst) = localtime($izeit);
for my $h2we (split m{,}xms, AttrVal('global', 'holiday2we', '')) {
if($h2we && ( $ergebnis eq 'none' || $h2we eq "noWeekEnd" ) && InternalVal($h2we, 'TYPE', '') eq 'holiday' && !$noWeekEnd) {
$ergebnis = CommandGet(undef,$h2we . ' ' . sprintf("%02d-%02d",$imon+1,$imday));
if ($ergebnis ne 'none' && $h2we eq 'noWeekEnd') {
$ergebnis = 'none';
$noWeekEnd = 1;
}
}
}
if ($ergebnis ne 'none') {
$wedays{$_} = $ergebnis ;
} else {
if ($iwday == 0 || $iwday == 6) {
$wedays{$_} = 1;
delete $wedays{$_} if AttrVal('global', 'holiday2we', '') =~ m{\bweekEnd\b}xms;
} else {
delete $wedays{$_};
}
}
}
$hash->{helper}{WEDAYS} = \%wedays;
$hash->{SETTIMERATMIDNIGHT} = $fnHash->{SETTIMERATMIDNIGHT};
WeekdayTimer_DeleteTimer($hash);
WeekdayTimer_Profile ($hash);
WeekdayTimer_SetTimer ($hash) if !AttrVal($hash->{NAME},'disable',0);
delete $hash->{SETTIMERATMIDNIGHT};
WeekdayTimer_SetTimerForMidnightUpdate( $hash );
return;
}
################################################################################
sub WeekdayTimer_SetTimer {
my $hash = shift // return;
my $name = $hash->{NAME};
my $now = time;
my $isHeating = checkIfDeviceIsHeatingType($hash);
my $swip = AttrVal($name, 'switchInThePast', 0);
my $switchInThePast = ($swip || $isHeating);
Log3( $hash, 4, "[$name] Heating recognized - switch in the past activated" ) if ($isHeating);
Log3( $hash, 4, "[$name] no switch in the yesterdays because of the devices type($hash->{DEVICE} is not recognized as heating) - use attr switchInThePast" ) if ( !$switchInThePast && !defined $hash->{SETTIMERATMIDNIGHT} );
my @switches = sort keys %{$hash->{profil}};
return Log3( $hash, 3, "[$name] no switches to send, due to possible errors." ) if !@switches;
readingsSingleUpdate ($hash, 'state', 'inactive', 1) if (!defined $hash->{SETTIMERATMIDNIGHT});
for(my $i=0; $i<=$#switches; $i++) {
my $idx = $switches[$i];
my $time = $hash->{profil}{$idx}{TIME};
my $timToSwitch = $hash->{profil}{$idx}{EPOCH};
my $tage = $hash->{profil}{$idx}{TAGE};
my $para = $hash->{profil}{$idx}{PARA};
my $overrulewday = $hash->{profil}{$idx}{WE_Override};
my $isActiveTimer = isAnActiveTimer ($hash, $tage, $para, $overrulewday);
readingsSingleUpdate ($hash, 'state', 'active', 1)
if (!defined $hash->{SETTIMERATMIDNIGHT} && $isActiveTimer);
if ( $timToSwitch - $now > -5 || defined $hash->{SETTIMERATMIDNIGHT} ) {
if($isActiveTimer) {
Log3( $hash, 4, "[$name] setTimer - timer seems to be active today: ".join( q{},@{$tage})."|$time|$para" );
resetRegisteredInternalTimer("$idx", $timToSwitch + AttrVal($name,'WDT_sendDelay',0), \&WeekdayTimer_Update, $hash, 0);
} else {
Log3( $hash, 4, "[$name] setTimer - timer seems to be NOT active today: ".join(q{},@{$tage})."|$time|$para ". $hash->{CONDITION} );
deleteSingleRegisteredInternalTimer("$idx", $hash);
}
}
}
return if defined $hash->{SETTIMERATMIDNIGHT};
my ($aktIdx,$aktTime,$aktParameter,$nextTime,$nextParameter) =
WeekdayTimer_searchAktNext($hash, time + 5);
Log3( $hash, 3, "[$name] can not compute past switching time" ) if !defined $aktTime;
readingsBeginUpdate($hash);
readingsBulkUpdate ($hash, 'nextUpdate', FmtDateTime($nextTime));
readingsBulkUpdate ($hash, 'nextValue', $nextParameter);
readingsBulkUpdate ($hash, 'currValue', $aktParameter);
readingsEndUpdate ($hash, 1);
return if !$switchInThePast || !defined $aktTime || checkDelayedExecution($hash, $aktParameter, $aktIdx );
# alle in der Vergangenheit liegenden Schaltungen sammeln und
# nach 5 Sekunden in der Reihenfolge der Schaltzeiten
# durch WeekdayTimer_delayedTimerInPast() als Timer einstellen
# die Parameter merken wir uns kurzzeitig im hash
# modules{WeekdayTimer}{timerInThePast}
my $device = $hash->{DEVICE};
Log3( $hash, 4, "[$name] past timer on $hash->{DEVICE} at ". FmtDateTime($aktTime). " with $aktParameter activated" );
#my $parameter = $modules{WeekdayTimer}{timerInThePast}{$device}{$aktTime} // [];
my $parameter = $hash->{helper}{timerInThePast}{$aktTime} // [];
push @{$parameter},["$aktIdx", $aktTime, \&WeekdayTimer_Update, $hash, 0];
$hash->{helper}{timerInThePast}{$device}{$aktTime} = $parameter;
#$modules{WeekdayTimer}{timerInThePast}{$device}{$aktTime} = $parameter;
#my $tipHash = $modules{WeekdayTimer}{timerInThePastHash} // $hash;
my $tipHash = $hash->{helper}{timerInThePastHash} // $hash;
#$tipHash = $hash if !defined $tipHash;
#$modules{WeekdayTimer}{timerInThePastHash} = $tipHash;
$tipHash = $hash->{helper}{timerInThePastHash} = $tipHash;
resetRegisteredInternalTimer('delayed', time + 5 + AttrVal($name,'WDT_sendDelay',0), \&WeekdayTimer_delayedTimerInPast, $tipHash, 0);
return;
}
################################################################################
sub WeekdayTimer_delayedTimerInPast {
my $fnHash = shift // return;
my ($hash, $modifier) = ($fnHash->{HASH}, $fnHash->{MODIFIER});
return if !defined($hash);
my $tim = time;
#my $tipIpHash = $modules{WeekdayTimer}{timerInThePast};
my $tipIpHash = $hash->{helper}{timerInThePast};
for my $device ( keys %{$tipIpHash} ) {
for my $time ( sort keys %{$tipIpHash->{$device}} ) {
Log3( $hash, 4, "[$hash->{NAME}] $device ".FmtDateTime($time)." ".($tim-$time)."s " );
for my $para ( @{$tipIpHash->{$device}{$time}} ) {
my $mHash = resetRegisteredInternalTimer(@{$para}[0],@{$para}[1],@{$para}[2],@{$para}[3],@{$para}[4]);
$mHash->{forceSwitch} = 1;
}
}
}
#delete $modules{WeekdayTimer}{timerInThePast};
#delete $modules{WeekdayTimer}{timerInThePastHash};
delete $hash->{helper}{timerInThePast};
delete $hash->{helper}{timerInThePastHash};
return;
}
################################################################################
sub WeekdayTimer_searchAktNext {
my ($hash, $now) = @_;
my $name = $hash->{NAME};
my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime($now);
#Log3 $hash, 3, "[$name] such--->".FmtDateTime($now);
my ($oldTag, $oldTime, $oldPara , $oldIdx);
my ($nextTag, $nextTime, $nextPara, $nextIdx);
my $language = $hash->{LANGUAGE};
my %shortDays = %{$hash->{'.shortDays'}};
my @realativeWdays = ($wday..6,0..$wday-1,$wday..6,0..6);
for (my $i=0;$i<=$#realativeWdays;$i++) {
my $relativeDay = $i-7;
my $relWday = $realativeWdays[$i];
for my $time (sort keys %{$hash->{helper}{SWITCHINGTIME}{$relWday}}) {
my ($stunde, $minute, $sekunde) = split m{:}xms, $time;
$oldTime = $nextTime;
$oldPara = $nextPara;
$oldIdx = $nextIdx;
$oldTag = $nextTag;
$nextTime = getSwitchtimeEpoch ($now, $stunde, $minute, $sekunde, $relativeDay);
$nextPara = $hash->{helper}{SWITCHINGTIME}{$relWday}{$time};
#$nextIdx = $hash->{helper}{SWITCHINGTIME}{$relWday}{$time};
$nextIdx = $hash->{profile_IDX}{$relWday}{$time};
$nextTag = $relWday;
#Log3 $hash, 3, $shortDays{$language}[$nextTag]." ".FmtDateTime($nextTime)." ".$nextPara." ".$nextIdx;
my $ignore = 0;
my $wend = 0;
my $tage = $hash->{profil}{$nextIdx}{TAGE}[0];
if ($wday==$relWday) {
$wend = $hash->{helper}{WEDAYS}{0};
$ignore = (($tage == 7 && !$wend ) || ($tage == 8 && $wend ));
} elsif ( $wday==$relWday+1) {
$wend = $hash->{helper}{WEDAYS}{1};
$ignore = (($tage == 7 && !$wend ) || ($tage == 8 && $wend ));
}
if (!$ignore && $nextTime >= $now ) {
return ($oldIdx, $oldTime, $oldPara, $nextTime, $nextPara);
}
}
}
return (undef,undef,undef,undef);
}
################################################################################
sub WeekdayTimer_DeleteTimer {
my $hash = shift // return;
map {deleteSingleRegisteredInternalTimer($_, $hash)} keys %{$hash->{profil}};
return;
}
################################################################################
sub WeekdayTimer_Update {
my $fnHash = shift // return;
my $hash = $fnHash->{HASH} // $fnHash;