-
Notifications
You must be signed in to change notification settings - Fork 32
/
RM12.CG
1125 lines (995 loc) · 18.3 KB
/
RM12.CG
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
[logics for room 12 -- rmAlley
[ "Leisure Suit Larry in the Land of the Lounge Lizards"
[ by Al Lowe
%include "rm12.msg"
%include "gamedefs.h"
#define L_HOTEL_SIGN 0
#define L_WINDOW_OPEN 1 [ 1 cell only
#define L_WINDOW_BREAKING 2
#define L_WINDOW_BROKEN 3
#define L_WITH_HAMMER 0
#define L_WITHOUT_HAMMER 1
%define onFireEscape lf0
%define nearWindow lf1
%define nearPills lf2
%define hitWindow lf3
%define nearDumpster lf5
%define windowDone lf7
%define ropeAroundWaist lf8
%define ropeAroundRailing lf9
%define yuchTimer lv0
%object aHotelSign 1
%object aLadder 2
%object aWindow 3
if (initLog)
{
LoadPic( currentRoom);
DrawPic( currentRoom);
DiscardPic( currentRoom);
LoadView( vAlleyStuff);
LoadView( vEgoOnLadder);
LoadView( vEgoFalling);
LoadView( vEgoIntoDumpster);
LoadView( vEgoLeavingDumpster);
LoadView( vEgoDead);
LoadView( vEgoOnRope);
LoadSound( sEgoFalling);
AnimateObj( aHotelSign);
IgnoreHorizon( aHotelSign);
IgnoreBlocks( aHotelSign);
IgnoreObjs( aHotelSign);
SetView( aHotelSign, vAlleyStuff);
SetLoop( aHotelSign, L_HOTEL_SIGN);
SetCel( aHotelSign, 0);
Position( aHotelSign, 18, 73);
Draw( aHotelSign);
work = 8;
CycleTime( aHotelSign, work);
AnimateObj( aLadder);
IgnoreHorizon( aLadder);
IgnoreBlocks( aLadder);
IgnoreObjs( aLadder);
SetView( aLadder, vEgoOnLadder);
SetCel( aLadder, 0);
CycleTime( aLadder, three);
Position( aLadder, 51, 101);
Draw( aLadder);
StopUpdate( aLadder);
if (!ObjInRoom( iPills, currentRoom) &&
alleyWindowBroken)
{
AddToPic( vAlleyStuff, L_WINDOW_BROKEN, 0, 112, 51, 4, 4);
}
else
{
AnimateObj( aWindow);
IgnoreHorizon( aWindow);
IgnoreBlocks( aWindow);
IgnoreObjs( aWindow);
SetView( aWindow, vAlleyStuff);
SetLoop( aWindow, L_WINDOW_BREAKING);
if (alleyWindowBroken)
{
LastCel( aWindow, work);
SetCelV( aWindow, work);
}
else
{
SetCel( aWindow, 0);
}
Position( aWindow, 112, 51);
Draw( aWindow);
StopUpdate( aWindow);
}
if (hookerWindowOpen)
{
AddToPic( vAlleyStuff, L_WINDOW_OPEN, 0, 65, 51, 4, 4);
}
currentStatus = NORMAL;
if (previousRoom == rmOutsideBar)
{
egoX = 0;
egoY = 148;
Reset( onFireEscape);
StartMotion( ego);
SetLoop( ego, FACING_RIGHT);
}
else
{
if (previousRoom == rmInsideBar)
{
egoX = 58;
egoY = 148;
currentStatus = IN_DUMPSTER;
}
else
{
egoX = 70;
egoY = 64;
SetLoop( ego, FACING_FRONT);
Set( onFireEscape);
Reset( keepCycling);
StartMotion( ego);
Reset( programControl);
ReleasePriority( ego);
}
}
PositionV( ego, egoX, egoY);
if (previousRoom != rmInsideBar)
{
Draw( ego);
}
ShowPic( );
if (currentStatus == IN_DUMPSTER)
{
PreventInput();
Set( programControl);
Set( notCloseEnough);
}
else
{
Reset( programControl);
AcceptInput();
}
Return( );
} [ end initLOG
Reset( onFireEscape);
if (Posn( ego, 53, 60, 94, 64))
{
Set( onFireEscape);
}
Reset( nearPills);
if (ObjInRoom( iPills, currentRoom) &&
onFireEscape &&
Posn( ego, 82, 60, 99, 64))
{
Set( nearPills);
}
if (currentStatus == HANGING_BY_ROPE &&
ObjInRoom( iPills, currentRoom))
{
Set( nearPills);
}
Reset( nearWindow);
if (onFireEscape)
{
if (Posn( ego, 61, 60, 79, 64))
{
Set( nearWindow);
}
}
Reset( nearDumpster);
if (!onFireEscape &&
Posn( ego, 42, 148, 58, 152))
{
Set( nearDumpster);
}
if (onFireEscape &&
currentStatus == NORMAL &&
ropeAroundWaist && ropeAroundRailing)
{
StopMotion( ego);
}
if (currentStatus == NORMAL &&
Posn( ego, 53, 60, 54, 64))
{
Reset( onFireEscape);
script = 0;
Set( scriptDone); [ make him start falling in trash
}
[*****
:handleInput
[*****
if (!haveInput) {goto noInput;}
if ((Said( look) ||
Said( look, room) ||
Said( look, alley)))
{
if (!ObjInRoom( iPills, currentRoom))
{
Print( 3);
}
else
{
Print( 6);
}
}
if ((Said( look, ladder) ||
Said( look, rail)))
{
Print( 43);
}
[ If on ground, can "search dumpster" to find old hammer.
if (currentStatus != IN_DUMPSTER)
{
if ((Said( search, bin) ||
Said( look, bin) ||
Said( look$in, bin)))
{
if (!nearDumpster)
{
Print( 32);
}
else
{
Print( 28);
}
}
if ((Said( brush, off, clothes) ||
Said( brush, clothes) ||
Said( brush, me, off)))
{
Set( OK);
}
if ((Said( enter, bin) ||
Said( jump, bin) ||
Said( jump, in, bin) ||
Said( climb, bin) ||
Said( climb, in, bin)))
{
if (onFireEscape)
{
Print( 55);
}
else
{
if (!nearDumpster)
{
Print( 32);
}
else
{
script = 100;
Set( scriptDone);
}
}
}
}
else
{
if ((Said( climb, out, bin) ||
Said( jump, out, bin) ||
Said( climb, out) ||
Said( get, out) ||
Said( go, out) ||
Said( go) ||
Said( leave, bin)))
{
script = 200;
Set( scriptDone);
}
if ((Said( search, bin) ||
Said( look$in, bin) ||
Said( look, bin)))
{
if (ObjInRoom( iHammer, currentRoom))
{
Print( 25);
}
else
{
Print( 26);
}
}
if (Said( get, hammer))
{
if (!ObjInRoom( iHammer, currentRoom))
{
Set( alreadyGotIt);
}
else
{
Set( OK);
Get( iHammer);
currentScore += 3;
}
}
}
if (Said( look, sign))
{
Print( 47);
Print( 48);
}
if ((Said( climb, up) ||
Said( climb, rail) ||
Said( climb, up, rail) ||
Said( pull, down, ladder, rail) ||
Said( pull, ladder, rail) ||
Said( pull, down, ladder) ||
Said( pull, ladder) ||
Said( climb, ladder) ||
Said( stand, on, ladder) ||
Said( get, ladder) ||
Said( lower, ladder) ||
Said( jump, ladder) ||
Said( jump, up, ladder) ||
Said( jump, on, ladder) ||
Said( jump) ||
Said( jump, up)))
{
if ((onFireEscape ||
currentStatus == HANGING_BY_ROPE ||
nearWindow))
{
Print( 8);
}
else
{
if (nearDumpster)
{
Print( 33);
}
else
{
Print( 53);
}
}
}
if ((Said( close, window) ||
Said( lower, window)))
{
if ((!onFireEscape ||
!nearWindow))
{
Set( notCloseEnough);
}
else
{
Print( 4);
}
}
if ((Said( look, window) ||
Said( look$in, window)))
{
if (!onFireEscape)
{
Print( 14);
}
else
{
if (nearWindow)
{
Print( 12);
}
else
{
if (ObjInRoom( iPills, currentRoom))
{
Print( 13);
}
else
{
Print( 15);
}
}
}
}
if ((Said( look, west, window) ||
Said( look$in, west, window)))
{
if (!onFireEscape)
{
Print( 14);
}
else
{
Print( 12);
}
}
if ((Said( look, east, window) ||
Said( look$in, east, window)))
{
if (!onFireEscape)
{
Print( 14);
}
else
{
if (ObjInRoom( iPills, currentRoom))
{
Print( 13);
}
else
{
Print( 15);
}
}
}
[ Handle ego on balcony going for the pill bottle.
[If "reach window" without rope, fall from fire escape, and die.
[If ties rope to self, and railing, reach him over.
if (Has( iRope) &&
currentStatus != HANGING_BY_ROPE)
{
if ((Said( tie, rope, waist) ||
Said( tie, rope, me)))
{
if (!ropeAroundWaist)
{
Set( OK);
Set( ropeAroundWaist);
}
else
{
Print( 22);
}
}
if (Said( tie, rope, rail))
{
if (!onFireEscape)
{
Print( 36);
}
else
{
if (!ropeAroundRailing)
{
Set( OK);
Set( ropeAroundRailing);
}
else
{
Print( 22);
}
}
}
}
if ((Said( get, pills) ||
Said( get, bottle) ||
Said( get, bottle, pills) ||
Said( reach, over, window) ||
Said( reach, over, rail, get, pills) ||
Said( reach, for, pills) ||
Said( reach, over, rail, for, pills) ||
Said( reach, over, rail) ||
Said( reach, window) ||
Said( jump, window) ||
Said( stand, rail) ||
Said( stand, on, rail) ||
Said( lean, over, rail) ||
Said( lean, over) ||
Said( lean, out) ||
Said( climb, on, rail) ||
Said( climb, over) ||
Said( climb, over, rail, get, pills) ||
Said( climb, rail, get, pills) ||
Said( climb, over, rail, pills) ||
Said( climb, rail, pills) ||
Said( climb, over, rail) ||
Said( climb, rail)))
{
if (Has( iPills))
{
Set( alreadyGotIt);
}
else
{
if (ObjInRoom( iPills, currentRoom) &&
!nearPills)
{
Print( 1);
}
else
{
if ((!ropeAroundWaist || !ropeAroundRailing))
{
script = 250;
Set( scriptDone);
message = 16;
}
else
{
if (currentStatus != HANGING_BY_ROPE)
{
currentStatus = HANGING_BY_ROPE;
Set( programControl);
StopMotion( ego);
SetView( ego, vEgoOnRope);
SetLoop( ego, L_WITHOUT_HAMMER);
RepositionTo( ego, 92, 61);
Set( keepCycling);
CycleTime( ego, three);
Print( 17);
}
else
{
if (!ObjInRoom( iPills, currentRoom))
{
Print( 24);
}
else
{
if (!alleyWindowBroken)
{
Print( 21);
Print( 9);
}
else
{
SetLoop( ego, L_WITHOUT_HAMMER);
StartUpdate( aWindow);
Erase( aWindow);
AddToPic( vAlleyStuff, L_WINDOW_BROKEN, 0, 112, 51, 4, 4);
Get( iPills);
currentScore += 8;
Print( 19);
}
}
}
}
}
}
}
if (!alleyWindowBroken &&
(Said( break, window, hammer) ||
Said( use, hammer, break, window) ||
Said( break, window) ||
Said( break, window, with, hammer) ||
Said( hit, window, hammer) ||
Said( use, hammer, hit, window) ||
Said( hit, window) ||
Said( hit, window, with, hammer) ||
Said( use, hammer)))
{
if (!Has( iHammer))
{
Set( dontHaveIt);
}
else
{
if ((!nearPills ||
!ropeAroundWaist ||
!ropeAroundRailing))
{
Set( notCloseEnough);
}
else
{
if (currentStatus != HANGING_BY_ROPE)
{
Print( 20);
}
else
{
SetLoop( ego, L_WITH_HAMMER);
SetCel( ego, 0);
EndOfLoop( ego, hitWindow);
}
}
}
}
if (currentStatus == HANGING_BY_ROPE)
{
if (Said( unlock, window))
{
Print( 10);
}
if (Said( open, window))
{
Print( 11);
}
if (!alleyWindowBroken &&
(Said( hit, window) ||
Said( hit, window, with, hand) ||
Said( use, hand, hit, window) ||
Said( break, window)))
{
Print( 21);
Print( 9);
}
if ((Said( go, rail) ||
Said( go, back, on, rail) ||
Said( go, on, rail) ||
Said( go, back) ||
Said( go, back, rail) ||
Said( get, on, rail) ||
Said( get, back, rail) ||
Said( get, back, on, rail) ||
Said( pull, on, rope) ||
Said( pull, rope) ||
Said( get, rail) ||
Said( climb, back) ||
Said( climb, back, rail) ||
Said( climb, back, on, rail) ||
Said( climb, on, rail) ||
Said( climb, rail) ||
Said( return, rail) ||
Said( return, rail) ||
Said( stop, hanging, rope)))
{
Set( OK);
currentStatus = NORMAL;
SetView( ego, vEgo);
RepositionTo( ego, 86, 64);
AcceptInput();
StartMotion( ego);
Reset( programControl);
Reset( keepCycling);
CycleTime( ego, one);
}
if (Said( look, down))
{
Print( 52);
}
}
if ((Said( cut, rope, rol) ||
Said( use, knife, rol)))
{
if (!Has( iPocketKnife))
{
Print( 56);
}
else
{
if (currentStatus == HANGING_BY_ROPE)
{
Print( 41);
script = 250;
Set( scriptDone);
message = 23;
}
else
{
if (!ropeAroundWaist && !ropeAroundRailing)
{
Print( 40);
}
else
{
Print( 41);
Reset( ropeAroundWaist);
Reset( ropeAroundRailing);
StartMotion( ego);
Reset( programControl);
Get( iRope);
}
}
}
}
if ((Said( take, rope, rol) ||
Said( untie, rope, rol)))
{
if (currentStatus == HANGING_BY_ROPE)
{
script = 250;
Set( scriptDone);
message = 23;
}
else
{
if (!ropeAroundWaist && !ropeAroundRailing)
{
Print( 40);
}
else
{
Print( 39);
Get( iRope);
Reset( ropeAroundRailing);
Reset( ropeAroundWaist);
StartMotion( ego);
Reset( programControl);
}
}
}
if (onFireEscape)
{
if (Said( look, fire$escape))
{
Print( 5);
}
if ((Said( enter, window) ||
Said( climb, window) ||
Said( go, back) ||
Said( go, room) ||
Said( go, window)))
{
if (!nearWindow)
{
Print( 54);
}
else
{
if (ropeAroundWaist && ropeAroundRailing)
{
Print( 57);
}
else
{
Set( OK);
newRoom = rmHooker;
}
}
}
if ((Said( climb, down) ||
Said( lower, ladder) ||
Said( go, ladder) ||
Said( go, down, ladder) ||
Said( climb, down, ladder) ||
Said( climb, ladder)))
{
Print( 2);
}
if (Said( look, down))
{
Print( 52);
}
if ((Said( jump) ||
Said( jump, off) ||
Said( jump, down) ||
Said( jump, bin) ||
Said( stand, on, rail) ||
Said( jump, off, rail) ||
Said( climb, down, rail)))
{
if (ropeAroundWaist && ropeAroundRailing)
{
Print( 57);
}
else
{
script = 250;
Set( scriptDone);
message = 23;
}
}
}
if (ObjInRoom( iPills, currentRoom) &&
Said( look, pills))
{
if (nearPills)
{
Print( 13);
}
else
{
Print( 51);
}
}
[ Misses, give clue.
if ((Said( take, ladder) ||
Said( remove, ladder)))
{
Print( 49);
}
if ((Said( throw, rope, rol) ||
Said( climb, down, rope, rol) ||
Said( climb, rope, rol)))
{
Print( 37);
}
if ((Said( tie, rope) ||
Said( use, rope)))
{
Print( 38);
}
if ((Said( look, over, fence) ||
Said( look, fence)))
{
Print( 34);
}
if ((Said( climb, fence) ||
Said( jump, fence) ||
Said( jump, over, fence) ||
Said( climb, over, fence)))
{
Print( 35);
}
if ((Said( close, lid, rol) ||
Said( climb, on, bin, rol) ||
Said( climb, bin, rol) ||
Said( climb, on, top, bin, rol) ||
Said( lower, lid, rol) ||
Said( lower, bin, rol) ||
Said( stand, on, bin) ||
Said( move, lid, rol) ||
Said( close, bin, rol)))
{
Print( 44);
}
if ((Said( look, behind, bin) ||
Said( move, bin, rol)))
{
Print( 45);
}
if (Said( tie, rope, anyword))
{
Print( 46);
}
if ((Said( cut, glass, with, ring) ||
Said( use, ring, cut, glass) ||
Said( hold, rope, rol) ||
Said( hold, ladder, rol) ||
Said( hit, fence, rol) ||
Said( hit, ladder, rol) ||
Said( hit, wall, rol)))
{
Print( 42);
}
[*****
:noInput
[*****
if (hitWindow)
{
Reset( hitWindow);
Print( 18);
PreventInput();
StartUpdate( aWindow);
EndOfLoop( aWindow, windowDone);
}
if (windowDone)
{
Reset( windowDone);
Reset( keepCycling);
StopUpdate( aWindow);
Set( alleyWindowBroken);
AcceptInput();
}
if (aSecondPassed)
{
--yuchTimer;
if (yuchTimer == 16)
{
Print( 30);
}
if (yuchTimer == 11)
{
Print( 31);
AcceptInput();
}
if (yuchTimer == 1 &&
currentStatus == IN_DUMPSTER)
{
Print( 27);
}
}
CurrentCel( aLadder, work);
if (work == 4)
{
Set( scriptDone);
}
if (scriptDone)
{
Reset( scriptDone);
++script;
if (script == 1) [ Fall down ladder.
{
currentStatus = FALLING;
StartUpdate( aLadder);
SetCel( aLadder, 1);
Set( programControl);
PreventInput();
Erase( ego);
EndOfLoop( aLadder, scriptDone);
Sound( sEgoFalling, done);
}
if (script == 2)
{
SetView( ego, vEgoFalling);
SetPriority( ego, 11);
Position( ego, 53, 99);
Draw( ego);
MoveObj( ego, 53, 137, 3, scriptDone);
}
if (script == 3)
{
SetCel( aLadder, 0);
StopUpdate( aLadder);
ForceUpdate( aLadder);
}
if (script == 4)
{
StopMotion( ego);
Set( programControl);
SetView( ego, vEgoIntoDumpster);
SetCel( ego, 1);
SetPriority( ego, 15);
RepositionTo( ego, 40, 126);
CycleTime( ego, three);
Set( keepCycling);