multiplot

#!/bin/bash
USAGE="usage: multiplot [list of node numbers or ranges]"

# usage: multiplot [list of node numbers or ranges]"
# example: "multiplot 1 3 6-9 < datafile | pd"
# a null list prints all the columns
# RCW: 11/17/2015

export NODES=$*

awk '
   BEGIN {
      nodes=ENVIRON["NODES"]
   }

   /^[ ]*[-+.0-9]/ {
      lines++
      nf = max(nf,NF);
      for (i=1; i<=NF; i++) {
         F[i,lines] = $i
      }
      next;
   }

   // {	
      print $0	# pass non numeric through
   }

   function max(a,b) {
      if (a>b) return a
      return b
   }

   END {
     if (nodes=="") {
	 nnodes=nf
	 for (i=2; i<=nnodes; i++) {
	     for (j=1; j<=lines; j++) {
		print F[1,j], F[i,j]
	     }
	 }
     } else {
	 nnodes=split(expand(nodes),aa);
	 for (i=1; i<=nnodes; i++) {
	    for (j=1; j<=lines; j++) {
	       print F[1,j], F[aa[i],j]
	    }
	 }
      }
   }

   function expand(rangelist, n, out, a, o, b) {
       n=split(rangelist, a);
       out=""
       for(i=1; i<=n; i++) {
	    if(a[i] ~ /-/) {
		m=split(a[i],b,"-")
	        if (m==2) {
		    for(o=b[1];o<=b[2];o++) {
			out=out " " o
		    }
		    out=out " "
	        }
	    } else {
		out=out " " a[i];
	    }
	}
    	return out
   }
'

exit 1