meson.build

project(
  'telegraph',
  version: '0.1.8',
  meson_version: '>= 0.59.0',
  license: 'GPL-3.0-only',
)

i18n = import('i18n')
python = import('python')
gnome = import('gnome')

base_id = 'io.github.fkinoshita.Telegraph'
project_name = 'Telegraph'
package_url = 'https://github.com/fkinoshita/Telegraph'
copyright = '© 2023 Felipe Kinoshita.'
contributors = '\n'.join([
    'Felipe Kinoshita https://mastodon.social/@fkinoshita',
    'gregorni https://fosstodon.org/@gregorni',
    'axtlos https://axtlos.neocities.org'
])
designers = '\n'.join([
  '',
])
artists = '\n'.join([
  'Brage Fuglseth https://bragefuglseth.dev/',
])

dependency('gtk4', version: '>=4.9')
dependency('libadwaita-1', version: '>=1.2')

DATA_DIR = join_paths(get_option('prefix'), get_option('datadir'), meson.project_name())

# Profiles
if get_option('profile') == 'development'
    profile = 'Devel'
    application_id = '@0@.@1@'.format(base_id, profile)

    find_program('git')
    rev_txt = run_command('git', 'rev-parse', '--short', 'HEAD').stdout().strip()
    version = meson.project_version() + '-' + rev_txt
else
    application_id = base_id
    profile = 'Default'
    version = meson.project_version()
endif

top_source_dir = meson.current_source_dir()
gettext_package = meson.project_name()

subdir('data')
subdir('po')
subdir('src')

gnome.post_install(
  glib_compile_schemas: true,
  gtk_update_icon_cache: true,
  update_desktop_database: true,
)