Can you disable some plugsin without removing them?

[Xiaoming94]

I guess this is probably an edge-usecase (I know for certain it is for me...) but is there a way to only enable some plugins you have listed in zsh_plugins.txt or do I have to comment them out?

I'm thinking this is mainly for like prompt themes. So assume, I have powerlevel10k, omz/robbyrussel or a zsh-prompt that I've created myself in my $ZDOTDIR and I only want to load one of them when starting the prompt (so that the other themes remain unsourced).

Is this achievable without removing the prompt-themes I installed with antidote?

[Xiaoming94]

I am probably the worst kind of person with RTFM. Apparently when it comes to prompt themes, that is why we use autoload promptinit stuff in the documentation. So when it comes to themes, this was never an issue.

But I guess, this question still stands for other plugins and libraries out of people's curiosity

[mattmc3]

This isn't an edge case at all! It's a great question and I'm sure a lot of people would benefit from a bit more explanation of how the Zsh prompt system works, and how to use antidote with it.

First off:

is there a way to only enable some plugins you have listed in zsh_plugins.txt or do I have to comment them out

The answer for most plugins is, yes - the way to disable them in antidote is to comment them out in .zsh_plugins.txt.

I'm thinking this is mainly for like prompt themes.

Prompt themes are different! If you are using the built-in Zsh prompt system, you actually shouldn't be disabling those extra prompt plugins. You just need to not source them. That means you need to use antidote's kind: annotation to change from using the default kind:zsh to kind:fpath for prompt plugins (assuming they are properly designed to follow the Zsh's prompt system conventions).

Here's an example .zsh_plugins.txt:

# ${ZDOTDIR:-$HOME}/.zsh_plugins.txt

### Prompt themes
# Per the Zsh docs, all prompt functions need to be in your 'fpath' prior to calling 'promptinit'.

# You can use popular Zsh prompt plugins by loading them with 'kind:fpath'. Assuming
# they are properly built to properly support the Zsh prompt system, this will make them
# available to the 'prompt' command.
sindresorhus/pure kind:fpath
romkatv/powerlevel10k kind:fpath
miekg/lean kind:fpath

# To use your own custom prompts, you can also have antidote add a directory
# (eg: $ZDOTDIR/themes) to your fpath and put your own prompt functions in it
# For example, if you like the Starship prompt, drop a function file in called
# '$ZDOTDIR/themes/prompt_starship_setup' with the following contents:
#
#   (( $# )) && export STARSHIP_CONFIG="$1"
#   source <(starship init zsh)
#
# Now you can load the Starship prompt by putting this in your .zshrc:
#
#  autoload -Uz promptinit && prompt starship /path/to/my/starship.toml`
#
$ZDOTDIR/themes kind:fpath

Then in your .zshrc:

# .zshrc
setopt prompt_subst
autoload -Uz promptinit && promptinit
prompt starship

Alternatively, if you source a prompt plugin (kind:zsh), you don't need to do promptinit yourself in your .zshrc at all, but in that scenario you want to comment out every other prompt plugin or they'll all load and slow down your config. Using this kind:fpath method I just described is much nicer, more flexible, and even lets you quickly change your prompt during an interactive session.

It's also important to note that Oh-My-Zsh themes were NOT built to properly support the Zsh prompt system. (That's one of many reasons I don't really prefer Oh-My-Zsh). In order to support the Zsh prompt system, OMZ themes would have to have proper functions (eg: prompt_robbyrussell_setup). However, you can solve this by making your own if you want. Just drop a file in ${ZDOTDIR:-$HOME}/themes/prompt_omz_setup with the following contents:

# contents of ${ZDOTDIR:-$HOME}/themes/prompt_omz_setup

# Be sure OMZ's requirements are set up. To do that, I recommend using the
# 'getantidote/use-omz' plugin to lazy-load whatever you need from OMZ!
# If you don't, you will need to load all the OMZ prerequisites yourself.
# Uncomment the following lines (though really, use getantidote/use-omz - it's great):
# ZSH="$(antidote path ohmyzsh/ohmyzsh)"
# source $ZSH/lib/*.zsh

# Now, load whatever OMZ theme you want.
[[ -n "$ZSH_THEME" ]] || ZSH_THEME="${1:-robbyrussell}"
source $ZSH/themes/${ZSH_THEME}.zsh-theme

Now, in your .zshrc you can load any OMZ theme with the Zsh prompt system like so:

# .zshrc
setopt prompt_subst
autoload -Uz promptinit && promptinit
prompt omz robbyrussell

I know this was a lot - probably more than you needed - but hopefully helpful. Let me know if you have any other questions.