.zprofile

#
# Executes commands at login pre-zshrc.
#
# Authors:
#   Sorin Ionescu <sorin.ionescu@gmail.com>
#

#
# zprofile loads /etc/profile.env which resets some env vars
# thus load local env afterwards
#
if [[ -s "${ZDOTDIR:-$HOME}/.env" ]]; then
  . "${ZDOTDIR:-$HOME}/.env"
fi

#
# Browser
#

if (( ${+commands[xdg-open]} )); then
  export BROWSER='xdg-open'
elif [[ "$OSTYPE" == darwin* ]]; then
  export BROWSER='open'
fi

#
# Editors
#

export EDITOR='vim'
export VISUAL='vim'
export PAGER='less'

#
# Language
#

if [[ -z "$LANG" ]]; then
  export LANG='en_US.UTF-8'
fi

#
# Paths
#

# Ensure path arrays do not contain duplicates.
typeset -gU cdpath fpath mailpath path

# Set the list of directories that cd searches.
# cdpath=(
#   $cdpath
# )

# Set the list of directories that Zsh searches for programs.
# path=(
#   /usr/local/{bin,sbin}
#   $path
# )

#
# Less
#

# Set the default Less options.
# Mouse-wheel scrolling has been disabled by -X (disable screen clearing).
# Remove -X and -F (exit if the content fits on one screen) to enable it.
export LESS='-F -g -i -M -R -S -w -X -z-4'

# Set the Less input preprocessor.
# Try both `lesspipe` and `lesspipe.sh` as either might exist on a system.
if (( $#commands[(i)lesspipe(|.sh)] )); then
  export LESSOPEN="| /usr/bin/env $commands[(i)lesspipe(|.sh)] %s 2>&-"
fi

#
# Keychain
#

# if (( $#commands[keychain] )); then
#   eval $(keychain --quiet --quick --noask --eval id_ed25519 id_rsa)
# fi