Add System-Initialization Sub to Install Codeunit

[christianbraeunlich]

Hello there,
there's nothing wrong with initializing your setup tables (in all/certain companies) when your app gets installed (SubType = Install) and you should keep on doing that.

What I would suggest: make sure that these functions are called whenever there is a new company being created (aka. "System-Initialization" / OnCompanyInitialize)

Therefor:

Bad code

codeunit 50000 "BAD Install CU"
{
    Subtype = Install;

    trigger OnInstallAppPerCompany()
    begin
        InitializeModuleSetup();
    end;

    local procedure InitializeModuleSetup()
    var
        ModuleSetup: Record "Module Setup";
    begin
        if not ModuleSetup.Get() then begin
            ModuleSetup.Init();
            ModuleSetup.Insert(true);
        end;
    end;
}

Good code

codeunit 50000 "GOOD Install CU"
{
    Subtype = Install;

    trigger OnInstallAppPerCompany()
    begin
        InitializeModuleSetup();
    end;

    [EventSubscriber(ObjectType::Codeunit, Codeunit::"Company-Initialize", 'OnCompanyInitialize', '', false, false)]
    local procedure InitializeCompany()
    begin
        InitializeModuleSetup();
    end;

    local procedure InitializeModuleSetup()
    var
        ModuleSetup: Record "Module Setup";
    begin
        if not ModuleSetup.Get() then begin
            ModuleSetup.Init();
            ModuleSetup.Insert(true);
        end;
    end;
}

[christianbraeunlich]

One additional thing to mention here is the Retention Policy. Maybe even a new Best Practice to always allow the selected tables for the retention policy on newly created companies.

[waldo1001]

Retention policy is yet another recommendation/guideline, no?

[christianbraeunlich]

Yea, could also be a new recommendation.
However I was thinking about a Best Practice to put the Retention Policy (AllowTable) into the "Company-Initialize", 'OnCompanyInitialize' EventSubscriber. This would allow customers to apply the Retention Policy to the specified tables from that extension even in newly created companies. Would simply mention it in here as another practical example - what do you think? 🦦

[rvanbekkum]

Looks like Microsoft adopted this rule/guideline in AA0235: https://learn.microsoft.com/en-us/dynamics365/business-central/dev-itpro/developer/analyzers/codecop-aa0235

I cannot get it to trigger yet though (do you?), might be a bug, ... or I am forgetting something right now. 🤔

[rvanbekkum]

Reported the issue now: microsoft/AL#7269

[christianbraeunlich]

Reported this issue now aswell: https://github.com/MicrosoftDocs/dynamics365smb-devitpro-pb/issues/2638

[pri-kise]

Does anybody know what's the difference between the events

    [EventSubscriber(ObjectType::Codeunit, Codeunit::"System Initialization", 'OnAfterInitialization', '', false, false)]
    local procedure AddAllowedTablesOnAfterSystemInitialization()
    begin
        AddRetentionPolicyAllowedTables();
    end;

Reference: https://github.com/microsoft/ALAppExtensions/blob/main/Modules/System/Email/src/EmailInstaller.Codeunit.al

And the event

[EventSubscriber(ObjectType::Codeunit, Codeunit::"Company-Initialize", 'OnCompanyInitialize', '', false, false)]
    local procedure InitializeCompany()
    begin
        InitializeModuleSetup();
    end;

[christianbraeunlich]

Good question. The answer hides inside the BaseApp Codeunit CompanyInitialize: https://github.dev/StefanMaron/MSDyn365BC.Code.History/blob/master/BaseApp/Source/Base%20Application/CompanyInitialize.Codeunit.al#L62. On line 62 the publisher OnCompanyInitialize is triggered.

OnAfterInitialization is deprecated (see: https://github.dev/StefanMaron/MSDyn365BC.Code.History/blob/master/System%20Application/Source/System%20Application/System%20Initialization/src/SystemInitialization.Codeunit.al#L42)

[EventSubscriber(ObjectType::Codeunit, Codeunit::"System Initialization", 'OnAfterLogin', '', false, false)]
local procedure CompanyInitializeOnAfterLogin()
var
    ClientTypeManagement: Codeunit "Client Type Management";
begin
    ...

    InitializeCompany();
end;

And InitializeCompany calls the OnRun trigger of the Company-Initialize codeunit:

internal procedure InitializeCompany()
var
    GLSetup: Record "General Ledger Setup";
begin
    if not GLSetup.Get() then
        CODEUNIT.Run(CODEUNIT::"Company-Initialize");
end;

I believe that the actual Application is triggering this event. Also notice that the (new) OnAfterLogin IntegrationEvent is Isolated := true:

/// <summary>
/// Integration event for after the login.
/// Subscribe to this event in order to execute additional initialization steps.
/// </summary>
[IntegrationEvent(false, false, true)]
internal procedure OnAfterLogin()
begin
end;

🦦