Ideas, Researchers, and Departments.nlogo

;; Title: Ideas, Researchers, and Departments
;; Author: Mike Packard
;; Date Modified: June 1st, 2021


;******************************************
;    Setting up globals, agent types
;******************************************

globals [ year month pubs auths ]

breed [ researchers researcher ]
breed [ departments department ]
breed [ ghosts ghost ]

departments-own [ prestige old-prestige encourage-colab internal-preference prob cum_prob  staff]

researchers-own [
  prestige progress dist-to-move collaborators uni                 ; Actual
  expected-prestige dist-to-consider my-potential-collaborators    ; Expectataions
  want-to-collaborate want-to-separate in-a-group                  ; Trackers
]

patches-own [ potential ]

undirected-link-breed [potential-colabs potential-colab]
undirected-link-breed [colabs colab]


;******************************************
;    Initializing the model
;******************************************

to setup
  clear-all
  setup-globals
  setup-departments
  setup-researchers
  setup-patches
  create-ghosts 1 [ set hidden? True ]
  reset-ticks
end

to setup-globals
  set year 1960
  set month 1
end

to setup-departments
  create-departments 50 [
    set hidden? True
    set prestige random-float 100
    set old-prestige prestige
    set prob exp 5.91954869 * exp (-0.06485822 * (who + 1))

    set encourage-colab 0.8 + (random-float 0.4)
    set internal-preference 0.8 + (random-float 0.4)
    set staff 0
  ]
  ask departments [ set cum_prob sum [prob] of departments with [self < myself] ]
end

to setup-researchers
  set-default-shape researchers "person"
  create-researchers 180 [
    set-researcher-attributes
  ]
end

to set-researcher-attributes
  set collaborators []
  set-department

  set progress 0
  set prestige (random-float 100.0)

  setxy random-xcor random-ycor
  set color [who] of uni * 10 + 5
end

to set-department
  let powerball random-float sum [prob] of departments
  let contenders departments with [cum_prob < powerball]
  set uni max-one-of contenders [cum_prob]
  ask max-one-of contenders [cum_prob] [ set staff staff + 1]
end

to setup-patches
  ask patches [
    set potential 60 + random-float 20
    set pcolor 60 + 7 * (potential / 100)
  ]
end

;******************************************
;    Define behaviors at each time-step
;******************************************

to go
  set pubs 0
  set auths 0

  add-researchers

  ask researchers [ set prestige prestige + ([prestige] of uni / 10) - 5]
  ask researchers [ set in-a-group False set want-to-collaborate False]
  ask researchers [ find-a-group ]
  ask researchers [ consider-group ]

  ask researchers [ update-groups ]
  ask potential-colabs [die]


  ask researchers [ move-or-work ]


  ask researchers [ publish ]
  ask researchers [ set prestige prestige * prestige-decay ]

  ask patches [ update-landscape ]

  normalize-department-prestige
  ask departments [ if random-float 1 > 0.95 [set encourage-colab encourage-colab * (0.95 + random-float 0.1)]]
  ask departments [ if random-float 1 > 0.95 [set internal-preference internal-preference * (0.95 + random-float 0.1)]]

  ifelse month = 12 [
    set month 1
    set year year + 1

    if departments-evolve [
      departments-learn
    ]
  ] [set month month + 1 ]

  if year > 2019 [ stop ]
  tick
end

to add-researchers
  if year < 1980 or year >= 2000 [
    create-researchers (1 + random 2) [ set-researcher-attributes ]
  ]
end



;******************************************
;    Take steps to update collaborations
;******************************************

to find-a-group
  if in-a-group = False [
    let nearby-researcher one-of other researchers in-radius 6 with [in-a-group = False and collaborators = [] ]

    if nearby-researcher != nobody [
      let group (turtle-set self nearby-researcher collaborators [collaborators] of nearby-researcher)
      ask group [
        create-potential-colabs-with other group [set hidden? true]
        set in-a-group True
      ]
    ]
  ]
end

to consider-group
  set my-potential-collaborators collaborators
  set expected-prestige 0
  set dist-to-consider 0
  set want-to-collaborate False
  set want-to-separate False
  consider-the-future

  set my-potential-collaborators [self] of link-neighbors
  consider-the-future

  if collaborators != [] [
    ;show who
    set my-potential-collaborators []
    consider-the-future
  ]
