build.gradle

buildscript {
    ext.spotless_version = '3.6.0'

    repositories {
        jcenter()
        maven { url "https://plugins.gradle.org/m2/" }
    }

    dependencies {
        classpath "com.diffplug.spotless:spotless-plugin-gradle:$spotless_version"
        classpath "com.github.jengelman.gradle.plugins:shadow:1.2.4"
    }
}

allprojects {
    group 'com.github.kvnxiao'
    version '1.0.1'

    task wrapper(type: Wrapper) {
        gradleVersion = '4.2.1'
        distributionUrl = "https://services.gradle.org/distributions/gradle-$gradleVersion-all.zip"
    }
}

apply plugin: 'java'
apply plugin: 'com.github.johnrengelman.shadow'
apply plugin: 'com.diffplug.gradle.spotless'

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    jcenter()
}

dependencies {
    compile 'org.slf4j:slf4j-api:1.7.25'
    compile 'me.doubledutch:lazyjson:2.3.1'
    testCompile 'ch.qos.logback:logback-classic:1.2.3'
    testCompile group: 'junit', name: 'junit', version: '4.12'
}

spotless {
    java {
        googleJavaFormat("1.4")
        licenseHeaderFile "${rootProject.projectDir}/docs/license_header"
        importOrder 'java', 'javax', 'com', 'org'
        trimTrailingWhitespace()
        removeUnusedImports()
    }
}

task outputDocWebsite(type: Copy) {
    from("${project.buildDir}/docs/javadoc")
    into("${rootProject.projectDir}/docs/")
}

javadoc.finalizedBy outputDocWebsite