build.gradle

allprojects {
  version = '4.1.0'
}

buildscript {
  repositories {
    maven { url 'http://repo.springsource.org/plugins-release' }
  }
  dependencies {
    classpath 'org.springframework.build.gradle:propdeps-plugin:0.0.3'
  }
}

defaultTasks 'build'

subprojects {
  
  plugins.with {
    apply 'java'
    apply 'maven-publish'
    apply 'checkstyle'
    apply 'findbugs'
    apply 'jacoco'
    
    apply 'propdeps'
    apply 'propdeps-maven'
    apply 'propdeps-idea'
    apply 'propdeps-eclipse'
  }
  
  group = 'com.readytalk'
  description = 'Metrics StatsD Support'

  repositories {
    mavenCentral()
  }
  
  dependencies {
    compile (
      'org.slf4j:slf4j-api:1.7.5',
    )
  
    optional (
      'com.google.code.findbugs:jsr305:2.0.1',
      'com.google.code.findbugs:annotations:2.0.1',
    )
  
    testCompile (
      'junit:junit:4.11',
      'org.mockito:mockito-all:1.9.5',
      'org.slf4j:slf4j-jdk14:1.7.5',
      'org.easytesting:fest-assert-core:2.0M10',
    )
  }

  sourceCompatibility = 1.6
  targetCompatibility = 1.6

  tasks.withType(Compile) { 
    options.compilerArgs << "-Xlint:all" 
  }

  task sourceJar(type: Jar) {
    from sourceSets.main.allJava
  }

  checkstyle {
    toolVersion = '5.6'
    showViolations = false
    sourceSets = [sourceSets.main]
    configFile = file("$rootDir/config/checkstyle/checkstyle.xml")
  }

  findbugs {
    toolVersion = '2.0.1'
    sourceSets = [sourceSets.main]
    ignoreFailures = true
  }

  jacocoTestReport {
    reports {
      html.enabled = true
      csv.enabled = true
      xml.enabled = true
    } 
  }
  
  publishing {
    publications {
      mavenJava(MavenPublication) {
        from components.java

        artifact sourceJar {
          classifier "sources"
        }
      }
    }
  }

  jacocoTestReport.dependsOn test
  build.dependsOn javadoc, jacocoTestReport
}

task wrapper(type: Wrapper) {
  gradleVersion = '1.6'
}