end

to update-groups
  if want-to-separate [
    ask turtle-set collaborators [ set collaborators remove myself collaborators ]
    ask my-links [die]
    set collaborators []
  ]

  if want-to-collaborate [
    if all? potential-colab-neighbors [want-to-collaborate] [
      create-colabs-with potential-colab-neighbors [set color 105 ]
      set collaborators  [self] of potential-colab-neighbors
    ]
  ]
end

;******************************************
;    Decide whether to explore or exploit
;******************************************

to move-or-work

  set expected-prestige 0
  set dist-to-consider 0
  set my-potential-collaborators collaborators

  consider-the-future

  repeat 5 [
    set heading random-float 360
    set dist-to-consider random-float 6 ; MAX-MOVE-DIST
    set my-potential-collaborators collaborators

    if collaborators != [] [
      ask one-of ghosts [
        set xcor [xcor] of myself
        set ycor [ycor] of myself
        set heading [heading] of myself
        fd [dist-to-consider] of myself
        if one-of (turtle-set [collaborators] of myself) in-radius 6 = nobody [
          ask myself [set my-potential-collaborators []]
        ]
      ]
    ]

    consider-the-future
  ]

  ifelse dist-to-move > 0 [

    if my-potential-collaborators = [] [
      ask my-colabs [die]
      ask turtle-set collaborators [set collaborators remove myself collaborators]
      set collaborators []
    ]
    fd dist-to-move
  ] [
    set progress progress + 1
    ask turtle-set collaborators [
      set progress progress + 1 ; Consider making this a random variable
      ]
    ]
end

;******************************************
;    Master function for calculating expected futures
;******************************************

to consider-the-future
  let new-expected-prestige prestige
  let expected-potential [potential] of patch-ahead dist-to-consider
  let expected-collaborator-potential map [ i -> [potential] of i] my-potential-collaborators
  let expected-progress progress
  let num-collaborators length my-potential-collaborators + 1
  let time-away 0

  let colab-score num-collaborators * [encourage-colab] of uni

  let my-uni uni
  let internal-collaborators length filter [ i -> [uni] of i = my-uni ] my-potential-collaborators
  let internal-score [internal-preference] of uni ^ internal-collaborators *
  (1 / [internal-preference] of uni) ^ (num-collaborators - internal-collaborators - 1)

  ; Rewrite this to allow for moves that don't take you out of range of your group
  if dist-to-consider > 0 [
    set expected-progress 0
  ]

  foreach (range foresight) [
    set new-expected-prestige new-expected-prestige * prestige-decay
    if dist-to-consider = 0 or time-away > 0 [
      set expected-progress expected-progress + num-collaborators
    ]

    if expected-progress >= time-to-publish [
      set expected-progress 0

      ; Determine expected reward
      let total-potential expected-potential + sum(expected-collaborator-potential)
      let mean-potential total-potential / num-collaborators
      let expected-reward mean-potential * 0.25 / num-collaborators

      set new-expected-prestige new-expected-prestige + expected-reward * discount-rate ^ time-away
      set expected-potential expected-potential - expected-reward
      set expected-collaborator-potential map [ i -> i - expected-reward ] expected-collaborator-potential
    ]

    set expected-potential precision (expected-potential * potential-decay) 3
    set expected-collaborator-potential map [ i -> precision (i * potential-decay) 3 ] expected-collaborator-potential

    set time-away time-away + 1
  ]

  if new-expected-prestige * internal-score * colab-score > expected-prestige [
    set expected-prestige new-expected-prestige
    set dist-to-move dist-to-consider
    if my-potential-collaborators != collaborators [ set want-to-collaborate True ]
    if my-potential-collaborators = [] and collaborators != [] [set want-to-separate True set want-to-collaborate False ]
  ]
end

;******************************************
;    Publish
;******************************************

