build.gradle

plugins {
    id "architectury-plugin" version "3.4-SNAPSHOT"
    id "dev.architectury.loom" version "1.7-SNAPSHOT" apply false
    id 'com.github.johnrengelman.shadow' version '8.1.1' apply false
    id "io.github.pacifistmc.forgix" version "1.2.9"
}

architectury {
    minecraft = rootProject.minecraft_version
}

allprojects {
    group = rootProject.maven_group
    version = rootProject.mod_version

    forgix {
        group = "com.fabbe50.fogoverrides"
        mergedJarName = "${archives_base_name}-${minecraft_version}-${mod_version}.jar"

        fabric {
            projectName = "fabric"
            jarLocation = "build/libs/${archives_base_name}-fabric-${minecraft_version}-${mod_version}.jar"
        }

        neoforge {
            projectName = "neoforge"
            jarLocation = "build/libs/${archives_base_name}-neoforge-${minecraft_version}-${mod_version}.jar"
            mixin "fogoverrides.mixins.json"
            mixin "fogoverrides-common.mixins.json"
        }
    }
}

subprojects {
    apply plugin: "dev.architectury.loom"
    apply plugin: "architectury-plugin"
    apply plugin: "maven-publish"

    base {
        archivesName = "${archives_base_name}-${project.name}-${minecraft_version}"
    }

    repositories {
        maven { url "https://maven.neoforged.net/releases/"}
        maven { url "https://maven.terraformersmc.com/releases/" }
    }

    dependencies {
        minecraft "com.mojang:minecraft:${rootProject.minecraft_version}"
        mappings loom.officialMojangMappings()
    }

    java {
        withSourcesJar()
        sourceCompatibility = JavaVersion.VERSION_21
        targetCompatibility = JavaVersion.VERSION_21
    }

    tasks.withType(JavaCompile).configureEach {
        it.options.encoding = "UTF-8"
        it.options.release = 21
    }
}