build.gradle

import org.asciidoctor.gradle.jvm.AsciidoctorTask

String customGroovyVersion = findProperty('groovyVersion') ?: System.getenv('GROOVY_VERSION')
if (customGroovyVersion) {
    logger.lifecycle("Using custom Groovy version: $customGroovyVersion")
}

subprojects {

    version = projectVersion

    if (customGroovyVersion) {
        configurations.configureEach {
            resolutionStrategy.eachDependency { DependencyResolveDetails details ->
                if (details.requested.group == 'org.apache.groovy') {
                    details.useVersion(customGroovyVersion)
                }
            }
        }
    }

    repositories {
        maven { url = 'https://repo.grails.org/grails/core' }
        mavenCentral()
        if (customGroovyVersion?.endsWith('-SNAPSHOT')) {
            // Used for testing locally against the latest snapshot of Groovy
            // Usage: ./gradlew build -P"groovyVersion=X.X.X-SNAPSHOT"
            logger.lifecycle('Adding Groovy Snapshot Repo for project: {}, Using Groovy {}', name, customGroovyVersion)
            maven {
                name = 'ASF Snapshot repo'
                url = 'https://repository.apache.org/content/repositories/snapshots'
            }
        }
    }
}

tasks.register('clean', Delete) {
    group = 'build'
    delete layout.buildDirectory
}

// Workaround needed for nexus publishing bug
// version and group must be specified in the root project
// https://github.com/gradle-nexus/publish-plugin/issues/310
version = projectVersion
group = 'this.will.be.overridden'

def publishedProjects = [
        'acl-plugin',
        'cas-plugin',
        'core-plugin',
        'ldap-plugin',
        'oauth2-plugin',
        'spring-security-rest',
        'spring-security-rest-gorm',
        'spring-security-rest-grailscache',
        'spring-security-rest-memcached',
        'spring-security-rest-redis',
        'ui-plugin'
]
subprojects {
    if (name in publishedProjects) {
        // This has to be applied here
        apply plugin: 'org.grails.grails-publish'
    }
    else if(name == 'spring-security-rest-testapp-profile') {
        apply plugin: 'org.grails.grails-profile-publish'
    }
}