LQGlobal.pri

# Config Para
CONFIG(debug, debug|release):{
	FILE_POSTFIX = D
	DIR_COMPILEMODE = Debug
}
else:CONFIG(release, debug|release):{
	FILE_POSTFIX =
	DIR_COMPILEMODE = Release
}

win32:{
	CONFIG(MinGW, MinGW|MSVC):{
		DIR_COMPILER = MinGW
		FILE_LIB_PREFIX = lib
		FILE_LIB_EXT = .a
	}
	else:CONFIG(MSVC, MinGW|MSVC):{
		DIR_COMPILER = MSVC
		FILE_LIB_PREFIX =
		FILE_LIB_EXT = .lib
	}

	DIR_PLATFORM = Win32
	FILE_DLL_PREFIX =
	FILE_DLL_EXT = .dll
}
else:mac:{
	CONFIG(clang, clang):{
		DIR_COMPILER = clang
	}

	DEFINES += MAC
	DIR_PLATFORM = MAC
	FILE_LIB_PREFIX = lib
	FILE_LIB_EXT = .a
	FILE_DLL_PREFIX = lib
	FILE_DLL_EXT = .so
}
else:linux:{
	CONFIG(GCC, GCC|GCC32|GCC64):{
			DIR_COMPILER = GCC
	}
	else:CONFIG(GCC32, GCC|GCC32|GCC64):{
			DIR_COMPILER = GCC32
	}
	else:CONFIG(GCC64, GCC|GCC32|GCC64):{
			DIR_COMPILER = GCC64
	}

	DIR_PLATFORM = Linux
	FILE_LIB_PREFIX = lib
	FILE_LIB_EXT = .a
	FILE_DLL_PREFIX = lib
	FILE_DLL_EXT = .so
}


DESTDIR  = $$PWD/Bin/$${DIR_PLATFORM}/Client/$${DIR_COMPILER}/$${DIR_COMPILEMODE}

DIR_DEPEND_DEST = $$PWD/Bin/$${DIR_PLATFORM}/Client/$${DIR_COMPILER}/$${DIR_COMPILEMODE}