-
Notifications
You must be signed in to change notification settings - Fork 299
/
global-functions.rsc
1637 lines (1375 loc) · 46.5 KB
/
global-functions.rsc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#!rsc by RouterOS
# RouterOS script: global-functions
# Copyright (c) 2013-2025 Christian Hesse <[email protected]>
# Michael Gisbers <[email protected]>
# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
#
# requires RouterOS, version=7.14
#
# global functions
# https://git.eworm.de/cgit/routeros-scripts/about/
:local ScriptName [ :jobname ];
# expected configuration version
:global ExpectedConfigVersion 131;
# global variables not to be changed by user
:global GlobalFunctionsReady false;
:global Identity [ /system/identity/get name ];
# global functions
:global AlignRight;
:global CertificateAvailable;
:global CertificateDownload;
:global CertificateNameByCN;
:global CharacterMultiply;
:global CharacterReplace;
:global CleanFilePath;
:global CleanName;
:global DeviceInfo;
:global Dos2Unix;
:global DownloadPackage;
:global EitherOr;
:global EscapeForRegEx;
:global ExitError;
:global FetchHuge;
:global FetchUserAgentStr;
:global FormatLine;
:global FormatMultiLines;
:global GetMacVendor;
:global GetRandom20CharAlNum;
:global GetRandom20CharHex;
:global GetRandomNumber;
:global Grep;
:global HexToNum;
:global HumanReadableNum;
:global IfThenElse;
:global IsDefaultRouteReachable;
:global IsDNSResolving;
:global IsFullyConnected;
:global IsMacLocallyAdministered;
:global IsTimeSync;
:global LogPrint;
:global LogPrintOnce;
:global MAX;
:global MIN;
:global MkDir;
:global NotificationFunctions;
:global ParseDate;
:global ParseKeyValueStore;
:global PrettyPrint;
:global ProtocolStrip;
:global RandomDelay;
:global RequiredRouterOS;
:global ScriptFromTerminal;
:global ScriptInstallUpdate;
:global ScriptLock;
:global SendNotification;
:global SendNotification2;
:global SymbolByUnicodeName;
:global SymbolForNotification;
:global Unix2Dos;
:global UrlEncode;
:global ValidateSyntax;
:global VersionToNum;
:global WaitDefaultRouteReachable;
:global WaitDNSResolving;
:global WaitForFile;
:global WaitFullyConnected;
:global WaitTimeSync;
# align string to the right
:set AlignRight do={
:local Input [ :tostr $1 ];
:local Len [ :tonum $2 ];
:global CharacterMultiply;
:global EitherOr;
:set Len [ $EitherOr $Len 8 ];
:local Spaces [ $CharacterMultiply " " $Len ];
:return ([ :pick $Spaces 0 ($Len - [ :len $Input ]) ] . $Input);
}
# check and download required certificate
:set CertificateAvailable do={
:local CommonName [ :tostr $1 ];
:global CertificateDownload;
:global LogPrint;
:global ParseKeyValueStore;
:if ([ /system/resource/get free-hdd-space ] < 8388608 && \
[ /certificate/settings/get crl-download ] = true && \
[ /certificate/settings/get crl-store ] = "system") do={
$LogPrint warning $0 ("This system has low free flash space but " . \
"is configured to download certificate CRLs to system!");
}
:if ([ :len $CommonName ] = 0) do={
$LogPrint warning $0 ("No CommonName given!");
:return false;
}
:if ([ :len [ /certificate/find where common-name=$CommonName ] ] = 0) do={
$LogPrint info $0 ("Certificate with CommonName '" . $CommonName . "' not available.");
:if ([ $CertificateDownload $CommonName ] = false) do={
:return false;
}
}
:local CertVal [ /certificate/get [ find where common-name=$CommonName ] ];
:while (($CertVal->"akid") != "" && ($CertVal->"akid") != ($CertVal->"skid")) do={
:if ([ :len [ /certificate/find where skid=($CertVal->"akid") ] ] = 0) do={
$LogPrint info $0 ("Certificate chain for '" . $CommonName . \
"' is incomplete, missing '" . ([ $ParseKeyValueStore ($CertVal->"issuer") ]->"CN") . "'.");
:if ([ $CertificateDownload $CommonName ] = false) do={
:return false;
}
}
:set CertVal [ /certificate/get [ find where skid=($CertVal->"akid") ] ];
}
:return true;
}
# download and import certificate
:set CertificateDownload do={
:local CommonName [ :tostr $1 ];
:global ScriptUpdatesBaseUrl;
:global ScriptUpdatesUrlSuffix;
:global CertificateAvailable;
:global CertificateNameByCN;
:global CleanName;
:global FetchUserAgentStr;
:global LogPrint;
:global WaitForFile;
$LogPrint info $0 ("Downloading and importing certificate with " . \
"CommonName '" . $CommonName . "'.");
:local FileName ([ $CleanName $CommonName ] . ".pem");
:do {
/tool/fetch check-certificate=yes-without-crl http-header-field=({ [ $FetchUserAgentStr $0 ] }) \
($ScriptUpdatesBaseUrl . "certs/" . $FileName . $ScriptUpdatesUrlSuffix) \
dst-path=$FileName as-value;
$WaitForFile $FileName;
} on-error={
$LogPrint warning $0 ("Failed downloading certificate with CommonName '" . $CommonName . \
"' from repository! Trying fallback to mkcert.org...");
:do {
:if ([ $CertificateAvailable "ISRG Root X1" ] = false) do={
$LogPrint error $0 ("Downloading required certificate failed.");
:return false;
}
/tool/fetch check-certificate=yes-without-crl http-header-field=({ [ $FetchUserAgentStr $0 ] }) \
"https://mkcert.org/generate/" http-data=[ :serialize to=json ({ $CommonName }) ] \
dst-path=$FileName as-value;
$WaitForFile $FileName;
:if ([ /file/get $FileName size ] = 0) do={
/file/remove $FileName;
:error false;
}
} on-error={
$LogPrint warning $0 ("Failed downloading certificate with CommonName '" . $CommonName . "'!");
:return false;
}
}
/certificate/import file-name=$FileName passphrase="" as-value;
:delay 1s;
/file/remove [ find where name=$FileName ];
:if ([ :len [ /certificate/find where common-name=$CommonName ] ] = 0) do={
/certificate/remove [ find where name~("^" . $FileName . "_[0-9]+\$") ];
$LogPrint warning $0 ("Certificate with CommonName '" . $CommonName . "' still unavailable!");
:return false;
}
:foreach Cert in=[ /certificate/find where name~("^" . $FileName . "_[0-9]+\$") ] do={
$CertificateNameByCN [ /certificate/get $Cert common-name ];
}
:return true;
}
# name a certificate by its common-name
:set CertificateNameByCN do={
:local CommonName [ :tostr $1 ];
:global CleanName;
:local Cert [ /certificate/find where common-name=$CommonName ];
/certificate/set $Cert name=[ $CleanName $CommonName ];
}
# multiply given character(s)
:set CharacterMultiply do={
:local Return "";
:for I from=1 to=$2 do={
:set Return ($Return . $1);
}
:return $Return;
}
# character replace
:set CharacterReplace do={
:local String [ :tostr $1 ];
:local ReplaceFrom [ :tostr $2 ];
:local ReplaceWith [ :tostr $3 ];
:local Return "";
:if ($ReplaceFrom = "") do={
:return $String;
}
:while ([ :typeof [ :find $String $ReplaceFrom ] ] != "nil") do={
:local Pos [ :find $String $ReplaceFrom ];
:set Return ($Return . [ :pick $String 0 $Pos ] . $ReplaceWith);
:set String [ :pick $String ($Pos + [ :len $ReplaceFrom ]) [ :len $String ] ];
}
:return ($Return . $String);
}
# clean file path
:set CleanFilePath do={
:local Path [ :tostr $1 ];
:global CharacterReplace;
:while ($Path ~ "//") do={
:set $Path [ $CharacterReplace $Path "//" "/" ];
}
:if ([ :pick $Path 0 ] = "/") do={
:set Path [ :pick $Path 1 [ :len $Path ] ];
}
:if ([ :pick $Path ([ :len $Path ] - 1) ] = "/") do={
:set Path [ :pick $Path 0 ([ :len $Path ] - 1) ];
}
:return $Path;
}
# clean name for DNS, file and more
:set CleanName do={
:local Input [ :tostr $1 ];
:local Return "";
:for I from=0 to=([ :len $Input ] - 1) do={
:local Char [ :pick $Input $I ];
:if ([ :typeof [ find "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789" $Char ] ] = "nil") do={
:do {
:if ([ :len $Return ] = 0) do={
:error true;
}
:if ([ :pick $Return ([ :len $Return ] - 1) ] = "-") do={
:error true;
}
:set Char "-";
} on-error={
:set Char "";
}
}
:set Return ($Return . $Char);
}
:return $Return;
}
# get readable device info
:set DeviceInfo do={
:global ExpectedConfigVersion;
:global Identity;
:global IfThenElse;
:global FormatLine;
:local License [ /system/license/get ];
:local Resource [ /system/resource/get ];
:local RouterBoard;
:do {
:set RouterBoard [[ :parse "/system/routerboard/get" ]];
} on-error={ }
:local Snmp [ /snmp/get ];
:local Update [ /system/package/update/get ];
:return ( \
[ $FormatLine "Hostname" $Identity ] . "\n" . \
[ $IfThenElse ([ :len ($Snmp->"location") ] > 0) \
([ $FormatLine "Location" ($Snmp->"location") ] . "\n") ] . \
[ $IfThenElse ([ :len ($Snmp->"contact") ] > 0) \
([ $FormatLine "Contact" ($Snmp->"contact") ] . "\n") ] . \
[ $FormatLine "Board name" ($Resource->"board-name") ] . "\n" . \
[ $FormatLine "Architecture" ($Resource->"architecture-name") ] . "\n" . \
[ $IfThenElse ($RouterBoard->"routerboard" = true) \
([ $FormatLine "Model" ($RouterBoard->"model") ] . \
[ $IfThenElse ([ :len ($RouterBoard->"revision") ] > 0) \
(" " . $RouterBoard->"revision") ] . "\n" . \
[ $FormatLine "Serial number" ($RouterBoard->"serial-number") ] . "\n") ] . \
[ $IfThenElse ([ :len ($License->"level") ] > 0) \
([ $FormatLine "License" ($License->"level") ] . "\n") ] . \
"RouterOS:\n" . \
[ $FormatLine " Channel" ($Update->"channel") ] . "\n" . \
[ $FormatLine " Installed" ($Update->"installed-version") ] . "\n" . \
[ $IfThenElse ([ :typeof ($Update->"latest-version") ] != "nothing" && \
$Update->"installed-version" != $Update->"latest-version") \
([ $FormatLine " Available" ($Update->"latest-version") ] . "\n") ] . \
[ $IfThenElse ($RouterBoard->"routerboard" = true && \
$RouterBoard->"current-firmware" != $RouterBoard->"upgrade-firmware") \
([ $FormatLine " Firmware" ($RouterBoard->"current-firmware") ] . "\n") ] . \
"RouterOS-Scripts:\n" . \
[ $FormatLine " Version" $ExpectedConfigVersion ]);
}
# convert line endings, DOS -> UNIX
:set Dos2Unix do={
:return [ :tolf [ :tostr $1 ] ];
}
# download package from upgrade server
:set DownloadPackage do={
:local PkgName [ :tostr $1 ];
:local PkgVer [ :tostr $2 ];
:local PkgArch [ :tostr $3 ];
:local PkgDir [ :tostr $4 ];
:global CertificateAvailable;
:global CleanFilePath;
:global LogPrint;
:global MkDir;
:global WaitForFile;
:if ([ :len $PkgName ] = 0) do={ :return false; }
:if ([ :len $PkgVer ] = 0) do={ :set PkgVer [ /system/package/update/get installed-version ]; }
:if ([ :len $PkgArch ] = 0) do={ :set PkgArch [ /system/resource/get architecture-name ]; }
:if ($PkgName = "system") do={ :set PkgName "routeros"; }
:local PkgFile ($PkgName . "-" . $PkgVer . "-" . $PkgArch . ".npk");
:if ($PkgArch = "x86_64") do={ :set PkgFile ($PkgName . "-" . $PkgVer . ".npk"); }
:local PkgDest [ $CleanFilePath ($PkgDir . "/" . $PkgFile) ];
:if ([ $MkDir $PkgDir ] = false) do={
$LogPrint warning $0 ("Failed creating directory, not downloading package.");
:return false;
}
:if ([ :len [ /file/find where name=$PkgDest type="package" ] ] > 0) do={
$LogPrint info $0 ("Package file " . $PkgName . " already exists.");
:return true;
}
:if ([ $CertificateAvailable "ISRG Root X1" ] = false) do={
$LogPrint error $0 ("Downloading required certificate failed.");
:return false;
}
:local Url ("https://upgrade.mikrotik.com/routeros/" . $PkgVer . "/" . $PkgFile);
$LogPrint info $0 ("Downloading package file '" . $PkgName . "'...");
$LogPrint debug $0 ("... from url: " . $Url);
:local Retry 3;
:while ($Retry > 0) do={
:do {
/tool/fetch check-certificate=yes-without-crl $Url dst-path=$PkgDest;
$WaitForFile $PkgDest;
:if ([ /file/get [ find where name=$PkgDest ] type ] = "package") do={
:return true;
}
} on-error={
$LogPrint debug $0 ("Downloading package file failed.");
}
/file/remove [ find where name=$PkgDest ];
:set Retry ($Retry - 1);
}
$LogPrint warning $0 ("Downloading package file '" . $PkgName . "' failed.");
:return false;
}
# return either first (if "true") or second
:set EitherOr do={
:global IfThenElse;
:if ([ :typeof $1 ] = "num") do={
:return [ $IfThenElse ($1 != 0) $1 $2 ];
}
:if ([ :typeof $1 ] = "time") do={
:return [ $IfThenElse ($1 > 0s) $1 $2 ];
}
# this works for boolean values, literal ones with parentheses
:return [ $IfThenElse ([ :len [ :tostr $1 ] ] > 0) $1 $2 ];
}
# escape for regular expression
:set EscapeForRegEx do={
:local Input [ :tostr $1 ];
:if ([ :len $Input ] = 0) do={
:return "";
}
:local Return "";
:local Chars ("^.[]\$()|*+?{}\\");
:for I from=0 to=([ :len $Input ] - 1) do={
:local Char [ :pick $Input $I ];
:if ([ :find $Chars $Char ]) do={
:set Char ("\\" . $Char);
}
:set Return ($Return . $Char);
}
:return $Return;
}
# simple macro to print error message on unintentional error
:set ExitError do={
:local ExitOK [ :tostr $1 ];
:local Name [ :tostr $2 ];
:global IfThenElse;
:global LogPrint;
:if ($ExitOK = "false") do={
$LogPrint error $Name ([ $IfThenElse ([ :pick $Name 0 1 ] = "\$") \
"Function" "Script" ] . " '" . $Name . "' exited with error.");
}
}
# fetch huge data to file, read in chunks
:set FetchHuge do={
:local ScriptName [ :tostr $1 ];
:local Url [ :tostr $2 ];
:local CheckCert [ :tostr $3 ];
:global CleanName;
:global FetchUserAgentStr;
:global GetRandom20CharAlNum;
:global IfThenElse;
:global LogPrint;
:global MkDir;
:global WaitForFile;
:set CheckCert [ $IfThenElse ($CheckCert = "false") "no" "yes-without-crl" ];
:local DirName ("tmpfs/" . [ $CleanName $ScriptName ]);
:if ([ $MkDir $DirName ] = false) do={
$LogPrint error $0 ("Failed creating directory!");
:return false;
}
:local FileName ($DirName . "/" . [ $CleanName $0 ] . "-" . [ $GetRandom20CharAlNum ]);
:do {
/tool/fetch check-certificate=$CheckCert $Url dst-path=$FileName \
http-header-field=({ [ $FetchUserAgentStr $ScriptName ] }) as-value;
} on-error={
:if ([ $WaitForFile $FileName 500ms ] = true) do={
/file/remove $FileName;
}
$LogPrint debug $0 ("Failed downloading from: " . $Url);
/file/remove $DirName;
:return false;
}
$WaitForFile $FileName;
:local FileSize [ /file/get $FileName size ];
:local Return "";
:local VarSize 0;
:while ($VarSize != $FileSize) do={
:set Return ($Return . ([ /file/read offset=$VarSize chunk-size=32768 file=$FileName as-value ]->"data"));
:set FileSize [ /file/get $FileName size ];
:set VarSize [ :len $Return ];
:if ($VarSize > $FileSize) do={
:delay 100ms;
}
}
/file/remove $DirName;
:return $Return;
}
# generate user agent string for fetch
:set FetchUserAgentStr do={
:local Caller [ :tostr $1 ];
:local Resource [ /system/resource/get ];
:return ("User-Agent: Mikrotik/" . $Resource->"version" . " " . \
$Resource->"architecture-name" . " " . $Caller . "/Fetch (https://rsc.eworm.de/)");
}
# format a line for output
:set FormatLine do={
:local Key [ :tostr $1 ];
:local Value [ :tostr $2 ];
:local Indent [ :tonum $3 ];
:local Spaces;
:local Return "";
:global CharacterMultiply;
:global EitherOr;
:set Indent [ $EitherOr $Indent 16 ];
:local Spaces [ $CharacterMultiply " " $Indent ];
:if ([ :len $Key ] > 0) do={ :set Return ($Key . ":"); }
:if ([ :len $Key ] > ($Indent - 2)) do={
:set Return ($Return . "\n" . [ :pick $Spaces 0 $Indent ] . $Value);
} else={
:set Return ($Return . [ :pick $Spaces 0 ($Indent - [ :len $Return ]) ] . $Value);
}
:return $Return;
}
# format multiple lines for output
:set FormatMultiLines do={
:local Key [ :tostr $1 ];
:local Values [ :toarray $2 ];
:local Indent [ :tonum $3 ];
:local Return;
:global FormatLine;
:set Return [ $FormatLine $Key ($Values->0) $Indent ];
:foreach Value in=[ :pick $Values 1 [ :len $Values ] ] do={
:set Return ($Return . "\n" . [ $FormatLine "" $Value $Indent ]);
}
:return $Return;
}
# get MAC vendor
:set GetMacVendor do={
:local Mac [ :tostr $1 ];
:global CertificateAvailable;
:global IsMacLocallyAdministered;
:global LogPrint;
:if ([ $IsMacLocallyAdministered $Mac ] = true) do={
:return "locally administered";
}
:do {
:if ([ $CertificateAvailable "GTS Root R4" ] = false) do={
$LogPrint warning $0 ("Downloading required certificate failed.");
:error false;
}
:local Vendor ([ /tool/fetch check-certificate=yes-without-crl \
("https://api.macvendors.com/" . [ :pick $Mac 0 8 ]) output=user as-value ]->"data");
:return $Vendor;
} on-error={
:do {
/tool/fetch check-certificate=yes-without-crl ("https://api.macvendors.com/") \
output=none as-value;
$LogPrint debug $0 ("The mac vendor is not known in database.");
} on-error={
$LogPrint warning $0 ("Failed getting mac vendor.");
}
:return "unknown vendor";
}
}
# generate random 20 chars alphabetical (A-Z & a-z) and numerical (0-9)
:set GetRandom20CharAlNum do={
:global EitherOr;
:return [ :rndstr length=[ $EitherOr [ :tonum $1 ] 20 ] from="ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789" ];
}
# generate random 20 chars hex (0-9 and a-f)
:set GetRandom20CharHex do={
:global EitherOr;
:return [ :rndstr length=[ $EitherOr [ :tonum $1 ] 20 ] from="0123456789abcdef" ];
}
# generate random number
:set GetRandomNumber do={
:global EitherOr;
:return [ :rndnum from=0 to=[ $EitherOr [ :tonum $1 ] 4294967295 ] ];
}
# return first line that matches a pattern
:set Grep do={
:local Input ([ :tostr $1 ] . "\n");
:local Pattern [ :tostr $2 ];
:if ([ :typeof [ :find $Input $Pattern ] ] = "nil") do={
:return [];
}
:do {
:local Line [ :pick $Input 0 [ :find $Input "\n" ] ];
:if ([ :typeof [ :find $Line $Pattern ] ] = "num") do={
:return $Line;
}
:set Input [ :pick $Input ([ :find $Input "\n" ] + 1) [ :len $Input ] ];
} while=([ :len $Input ] > 0);
:return [];
}
# convert from hex (string) to num
:set HexToNum do={
:local Input [ :tostr $1 ];
:global HexToNum;
:if ([ :pick $Input 0 ] = "*") do={
:return [ $HexToNum [ :pick $Input 1 [ :len $Input ] ] ];
}
:return [ :tonum ("0x" . $Input) ];
}
# return human readable number
:set HumanReadableNum do={
:local Input [ :tonum $1 ];
:local Base [ :tonum $2 ];
:global EitherOr;
:global IfThenElse;
:local Prefix "kMGTPE";
:local Pow 1;
:set Base [ $EitherOr $Base 1024 ];
:local Bin [ $IfThenElse ($Base = 1024) "i" "" ];
:if ($Input < $Base) do={
:return $Input;
}
:for I from=0 to=[ :len $Prefix ] do={
:set Pow ($Pow * $Base);
:if ($Input / $Base < $Pow) do={
:set Prefix [ :pick $Prefix $I ];
:local Tmp1 ($Input * 100 / $Pow);
:local Tmp2 ($Tmp1 / 100);
:if ($Tmp2 >= 100) do={
:return ($Tmp2 . $Prefix . $Bin);
}
:return ($Tmp2 . "." . \
[ :pick $Tmp1 [ :len $Tmp2 ] ([ :len $Tmp1 ] - [ :len $Tmp2 ] + 1) ] . \
$Prefix . $Bin);
}
}
}
# mimic conditional/ternary operator (condition ? consequent : alternative)
:set IfThenElse do={
:if ([ :tostr $1 ] = "true" || [ :tobool $1 ] = true) do={
:return $2;
}
:return $3;
}
# check if default route is reachable
:set IsDefaultRouteReachable do={
:if ([ :len [ /ip/route/find where dst-address=0.0.0.0/0 active routing-table=main ] ] > 0) do={
:return true;
}
:return false;
}
# check if DNS is resolving
:set IsDNSResolving do={
:do {
:resolve "low-ttl.eworm.de";
} on-error={
:return false;
}
:return true;
}
# check if system is is fully connected (default route reachable, DNS resolving, time sync)
:set IsFullyConnected do={
:global IsDefaultRouteReachable;
:global IsDNSResolving;
:global IsTimeSync;
:if ([ $IsDefaultRouteReachable ] = false) do={
:return false;
}
:if ([ $IsDNSResolving ] = false) do={
:return false;
}
:if ([ $IsTimeSync ] = false) do={
:return false;
}
:return true;
}
# check if mac address is locally administered
:set IsMacLocallyAdministered do={
:if ([ :tonum ("0x" . [ :pick $1 0 [ :find $1 ":" ] ]) ] & 2 = 2) do={
:return true;
}
:return false;
}
# check if system time is sync
:set IsTimeSync do={
:global IsTimeSyncCached;
:global IsTimeSyncResetNtp;
:global LogPrintOnce;
:if ($IsTimeSyncCached = true) do={
:return true;
}
:if ([ /system/ntp/client/get enabled ] = true) do={
:if ([ /system/ntp/client/get status ] = "synchronized") do={
:set IsTimeSyncCached true;
:return true;
}
:local Uptime [ /system/resource/get uptime ];
:if ([ :typeof $IsTimeSyncResetNtp ] = "nothing") do={
:set IsTimeSyncResetNtp $Uptime;
}
:if ($Uptime - $IsTimeSyncResetNtp < 3m) do={
:return false;
}
$LogPrintOnce warning $0 ("The ntp client is configured, but did not sync.");
:set IsTimeSyncResetNtp $Uptime;
/system/ntp/client/set enabled=no;
:delay 20ms;
/system/ntp/client/set enabled=yes;
:return false;
}
:if ([ /system/license/get ]->"level" = "free" || \
[ /system/resource/get ]->"board-name" = "x86") do={
$LogPrintOnce debug $0 ("No ntp client configured, relying on RTC for CHR free license and x86.");
:return true;
}
:if ([ /ip/cloud/get update-time ] = true) do={
:if ([ :typeof [ /ip/cloud/get public-address ] ] = "ip") do={
:set IsTimeSyncCached true;
:return true;
}
:return false;
}
$LogPrintOnce debug $0 ("No time source configured! Returning gracefully...");
:return true;
}
# log and print with same text
:set LogPrint do={
:local Severity [ :tostr $1 ];
:local Name [ :tostr $2 ];
:local Message [ :tostr $3 ];
:global PrintDebug;
:global PrintDebugOverride;
:global EitherOr;
:local Debug [ $EitherOr ($PrintDebugOverride->$Name) $PrintDebug ];
:local PrintSeverity do={
:global TerminalColorOutput;
:if ($TerminalColorOutput != true) do={
:return $1;
}
:local Color { debug=96; info=97; warning=93; error=91 };
:return ("\1B[" . $Color->$1 . "m" . $1 . "\1B[0m");
}
:local Log ([ $EitherOr $Name "<unknown>" ] . ": " . $Message);
:if ($Severity ~ ("^(debug|error|info)\$")) do={
:if ($Severity = "debug") do={ :log debug $Log; }
:if ($Severity = "error") do={ :log error $Log; }
:if ($Severity = "info" ) do={ :log info $Log; }
} else={
:log warning $Log;
:set Severity "warning";
}
:if ($Severity != "debug" || $Debug = true) do={
:put ([ $PrintSeverity $Severity ] . ": " . $Message);
}
}
# log and print, once until reboot
:set LogPrintOnce do={
:local Severity [ :tostr $1 ];
:local Name [ :tostr $2 ];
:local Message [ :tostr $3 ];
:global LogPrint;
:global LogPrintOnceMessages;
:if ([ :typeof $LogPrintOnceMessages ] = "nothing") do={
:set LogPrintOnceMessages ({});
}
:if ($LogPrintOnceMessages->$Message = 1) do={
:return false;
}
:if ([ :len [ /log/find where message=($Name . ": " . $Message) ] ] > 0) do={
$LogPrint warning $0 \
("The message is already in log, scripting subsystem may have crashed before!");
}
:set ($LogPrintOnceMessages->$Message) 1;
$LogPrint $Severity $Name $Message;
:return true;
}
# get max value
:set MAX do={
:if ($1 > $2) do={ :return $1; }
:return $2;
}
# get min value
:set MIN do={
:if ($1 < $2) do={ :return $1; }
:return $2;
}
# create directory
:set MkDir do={
:local Path [ :tostr $1 ];
:global CleanFilePath;
:global LogPrint;
:global WaitForFile;
:local MkTmpfs do={
:global LogPrint;
:global WaitForFile;
:local TmpFs [ /disk/find where slot=tmpfs type=tmpfs ];
:if ([ :len $TmpFs ] = 1) do={
:if ([ /disk/get $TmpFs disabled ] = true) do={
$LogPrint info $0 ("The tmpfs is disabled, enabling.");
/disk/enable $TmpFs;
}
:return true;
}
$LogPrint info $0 ("Creating disk of type tmpfs.");
/file/remove [ find where name="tmpfs" type="directory" ];
:do {
/disk/add slot=tmpfs type=tmpfs tmpfs-max-size=([ /system/resource/get total-memory ] / 3);
$WaitForFile "tmpfs";
} on-error={
$LogPrint warning $0 ("Creating disk of type tmpfs failed!");
:return false;
}
:return true;
}
:set Path [ $CleanFilePath $Path ];
:if ($Path = "") do={
:return true;
}
:if ([ :len [ /file/find where name=$Path type="directory" ] ] = 1) do={
:return true;
}
:if ([ :pick $Path 0 5 ] = "tmpfs") do={
:if ([ $MkTmpfs ] = false) do={
:return false;
}
}
:do {
:local File ($Path . "/file");
/file/add name=$File;
$WaitForFile $File;
/file/remove $File;
} on-error={
$LogPrint warning $0 ("Making directory '" . $Path . "' failed!");
:return false;
}
:return true;
}
# prepare NotificationFunctions array
:if ([ :typeof $NotificationFunctions ] != "array") do={
:set NotificationFunctions ({});
}
# parse the date and return a named array
:set ParseDate do={
:local Date [ :tostr $1 ];
:return ({ "year"=[ :tonum [ :pick $Date 0 4 ] ];
"month"=[ :tonum [ :pick $Date 5 7 ] ];
"day"=[ :tonum [ :pick $Date 8 10 ] ] });
}
# parse key value store
:set ParseKeyValueStore do={
:local Source $1;
:if ([ :pick $Source 0 1 ] = "{") do={
:do {
:return [ :deserialize from=json $Source ];
} on-error={ }
}
:if ([ :typeof $Source ] != "array") do={
:set Source [ :tostr $1 ];
}
:local Result ({});
:foreach KeyValue in=[ :toarray $Source ] do={
:if ([ :find $KeyValue "=" ]) do={
:local Key [ :pick $KeyValue 0 [ :find $KeyValue "=" ] ];
:local Value [ :pick $KeyValue ([ :find $KeyValue "=" ] + 1) [ :len $KeyValue ] ];
:if ($Value="true") do={ :set Value true; }
:if ($Value="false") do={ :set Value false; }
:set ($Result->$Key) $Value;
} else={
:set ($Result->$KeyValue) true;
}
}
:return $Result;
}
# print lines with trailing carriage return
:set PrettyPrint do={
:put [ :tocrlf [ :tostr $1 ] ];
}
# strip protocol from from url string
:set ProtocolStrip do={
:local Input [ :tostr $1 ];
:local Pos [ :find $Input "://" ];
:if ([ :typeof $Pos ] = "nil") do={
:return $Input;
}
:return [ :pick $Input ($Pos + 3) [ :len $Input ] ];
}
# delay a random amount of seconds
:set RandomDelay do={
:local Time [ :tonum $1 ];
:local Unit [ :tostr $2 ];
:global EitherOr;
:global GetRandomNumber;
:global MAX;
:if ($Time = 0) do={
:return false;
}
:delay ([ $MAX 10 [ $GetRandomNumber ([ :tonsec [ :totime ($Time . [ $EitherOr $Unit "s" ]) ] ] / 1000000) ] ] . "ms");
}
# check for required RouterOS version
:set RequiredRouterOS do={
:local Caller [ :tostr $1 ];
:local Required [ :tostr $2 ];
:local Warn [ :tostr $3 ];
:global IfThenElse;
:global LogPrint;
:global VersionToNum;
:if (!($Required ~ "^\\d+\\.\\d+((alpha|beta|rc|\\.)\\d+|)\$")) do={
$LogPrint error $0 ("No valid RouterOS version: " . $Required);
:return false;
}
:if ([ $VersionToNum $Required ] > [ $VersionToNum [ /system/package/update/get installed-version ] ]) do={
:if ($Warn = "true") do={
$LogPrint warning $0 ("This " . [ $IfThenElse ([ :pick $Caller 0 ] = ("\$")) "function" "script" ] . \