CreateBreathMark.plg


{
	Initialize "() {
// v.1.0.0

AddToPluginsMenu('Create Breath Mark','Run'); }"
	Run "() {
selection = Sibelius.ActiveScore.Selection;
textStyle = 'Breath Mark';

if (isSelectionEmpty) {
	return false;
}

entries = CreateSparseArray();

for each NoteRest nr in selection {
	position = nr.Position;
	bar = nr.ParentBar;

	entry = CreateDictionary();

	if (position = 0) {
		prevBar = bar.ParentStaff.NthBar(bar.BarNumber - 1);
		entry['bar'] = prevBar;
		entry['position'] = prevBar.Length - 1;
		entry['text'] = ',';
	} else {
		entry['bar'] = bar;
		entry['position'] = position;
		entry['text'] = getBreathText(nr);
	}

	entries.Push(entry);
}

for each entry in entries {
	deleteBarObjects(getTextAtPostionForBar(textStyle, entry.position, entry.bar));
	entry.bar.AddText(entry.position, entry.text, textStyle);
}
}"
	isSelectionEmpty "(selection) {
for each obj in selection {
	if (IsObject(obj)) {
		 return false;
	}
}

return true;}"
	getTextAtPostionForBar "(style, pos, bar) {
items = CreateSparseArray();

for each Text text in bar {
	if (text.StyleAsText = style and text.Position = pos) {
		items.Push(text);
	}
}

return items;
}"
	deleteBarObjects "(objects) {
for each obj in objects {
	obj.Delete();
}
}"
	getBreathText "(noteRest) {
result = ',';
maxChars = 0;
entries = CreateSparseArray();

for each note in noteRest {
	entry = CreateDictionary();
	entry['pitch'] = note.WrittenName;
	entry['accStyle'] = note.AccidentalStyle;
	entries.Push(entry);
}

for each entry in entries {
	pitchLength = Length(entry.pitch) - 1;

	switch (entry.accStyle) {
		case (BracketedAcc) {
			pitchLength = pitchLength + 2;
		}
		case (CautionaryAcc) {
			pitchLength = pitchLength + 1;
		}
	}

	if (pitchLength > maxChars) {
		maxChars = pitchLength;
	}
}

for i = 0 to maxChars {
	result = result & ' ';
}

return result;
}"
}