to publish
  if progress >= time-to-publish [
    set pubs pubs + 1
    set auths auths + length collaborators + 1

    ; Determine reward per collaborator
    let total_potential potential + sum(map [ i -> [potential] of i] collaborators )
    let mean_potential total_potential / (length collaborators + 1)
    let reward mean_potential * (random-float 0.5) / (length collaborators + 1)
    let my-reward reward
    if length collaborators > 0 [ set my-reward reward * (mean [prestige] of turtle-set collaborators) / prestige]

    ; Update progress, prestige, department-prestige, potential, and potential of surrounding patches
    set progress 0
    set prestige prestige + my-reward
    set potential (potential - reward)

    ask uni [ set prestige prestige + reward ]

    let influence (prestige / 100 )
    let my-patch patch-here
    ask patches in-radius 4 [
      if pxcor != [pxcor] of my-patch or pycor != [pycor] of my-patch [
        set potential potential * (1 + (influence * (1 - distance myself / 4)))
      ]
    ]

    ; Tell collaborators to update progress, prestige, potential, and potential of surrounding patches
    ask turtle-set collaborators [
      set my-reward reward
      if length collaborators > 0 [ set my-reward reward * (mean [prestige] of turtle-set collaborators) / prestige]
      set progress 0
      set prestige prestige + my-reward
      set potential (potential - reward)
      ask uni [ set prestige prestige + reward ]

      set my-patch patch-here
      set influence (prestige / 100 )
      ask patches in-radius 4 [
        if pxcor != [pxcor] of my-patch or pycor != [pycor] of my-patch [
          set potential potential * (1 + (influence * (1 - distance myself / 4)))
        ]
      ]
    ]
  ]
  if prestige > 100 [ set prestige 100 ]
  if prestige < 0 [ set prestige 0.001 ]
end

;******************************************
;    Define Evolution at the Departmental Level
;******************************************

to departments-learn

  let rank-list sort [prestige / staff] of departments with [staff > 0]
  let num length rank-list
  let low-threshold item (floor num / 2) rank-list
  let high-threshold item (floor num * 0.9) rank-list

  ask departments with [staff > 0] [
    if  prestige / staff <= low-threshold [
      let teacher one-of departments with [staff > 0 and prestige / staff >= high-threshold]
      set encourage-colab [encourage-colab] of teacher
      set internal-preference [internal-preference] of teacher
    ]
  ]
end

;******************************************
;    Update topic areas and departments to prepare for next time-step
;******************************************

to update-landscape

  set potential precision (potential * potential-decay + random-float 0.1) 3
  if potential < 0 [set potential 0]
  if potential > 100 [set potential 100]
  set pcolor 60 + 7 * (potential / 100)

end

to normalize-department-prestige
  ask departments [
    set prestige prestige * dep-prestige-decay
    if prestige > 100 [ set prestige 100 ]
    if prestige < 0 [ set prestige 0 ]
  ]
end
@#$#@#$#@
GRAPHICS-WINDOW
210
10
785
586
-1
-1
7.0
1
10
1
1
1
0
1
1
1
0
80
0
80
0
0
1
ticks
30.0

BUTTON
25
55
88
88
setup
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
25
105
102
138
go-once
go
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
110
105
173
138
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

PLOT
798
62
998
212
Percentage Moving vs. Working
NIL
NIL
0.0
10.0
0.0
10.0
true
false
"" ""
PENS
"default" 1.0 0 -16777216 true "" "plot 100 * (count researchers with [dist-to-move > 0]) / (count researchers)"

SLIDER
20
170
192
203
prestige-decay
prestige-decay
0.70
0.99
0.95
0.01
1
NIL
HORIZONTAL

SLIDER
20
305
192
338
time-to-publish
time-to-publish
0
10
6.0
1
1
NIL
HORIZONTAL

SLIDER
20
385
192
418
discount-rate
discount-rate
0.5
0.99
0.8
0.01
1
NIL
HORIZONTAL

SLIDER
20
210
192
243
potential-decay
potential-decay
0.5
0.99
0.98
0.01
1
NIL
HORIZONTAL

SLIDER
20
345
192
378
foresight
foresight
12
32
24.0
1
1
NIL
HORIZONTAL

SWITCH
25
445
192
478
departments-evolve
departments-evolve
0
1
-1000

SLIDER
20
250
192
283
dep-prestige-decay
dep-prestige-decay
0
1
0.92
0.01
1
NIL
HORIZONTAL

@#$#@#$#@
## WHAT IS IT?

(a general understanding of what the model is trying to show or explain)

## HOW IT WORKS

(what rules the agents use to create the overall behavior of the model)

## HOW TO USE IT

(how to use the model, including a description of each of the items in the Interface tab)

