CMakeLists.txt

# builds all Gemini3D external libraries

cmake_minimum_required(VERSION 3.20...3.29)
# Cmake 3.19 string(JSON)
# Cmake 3.20 cmake_path()

if(NOT CMAKE_BUILD_TYPE)
  # ignore ENV{CMAKE_BUILD_TYPE} as we want to directly capture this project's user intent
  set(CMAKE_BUILD_TYPE Release CACHE STRING "Release default")
endif()

include(cmake/toolchain.cmake)

project(GeminiExternalLibs
LANGUAGES C CXX Fortran
VERSION 1.1.1
)

if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  get_filename_component(home "~" ABSOLUTE)
  string(TOLOWER ${CMAKE_Fortran_COMPILER_ID} ln)
  set_property(CACHE CMAKE_INSTALL_PREFIX PROPERTY VALUE ${home}/libgem_${ln})
endif()

include(options.cmake)

include(cmake/GitSubmodule.cmake)

if(package)
  file(MAKE_DIRECTORY ${PROJECT_BINARY_DIR}/package)
endif()

if(CRAY)
  # install toolchain file for future use
  file(COPY ${CMAKE_CURRENT_SOURCE_DIR}/cmake/cray.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/cmake/)
endif()

set(subprojs mumps)
if(NOT mumps_only)
  list(APPEND subprojs ffilesystem glow hwm14 h5fortran msis)
endif()

foreach(t IN LISTS subprojs)
  git_submodule(${CMAKE_CURRENT_SOURCE_DIR}/${t})
  add_subdirectory(${t})
endforeach()

# print summary of configuration
include(FeatureSummary)

add_feature_info(shared BUILD_SHARED_LIBS "build shared libs (otherwise, build static libs)")
add_feature_info(packaging package "preparing new data upoad (for development team)")

feature_summary(WHAT ENABLED_FEATURES DESCRIPTION "Gemini3D external libraries")

include(cmake/package/cpacker.cmake)