build.gradle

plugins {
    id 'maven'
    id 'java'
    id 'com.jfrog.bintray' version '1.7.3'
    id 'net.researchgate.release' version '2.6.0'
    id 'eclipse'
}

apply from: 'code-style/codestyle.gradle'

task cleanScreenshotDir(type: Delete) {
    description = "cleanup any screenshots written"
    delete fileTree(dir: "${projectDir}/screenshots", include: "**/*.png")
}

test.dependsOn cleanScreenshotDir

def coreFixtureVersion = "3.2.0" 
def seleniumJavaVersion = "3.5.3"

dependencies {
	compile 'org.slf4j:slf4j-api:1.7.18'
	compile 'org.apache.logging.log4j:log4j-core:2.5'
	compile 'org.apache.logging.log4j:log4j-api:2.5'
	compile 'org.apache.logging.log4j:log4j-slf4j-impl:2.5'
	compile 'junit:junit:4.12'
	testCompile group: 'org.powermock', name: 'powermock-module-junit4', version: '1.6.6'
    testCompile group: 'org.powermock', name: 'powermock-api-mockito', version: '1.6.6'
    // these are just added for web-fixtures 
    compile "org.testeditor.fixture:core-fixture:$coreFixtureVersion"
    compile "org.seleniumhq.selenium:selenium-java:$seleniumJavaVersion"
    compile 'com.paulhammant:ngwebdriver:1.0'
    compile 'io.github.bonigarcia:webdrivermanager:1.7.2'
    compile 'com.google.code.gson:gson:2.8.2'
}

configurations.all {
    resolutionStrategy {
        // fail eagerly on version conflict (includes transitive dependencies)
        // e.g. multiple different versions of the same dependency (group and name are equal)
        // failOnVersionConflict()
    
        // force certain versions of dependencies (including transitive)
        //  *append new forced modules:
        force 'org.slf4j:slf4j-api:1.7.18', "org.seleniumhq.selenium:selenium-java:$seleniumJavaVersion"
    }
}

sourceSets.main.resources.srcDirs = [ "src/main/java" ]
sourceSets.main.resources.includes = [ "**/*.aml" ]

/* 
 * code below copied from core-fixture
 */
repositories {
    jcenter()
}

group = 'org.testeditor.fixture'

sourceCompatibility = 1.8
targetCompatibility = 1.8

// show standard out during test to see logging output
test.testLogging.showStandardStreams = true

jar {
    manifest {
        attributes 'Implementation-Title': "${project.group}.${project.name}",
                   'Implementation-Version': project.version
    }
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives sourcesJar
}

install {
    repositories.mavenInstaller {
        pom.packaging = 'jar'
    }
}

release {
    preTagCommitMessage = '[release]'
    tagCommitMessage = '[release]'
    newVersionCommitMessage = '[release] new version'
    tagTemplate = 'v${version}'
}

bintray {
    user = System.getenv('BINTRAY_USER')
    key = System.getenv('BINTRAY_KEY')
    configurations = ['archives']
    publish = true 
    pkg {
        repo = 'Fixtures'
        name = project.name
        userOrg = 'test-editor'
        licenses = ['EPL-1.0']
        vcsUrl = "https://github.com/test-editor/${project.name}.git"
        version {
            name = project.version
            vcsTag = "v$project.version"
        }
        websiteUrl = 'http://testeditor.org'
    }
}