## THINGS TO NOTICE

(suggested things for the user to notice while running the model)

## THINGS TO TRY

(suggested things for the user to try to do (move sliders, switches, etc.) with the model)

## EXTENDING THE MODEL

(suggested things to add or change in the Code tab to make the model more complicated, detailed, accurate, etc.)

## NETLOGO FEATURES

(interesting or unusual features of NetLogo that the model uses, particularly in the Code tab; or where workarounds were needed for missing features)

## RELATED MODELS

(models in the NetLogo Models Library and elsewhere which are of related interest)

## CREDITS AND REFERENCES

(a reference to the model's URL on the web if it has one, as well as any other necessary credits, citations, and links)
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
15
Circle -1 true true 203 65 88
Circle -1 true true 70 65 162
Circle -1 true true 150 105 120
Polygon -7500403 true false 218 120 240 165 255 165 278 120
Circle -7500403 true false 214 72 67
Rectangle -1 true true 164 223 179 298
Polygon -1 true true 45 285 30 285 30 240 15 195 45 210
Circle -1 true true 3 83 150
Rectangle -1 true true 65 221 80 296
Polygon -1 true true 195 285 210 285 210 240 240 210 195 210
Polygon -7500403 true false 276 85 285 105 302 99 294 83
Polygon -7500403 true false 219 85 210 105 193 99 201 83

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

wolf
false
0
Polygon -16777216 true false 253 133 245 131 245 133
Polygon -7500403 true true 2 194 13 197 30 191 38 193 38 205 20 226 20 257 27 265 38 266 40 260 31 253 31 230 60 206 68 198 75 209 66 228 65 243 82 261 84 268 100 267 103 261 77 239 79 231 100 207 98 196 119 201 143 202 160 195 166 210 172 213 173 238 167 251 160 248 154 265 169 264 178 247 186 240 198 260 200 271 217 271 219 262 207 258 195 230 192 198 210 184 227 164 242 144 259 145 284 151 277 141 293 140 299 134 297 127 273 119 270 105
Polygon -7500403 true true -1 195 14 180 36 166 40 153 53 140 82 131 134 133 159 126 188 115 227 108 236 102 238 98 268 86 269 92 281 87 269 103 269 113

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270
@#$#@#$#@
NetLogo 6.1.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
<experiments>
  <experiment name="experiment" repetitions="1" runMetricsEveryStep="true">
    <setup>setup</setup>
    <go>go</go>
    <metric>pubs</metric>
    <metric>auths</metric>
    <enumeratedValueSet variable="time-to-publish">
      <value value="6"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="foresight">
      <value value="24"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="departments-evolve">
      <value value="false"/>
      <value value="true"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="discount-rate">
      <value value="0.8"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="potential-decay">
      <value value="0.98"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="dep-prestige-decay">
      <value value="0.96"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prestige-decay">
      <value value="0.95"/>
    </enumeratedValueSet>
  </experiment>
  <experiment name="experiemnt-10" repetitions="5" runMetricsEveryStep="true">
    <setup>setup</setup>
    <go>go</go>
    <metric>pubs</metric>
    <metric>auths</metric>
    <enumeratedValueSet variable="time-to-publish">
      <value value="6"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="foresight">
      <value value="24"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="departments-evolve">
      <value value="false"/>
      <value value="true"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="discount-rate">
      <value value="0.8"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="potential-decay">
      <value value="0.98"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="dep-prestige-decay">
      <value value="0.96"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prestige-decay">
      <value value="0.95"/>
    </enumeratedValueSet>
  </experiment>
  <experiment name="department-evolution" repetitions="5" runMetricsEveryStep="true">
    <setup>setup</setup>
    <go>go</go>
    <metric>mean [encourage-colab] of departments</metric>
    <metric>mean [internal-preference] of departments</metric>
    <enumeratedValueSet variable="time-to-publish">
      <value value="6"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="foresight">
      <value value="24"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="departments-evolve">
      <value value="true"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="discount-rate">
      <value value="0.8"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="potential-decay">
      <value value="0.98"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="dep-prestige-decay">
      <value value="0.92"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prestige-decay">
      <value value="0.95"/>
    </enumeratedValueSet>
  </experiment>
</experiments>
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180
@#$#@#$#@
1
@#$#@#$#@